addmaspart.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    addmaspart             ../starter/source/tools/admas/addmaspart.F
!||--- called by ------------------------------------------------------
!||    initia                 ../starter/source/elements/initia/initia.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||    fretitl2               ../starter/source/starter/freform.F
!||--- uses       -----------------------------------------------------
!||    message_mod            ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE addmaspart(IPART,IPMAS,PARTSAV,
     .                      PART_AREA,PM,ADDEDMS,NOM_OPT,PARTSAV_PON)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE optiondef_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "scr17_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IPART(LIPART1,*)
      my_real partsav(20,*),partsav_pon(*),part_area(*),pm(npropm,*),addedms(*)
      INTEGER NOM_OPT(LNOPT1,*)
      TYPE (ADMAS_)  , DIMENSION(NODMAS)  :: IPMAS
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,ID_MASS,IPA,IP,NMAS,KAD,II,IMID,ITYPE,IFLAG
      my_real amas,msp,masst(nodmas),ratio,addmas
      CHARACTER(LEN=NCHARTITLE) :: TITR
C=======================================================================
!---
      masst(1:nodmas) = zero
!
      DO 10 i=1,nodmas
        id_mass  = ipmas(i)%ID
        nmas = ipmas(i)%NPART
        itype= ipmas(i)%TYPE
        iflag= ipmas(i)%WEIGHT_FLAG
        IF (itype /= 3 .and. itype /= 4 .and. 
     .      itype /= 6 .and. itype /= 7) GOTO 10
!
        CALL fretitl2(titr,nom_opt(lnopt1-ltitr+1,i),ltitr)
!
! check for type 4 and 7 :
! if AMAS (replacing mass) < MSP (structured mass of concerned parts or list of parts)
        IF (itype == 4) THEN
          msp = zero ! structured mass of liste of parts
          amas = zero
          DO ii = 1,nmas
            ip = ipmas(i)%PARTID(ii)
            msp = msp + partsav_pon(ip) ! structured mass (of list of parts)
            amas = ipmas(i)%PART(ii)%RPMAS
          ENDDO ! DO II = 1,NMAS
          IF (amas > msp) THEN
            addmas = amas - msp
            DO ii =1,nmas
              ip = ipmas(i)%PARTID(ii)
              ipmas(i)%PART(ii)%RPMAS =  addmas ! non structural mass to be added (distributed)
            ENDDO ! DO II = KAD
          ELSE
            CALL ancmsg(msgid=1576,
     .                  msgtype=msgerror,
     .                  anmode=anstop,
     .                  i1=id_mass,
     .                  c1=ipmas(i)%TITLE,
     .                  r1=msp-amas)
          ENDIF ! IF (AMAS > MSP)
        ELSEIF (itype == 7) THEN
          DO ii = 1,nmas
            ip = ipmas(i)%PARTID(ii)
            msp = partsav_pon(ip) ! structured mass of part
            amas = ipmas(i)%PART(ii)%RPMAS ! non structural mass to be added (distributed)
            IF (amas > msp) THEN
              addmas = amas - msp
              ipmas(i)%PART(ii)%RPMAS = addmas ! non structural mass to be added (distributed)
            ELSE
              ipa = ipart(4,ip)
              CALL ancmsg(msgid=877,
     .                    msgtype=msgerror,
     .                    anmode=anstop,
     .                    i1=id_mass,
     .                    c1=ipmas(i)%TITLE,
     .                    r1=msp-amas,
     .                    i2=ipa)
            ENDIF ! IF (AMAS > MSP)
          ENDDO ! DO II = 1,NMAS
        ENDIF ! IF (ITYPE)
!
!  PART MASS DISTRIBUTION :
!
        DO ii = 1,nmas
          ip = ipmas(i)%PARTID(ii)
          msp = partsav_pon(ip)        ! ---> mass tag of PART
          masst(i) = masst(i) + msp
        ENDDO
!---
        DO ii = 1,nmas
          ip = ipmas(i)%PARTID(ii)
          msp  = partsav_pon(ip) ! structured mass part
          amas = ipmas(i)%PART(ii)%RPMAS     ! added mass part
!---
          IF (itype == 3 .OR. itype == 4) THEN
            ratio = msp / masst(i)
            amas = amas * ratio
            ipmas(i)%PART(ii)%RPMAS = amas
          ELSEIF (itype == 6 .OR. itype == 7) THEN
            ipmas(i)%PART(ii)%RPMAS = amas
          ENDIF ! IF (ITYPE)
!---
          addedms(ip) = addedms(ip) + ipmas(i)%PART(ii)%RPMAS
!---
        ENDDO ! DO II = 1,NMAS
!---
 10   CONTINUE
!---
      RETURN
      END