accel1.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    accel1   ../engine/source/tools/accele/accel1.F
!||--- called by ------------------------------------------------------
!||    resol    ../engine/source/engine/resol.F
!||====================================================================
      SUBROUTINE accel1(A,FF,A2,A1,A0,AS,VS,SKEW)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com08_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      my_real a(3),a0(3,2),a1(3,2),a2(3,2),as(3),vs(3),skew(lskew),ff
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER J
      my_real pi1,pi8,pi38,spi8,spi38,c0,c1,c2,c3,c4,c5,c6,c7,c8,c9,x1,x2,x3,y1,y2,y3,z1,z2,z3,d,dd,d2,dp,e,g,f
 
      as(1) = a(1)*skew(1) + a(2)*skew(2) + a(3)*skew(3)
      as(2) = a(1)*skew(4) + a(2)*skew(5) + a(3)*skew(6)
      as(3) = a(1)*skew(7) + a(2)*skew(8) + a(3)*skew(9)
      vs(1) = vs(1)+as(1)*dt12
      vs(2) = vs(2)+as(2)*dt12
      vs(3) = vs(3)+as(3)*dt12
      IF(ff==zero)RETURN
C
      f = min(ff,zep4/dt2)
C-----------------------------------------------
C INITIALIALISATION DES COEFFICIENTS DU FILTRE
C-----------------------------------------------
      pi1   = two*atan2(one,zero)
      pi8  = pi1*one_over_8
      pi38 = three*pi8
      spi8  = sin(pi8)
      spi38 = sin(pi38)
 
      d  = tan(pi1*f*dt2)
 
      dd = d*d
      d2 = two*d
      dp = one + dd
      e  = d2*spi8
      g  = e + dp
      g  = one/g
 
      c0 = dd * g
      c1 = two* c0
      c2 = c0
      c3 = two * g - c1
      c4 = (e - dp) * g
 
      e  = d2*spi38
      g  = e + dp
      g  = one/g
 
      c5 = dd * g
      c6 = two * c5
      c7 = c5
      c8 = two * g - c6
      c9 = (e - dp) * g
C-----------------------------------------------
C FILTERING
C-----------------------------------------------
      DO j=1,3
        x1 = a0(j,2)
        x2 = a0(j,1)
        x3 = a(j)
        y1 = a1(j,2)
        y2 = a1(j,1)
        y3 = c0 * x3 + c1 * x2 + c2 * x1 + c3 * y2 + c4 * y1
        z1 = a2(j,2)
        z2 = a2(j,1)
        z3 = c5 * y3 + c6 * y2 + c7 * y1 + c8 * z2 + c9 * z1
 
        a0(j,2) = x2
        a0(j,1) = x3
        a1(j,2) = y2
        a1(j,1) = y3
        a2(j,2) = z2
        a2(j,1) = z3
      ENDDO
 
      as(1) = a2(1,1)*skew(1) + a2(2,1)*skew(2) + a2(3,1)*skew(3)
      as(2) = a2(1,1)*skew(4) + a2(2,1)*skew(5) + a2(3,1)*skew(6)
      as(3) = a2(1,1)*skew(7) + a2(2,1)*skew(8) + a2(3,1)*skew(9)
 
      RETURN
      END