accele.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    accele   ../engine/source/assembly/accele.F
!||--- called by ------------------------------------------------------
!||    resol    ../engine/source/engine/resol.F
!||====================================================================
        SUBROUTINE accele(
     1                  A       ,AR    ,V    ,MS      ,IN   ,
     2                  SIZE_NALE      ,NALE   ,MS_2D  ,
     3                  SIZE_NPBY, NPBY   )
C-----------------------------------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "inter22.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
        INTEGER, INTENT(IN) :: SIZE_NALE !< size of NALE array
        INTEGER, INTENT(IN) :: SIZE_NPBY !< 2nd dimension of NPBY array
        INTEGER, DIMENSION(SIZE_NALE), INTENT(IN) :: NALE !< array of ALE node (1 if the node is related to ALE computation
        INTEGER, DIMENSION(NNPBY,SIZE_NPBY), INTENT(IN) :: NPBY !< rigid body array
        my_real, DIMENSION(3,NUMNOD), INTENT(INOUT) :: a,v,ar !< acceleration, velocity and  angular acceleration
        my_real, DIMENSION(NUMNOD), INTENT(INOUT) :: ms,in,ms_2d !< mass and inertia
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: N,I,MSR
      my_real :: RTMP
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------     
      
      !------------------------------------------------!
      !       acceleration computation 
      !------------------------------------------------!       
        IF(n2d == 0) THEN
!$OMP DO SCHEDULE(guided)
            DO n=1,numnod
                IF(ms(n)>zero) THEN
                    rtmp = one / ms(n)
                    a(1,n) = a(1,n) * rtmp
                    a(2,n) = a(2,n) * rtmp
                    a(3,n) = a(3,n) * rtmp
                ELSE
                    a(1,n) = zero
                    a(2,n) = zero
                    a(3,n) = zero
                    IF(nmult/=0) THEN
                        v(1,n) = zero
                        v(2,n) = zero
                        v(3,n) = zero
                    ENDIF
                ENDIF
            ENDDO
!$OMP END DO
        ELSE
            DO i=1,nrbody        
                msr = npby(1,i)
                IF(msr>0) THEN
                    ms(msr) = ms_2d(msr)
                ENDIF
            ENDDO
!$OMP DO SCHEDULE(guided)
            DO n=1,numnod
                IF(ms(n)>zero) THEN
                    rtmp = one / ms(n)
                    a(1,n) = a(1,n) * rtmp
                    a(2,n) = a(2,n) * rtmp
                    a(3,n) = a(3,n) * rtmp
                ELSE
                    a(1,n) = zero
                    a(2,n) = zero
                    a(3,n) = zero
                    IF(nmult/=0) THEN
                        v(1,n) = zero
                        v(2,n) = zero
                        v(3,n) = zero
                    ENDIF
                ENDIF
            ENDDO
!$OMP END DO
        ENDIF
 
      !------------------------------------------------!
      !       angular acceleration computation 
      !------------------------------------------------!
        IF (iroddl/=0) THEN
!$OMP DO SCHEDULE(guided)
            DO n=1,numnod
                IF(in(n)>zero) THEN
                    rtmp = one / in(n)
                    ar(1,n) = ar(1,n) * rtmp
                    ar(2,n) = ar(2,n) * rtmp
                    ar(3,n) = ar(3,n) * rtmp
                ELSE
                    ar(1,n) = zero
                    ar(2,n) = zero
                    ar(3,n) = zero      
                ENDIF
            ENDDO
!$OMP END DO
        ENDIF
 
      !------------------------------------------------!
      !      FVM DOES NOT NEED ACCEL AND VEL           !
      !------------------------------------------------!      
        IF(int22>0)THEN
!$OMP DO SCHEDULE(guided)
            DO n=1,numnod
                IF(nale(n)/=0)THEN
                    a( 1:3,n) = zero
                    ar(1:3,n) = zero
                    ms(n)     = zero
                ENDIF
            ENDDO  
!$OMP END DO   
        ENDIF      
      !------------------------------------------------!    
 
        RETURN
        END SUBROUTINE accele