aconv2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    aconv2                 ../engine/source/ale/ale2d/aconv2.F
!||--- called by ------------------------------------------------------
!||    aconve                 ../engine/source/ale/aconve.F
!||--- uses       -----------------------------------------------------
!||    ale_connectivity_mod   ../common_source/modules/ale/ale_connectivity_mod.F
!||====================================================================
      SUBROUTINE aconv2(VTOT,PHI,FLUX,FLU1,ALE_CONNECT,QMV,IFLG, IXQ, X, IOFF)
      USE ale_connectivity_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "mvsiz_p.inc"
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "com08_c.inc"
#include      "vect01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IFLG, IXQ(NIXQ, NUMELQ)
      INTEGER,INTENT(IN) :: IOFF
      my_real vtot(*), phi(*), flux(4,*), flu1(*), qmv(8,*), x(3,numnod)
      TYPE(t_ale_connectivity), INTENT(IN) :: ALE_CONNECT
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, J,IE, IV, IAD2, LGTH
      my_real vl(6,mvsiz), r1, r2, r3, r4
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      DO i=lft,llt
         ie =nft+i
         iad2 = ale_connect%ee_connect%iad_connect(ie)
         lgth = ale_connect%ee_connect%iad_connect(ie+1) - iad2
         DO j=1,lgth
            iv = ale_connect%ee_connect%connected(iad2 + j - 1)
            IF(iv > 0)THEN
               vl(j,i)=phi(iv)*flux(j,i)
            ELSEIF(iv == 0)THEN
               vl(j,i)=phi(ie)*flux(j,i)
            ELSE
            ! -IV is segment ID
            !  ebcs : PHI(NUMEL + 1:NSEGFLU) is filled in aconve.F using 
            ! SEGVAR (filled in ebcs[0-9][0-9].F)
               vl(j,i) = phi(-iv+ioff) *flux(j,i)           
            ENDIF
         ENDDO
      ENDDO
      
      DO i=lft,llt
        ie =nft+i
        vtot(i) = vtot(i) + half * dt1 * (- phi(ie)*flu1(i) - vl(1,i)-vl(2,i)-vl(3,i)-vl(4,i) )
        vtot(i)=max(em20,vtot(i))
      ENDDO
C
      IF(trimat > 0 .AND. iflg == 1)THEN
         IF (n2d  ==  1) THEN
            DO i=lft,llt
               ie =nft+i
               r1 = half * (x(2, ixq(2, ie)) + x(2, ixq(3, ie)))
               r2 = half * (x(2, ixq(3, ie)) + x(2, ixq(4, ie)))
               r3 = half * (x(2, ixq(4, ie)) + x(2, ixq(5, ie)))
               r4 = half * (x(2, ixq(5, ie)) + x(2, ixq(2, ie)))
               !!! Beware of r=0 axis
               IF (r1  ==  zero) r1 = one
               IF (r2  ==  zero) r2 = one
               IF (r3  ==  zero) r3 = one
               IF (r4  ==  zero) r4 = one
               !!! Divide by mean radius
               qmv(1,i) = qmv(1,i) - vl(1,i) / r1 - phi(ie)*qmv(5,i) 
               qmv(2,i) = qmv(2,i) - vl(2,i) / r2 - phi(ie)*qmv(6,i) 
               qmv(3,i) = qmv(3,i) - vl(3,i) / r3 - phi(ie)*qmv(7,i) 
               qmv(4,i) = qmv(4,i) - vl(4,i) / r4 - phi(ie)*qmv(8,i) 
            ENDDO
         ELSE
            DO i=lft,llt
               ie =nft+i
               qmv(1,i) = qmv(1,i) - vl(1,i) - phi(ie)*qmv(5,i) 
               qmv(2,i) = qmv(2,i) - vl(2,i) - phi(ie)*qmv(6,i) 
               qmv(3,i) = qmv(3,i) - vl(3,i) - phi(ie)*qmv(7,i) 
               qmv(4,i) = qmv(4,i) - vl(4,i) - phi(ie)*qmv(8,i) 
            ENDDO
         ENDIF
      ENDIF
C-----------------------------------------------
      RETURN
      END