afimp3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    afimp3                 ../engine/source/ale/ale3d/afimp3.F
!||--- called by ------------------------------------------------------
!||    atherm                 ../engine/source/ale/atherm.F
!||--- uses       -----------------------------------------------------
!||    ale_connectivity_mod   ../common_source/modules/ale/ale_connectivity_mod.f
!||====================================================================
      SUBROUTINE afimp3(PM ,X, IXS, T,GRAD ,COEF ,ALE_CONNECT ,FV)
      USE ale_connectivity_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "com04_c.inc"
#include      "vect01_c.inc"
#include      "tabsiz_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
! SPMD CASE : SIXS >= NIXS*NUMELS    (SIXS = NIXS*NUMELS_L+NIXS*NSVOIS_L)
! IXQ(1:NIXS, 1:NUMELS) local elems
!    (1:NIXS, NUMELS+1:) additional elems (also on adjacent domains but connected to the boundary of the current domain)
!
! SPMD CASE : SX >= 3*NUMNOD    (SX = 3*(NUMNOD_L+NRCVVOIS_L))
! X(1:3,1:NUMNOD) : local nodes
!  (1:3, NUMNOD+1:) additional nodes (also on adjacent domains but connected to the boundary of the current domain)
!      
      INTEGER IXS(NIXS,SIXS/NIXS)
      my_real pm(npropm,nummat), x(3,sx/3), t(*), grad(6,*), coef(*), fv(*)
      TYPE(t_ale_connectivity), INTENT(IN) :: ALE_CONNECT
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER JFACE(MVSIZ), JVOIS(MVSIZ), NC1(MVSIZ), NC2(MVSIZ), NC3(MVSIZ), NC4(MVSIZ),
     .        IPERM(4,6), IFIMP, I, II, MAT, IFQ, J, IAD2, LGTH
      my_real x1(mvsiz), x2(mvsiz), x3(mvsiz), x4(mvsiz), y1(mvsiz), y2(mvsiz), y3(mvsiz), y4(mvsiz),
     .        z1(mvsiz), z2(mvsiz), z3(mvsiz), z4(mvsiz), tflu(mvsiz), xf(mvsiz),
     .        n1x, n1y, n1z, area
C-----------------------------------------------
      DATA iperm / 1,2,3,4,
     .             4,3,7,8,
     .             8,7,6,5,
     .             5,6,2,1,
     .             2,6,7,3,
     .             1,4,8,5/
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
 
C---------------------------------------------------------------------
C     CALCULATION OF IMPOSED FLUXES
C---------------------------------------------------------------------
      ifimp=0
      DO i=lft,llt
        ii =nft+i
        mat=ixs(1,ii)
        ifq=nint(pm(44,mat))
        IF(ifq /= 0)THEN
         tflu(i)=pm(60,mat)*fv(ifq)
         xf(i)=one
         ifimp=1
        ELSE
         tflu(i)=zero
         xf(i)=zero
        ENDIF
      ENDDO
      IF(ifimp == 0)RETURN
C---------------------------------------------------------------------
C     FINDING RELATED FACE
C---------------------------------------------------------------------
      DO i=lft,llt
        ii =nft+i
        iad2 = ale_connect%ee_connect%iad_connect(ii)
        lgth = ale_connect%ee_connect%iad_connect(ii + 1) - iad2
        DO j=1,lgth
         jface(i)=j
         jvois(i) = ale_connect%ee_connect%connected(iad2 + j - 1)
         IF(jvois(i) <= 0)cycle!next J
         mat=ixs(1,jvois(i))
         mtn=nint(pm(19,mat))
         IF(mtn /= 11)exit!next I
        enddo!next J
      enddo!next I
C-----------------------------------------------
C     SURFACE CALCULATION
C-----------------------------------------------
      DO i=lft,llt
        ii =nft+i
        nc1(i)=ixs(1+iperm(1,jface(i)),ii)
        nc2(i)=ixs(1+iperm(2,jface(i)),ii)
        nc3(i)=ixs(1+iperm(3,jface(i)),ii)
        nc4(i)=ixs(1+iperm(4,jface(i)),ii)
 
        x1(i)=x(1,nc1(i))
        y1(i)=x(2,nc1(i))
        z1(i)=x(3,nc1(i))
 
        x2(i)=x(1,nc2(i))
        y2(i)=x(2,nc2(i))
        z2(i)=x(3,nc2(i))
 
        x3(i)=x(1,nc3(i))
        y3(i)=x(2,nc3(i))
        z3(i)=x(3,nc3(i))
 
        x4(i)=x(1,nc4(i))
        y4(i)=x(2,nc4(i))
        z4(i)=x(3,nc4(i))
      ENDDO
C------------------------------------------
C     NORMAL VECTOR CALCULATION
C------------------------------------------
      DO i=lft,llt
        ii =nft+i
        n1x=(y3(i)-y1(i))*(z2(i)-z4(i)) - (z3(i)-z1(i))*(y2(i)-y4(i))
        n1y=(z3(i)-z1(i))*(x2(i)-x4(i)) - (x3(i)-x1(i))*(z2(i)-z4(i))
        n1z=(x3(i)-x1(i))*(y2(i)-y4(i)) - (y3(i)-y1(i))*(x2(i)-x4(i))
        area  = half * sqrt(n1x**2+n1y**2+n1z**2)
        t(ii) = (one-xf(i))*t(ii) + xf(i)*t(jvois(i))
     1  - area*tflu(i)*half*(coef(ii)+coef(jvois(i))) /
     2   max(em20,coef(ii)*coef(jvois(i))*grad(jface(i),i))
      ENDDO
 
      RETURN
      END