OpenRadioss 2025.1.11
OpenRadioss project
Loading...
Searching...
No Matches
aflux2.F
Go to the documentation of this file.
1Copyright> OpenRadioss
2Copyright> Copyright (C) 1986-2025 Altair Engineering Inc.
3Copyright>
4Copyright> This program is free software: you can redistribute it and/or modify
5Copyright> it under the terms of the GNU Affero General Public License as published by
6Copyright> the Free Software Foundation, either version 3 of the License, or
7Copyright> (at your option) any later version.
8Copyright>
9Copyright> This program is distributed in the hope that it will be useful,
10Copyright> but WITHOUT ANY WARRANTY; without even the implied warranty of
11Copyright> MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
12Copyright> GNU Affero General Public License for more details.
13Copyright>
14Copyright> You should have received a copy of the GNU Affero General Public License
15Copyright> along with this program. If not, see <https://www.gnu.org/licenses/>.
16Copyright>
17Copyright>
18Copyright> Commercial Alternative: Altair Radioss Software
19Copyright>
20Copyright> As an alternative to this open-source version, Altair also offers Altair Radioss
21Copyright> software under a commercial license. Contact Altair to discuss further if the
22Copyright> commercial version may interest you: https://www.altair.com/radioss/.
23!||====================================================================
24!|| aflux2 ../engine/source/ale/ale2d/aflux2.f
25!||--- called by ------------------------------------------------------
26!|| aflux0 ../engine/source/ale/aflux0.F
27!||--- calls -----------------------------------------------------
28!|| amulf2 ../engine/source/ale/bimat/amulf2.F
29!||--- uses -----------------------------------------------------
30!|| ale_connectivity_mod ../common_source/modules/ale/ale_connectivity_mod.F
31!|| element_mod ../common_source/modules/elements/element_mod.F90
32!||====================================================================
33 SUBROUTINE aflux2(PM ,IXQ ,V ,W ,X ,
34 . FLUX ,FLU1 ,FILL ,DFILL ,VOL ,
35 . ALE_CONNECT,ALPH)
36C-----------------------------------------------
37C M o d u l e s
38C-----------------------------------------------
39 USE ale_connectivity_mod
40 use element_mod , only : nixq
41C-----------------------------------------------
42C I m p l i c i t T y p e s
43C-----------------------------------------------
44#include "implicit_f.inc"
45C-----------------------------------------------
46C G l o b a l P a r a m e t e r s
47C-----------------------------------------------
48#include "mvsiz_p.inc"
49C-----------------------------------------------
50C C o m m o n B l o c k s
51C-----------------------------------------------
52#include "com01_c.inc"
53#include "com04_c.inc"
54#include "vect01_c.inc"
55#include "param_c.inc"
56C-----------------------------------------------
57C D u m m y A r g u m e n t s
58C-----------------------------------------------
59 INTEGER IXQ(NIXQ,NUMELQ)
60 my_real PM(NPROPM,NUMMAT),V(3,NUMNOD),W(3,NUMNOD),X(3,NUMNOD),FLUX(4,*),FLU1(*),FILL(*),DFILL(*),VOL(*),ALPH(*)
61 TYPE(t_ale_connectivity), INTENT(IN) :: ALE_CONNECT
62C-----------------------------------------------
63C L o c a l V a r i a b l e s
64C-----------------------------------------------
65 INTEGER MAT(mvsiz), NC1(mvsiz), NC2(mvsiz), NC3(mvsiz), NC4(mvsiz), I,II,J,IAD2
66 my_real
67 . y1(mvsiz), y2(mvsiz), y3(mvsiz), y4(mvsiz),z1(mvsiz), z2(mvsiz), z3(mvsiz), z4(mvsiz),
68 . n1y(mvsiz), n2y(mvsiz), n3y(mvsiz), n4y(mvsiz), n1z(mvsiz), n2z(mvsiz), n3z(mvsiz), n4z(mvsiz),
69 . flux1(mvsiz), flux2(mvsiz), flux3(mvsiz), flux4(mvsiz),
70 . vy1(mvsiz), vy2(mvsiz), vy3(mvsiz), vy4(mvsiz), vz1(mvsiz), vz2(mvsiz), vz3(mvsiz), vz4(mvsiz),
71 . vdy1(mvsiz), vdy2(mvsiz),vdy3(mvsiz), vdy4(mvsiz),
72 . vdz1(mvsiz), vdz2(mvsiz),vdz3(mvsiz), vdz4(mvsiz), upw(mvsiz),
73 . reduc,upwl(4,mvsiz)
74C-----------------------------------------------
75C S o u r c e L i n e s
76C-----------------------------------------------
77 mat(1) = 1
78 DO i=lft,llt
79 ii=i+nft
80 mat(i)=ixq(1,ii)
81 nc1(i)=ixq(2,ii)
82 nc2(i)=ixq(3,ii)
83 nc3(i)=ixq(4,ii)
84 nc4(i)=ixq(5,ii)
85
86 y1(i)=x(2,nc1(i))
87 z1(i)=x(3,nc1(i))
88
89 y2(i)=x(2,nc2(i))
90 z2(i)=x(3,nc2(i))
91
92 y3(i)=x(2,nc3(i))
93 z3(i)=x(3,nc3(i))
94
95 y4(i)=x(2,nc4(i))
96 z4(i)=x(3,nc4(i))
97
98 vdy1(i)=v(2,nc1(i)) - w(2,nc1(i))
99 vdz1(i)=v(3,nc1(i)) - w(3,nc1(i))
100
101 vdy2(i)=v(2,nc2(i)) - w(2,nc2(i))
102 vdz2(i)=v(3,nc2(i)) - w(3,nc2(i))
103
104 vdy3(i)=v(2,nc3(i)) - w(2,nc3(i))
105 vdz3(i)=v(3,nc3(i)) - w(3,nc3(i))
106
107 vdy4(i)=v(2,nc4(i)) - w(2,nc4(i))
108 vdz4(i)=v(3,nc4(i)) - w(3,nc4(i))
109 ENDDO
110C-----------------------------------------------
111C RELATIVE VELOCITY ON FACE
112C-----------------------------------------------
113 DO i=lft,llt
114 vy1(i)=half*(vdy1(i)+vdy2(i))
115 vy2(i)=half*(vdy2(i)+vdy3(i))
116 vy3(i)=half*(vdy3(i)+vdy4(i))
117 vy4(i)=half*(vdy4(i)+vdy1(i))
118
119 vz1(i)=half*(vdz1(i)+vdz2(i))
120 vz2(i)=half*(vdz2(i)+vdz3(i))
121 vz3(i)=half*(vdz3(i)+vdz4(i))
122 vz4(i)=half*(vdz4(i)+vdz1(i))
123 ENDDO
124C------------------------------------------
125C NORMAL VECTOR
126C------------------------------------------
127 DO i=lft,llt
128 n1y(i)= (z2(i)-z1(i))
129 n1z(i)=-(y2(i)-y1(i))
130
131 n2y(i)= (z3(i)-z2(i))
132 n2z(i)=-(y3(i)-y2(i))
133
134 n3y(i)= (z4(i)-z3(i))
135 n3z(i)=-(y4(i)-y3(i))
136
137 n4y(i)= (z1(i)-z4(i))
138 n4z(i)=-(y1(i)-y4(i))
139 ENDDO
140
141 IF(n2d == 1)THEN
142 DO i=lft,llt
143 n1y(i)= n1y(i)*(y1(i)+y2(i))*half
144 n1z(i)= n1z(i)*(y1(i)+y2(i))*half
145 n2y(i)= n2y(i)*(y2(i)+y3(i))*half
146 n2z(i)= n2z(i)*(y2(i)+y3(i))*half
147 n3y(i)= n3y(i)*(y3(i)+y4(i))*half
148 n3z(i)= n3z(i)*(y3(i)+y4(i))*half
149 n4y(i)= n4y(i)*(y1(i)+y4(i))*half
150 n4z(i)= n4z(i)*(y1(i)+y4(i))*half
151 ENDDO
152 ENDIF
153C--------------------
154C VOLUME FLUXES
155C--------------------
156 DO i=lft,llt
157 flux1(i)=(vy1(i)*n1y(i)+vz1(i)*n1z(i))
158 flux2(i)=(vy2(i)*n2y(i)+vz2(i)*n2z(i))
159 flux3(i)=(vy3(i)*n3y(i)+vz3(i)*n3z(i))
160 flux4(i)=(vy4(i)*n4y(i)+vz4(i)*n4z(i))
161 ENDDO
162C-----------------------------------------------
163C MULTIMAT LAW51 (SUBMATERIALS)
164C-----------------------------------------------
165 IF(nint(pm(19,mat(1))) == 51)THEN
166 DO i=lft,llt
167 flux(1,i)=flux1(i)
168 flux(2,i)=flux2(i)
169 flux(3,i)=flux3(i)
170 flux(4,i)=flux4(i)
171 ENDDO
172 RETURN
173 ENDIF
174C-----------------------------------------------
175C UPWIND
176C-----------------------------------------------
177 DO j=1,4
178 DO i=lft,llt
179 upwl(j,i)=pm(16,mat(i))
180 ENDDO
181 ENDDO
182 !======================================================!
183 ! BOUNDARY FACE : no volume flux by default !
184 ! slip wall bc !
185 !======================================================!
186 DO i=lft,llt
187 iad2 = ale_connect%ee_connect%iad_connect(i + nft)
188 reduc=pm(92,mat(i))
189
190 ii=ale_connect%ee_connect%connected(iad2 + 1 - 1)
191 IF(ii == 0)THEN
192 flux1(i)=flux1(i)*reduc
193 ENDIF
194C
195 ii=ale_connect%ee_connect%connected(iad2 + 2 - 1)
196 IF(ii == 0)THEN
197 flux2(i)=flux2(i)*reduc
198 ENDIF
199C
200 ii=ale_connect%ee_connect%connected(iad2 + 3 - 1)
201 IF(ii == 0)THEN
202 flux3(i)=flux3(i)*reduc
203 ENDIF
204C
205 ii=ale_connect%ee_connect%connected(iad2 + 4 - 1)
206 IF(ii == 0)THEN
207 flux4(i)=flux4(i)*reduc
208 ENDIF
209C
210 ENDDO !next I
211C-----------------------------------------------
212C MULTIMAT LAW 20 (OBSOLETE)
213C-----------------------------------------------
214 IF(jmult /= 0)THEN
215 DO i=lft,llt
216 upw(i) =pm(16,mat(i))
217 ENDDO
218 CALL amulf2(fill,dfill,flux,flu1,vol,ale_connect,alph,
219 . flux1, flux2, flux3, flux4, upw,
220 . nc1, nc2, nc3, nc4)
221 ELSE
222C
223 DO i=lft,llt
224 flux(1,i)=flux1(i)-upwl(1,i)*abs(flux1(i))
225 flux(2,i)=flux2(i)-upwl(2,i)*abs(flux2(i))
226 flux(3,i)=flux3(i)-upwl(3,i)*abs(flux3(i))
227 flux(4,i)=flux4(i)-upwl(4,i)*abs(flux4(i))
228
229 flu1(i) =flux1(i)+upwl(1,i)*abs(flux1(i))
230 . +flux2(i)+upwl(2,i)*abs(flux2(i))
231 . +flux3(i)+upwl(3,i)*abs(flux3(i))
232 . +flux4(i)+upwl(4,i)*abs(flux4(i))
233 ENDDO
234 ENDIF
235C-----------------------------------------------
236 RETURN
237 END
238C
aflux2
subroutine aflux2(pm, ixq, v, w, x, flux, flu1, fill, dfill, vol, ale_connect, alph)
Definition aflux2.F:36
amulf2
subroutine amulf2(fill, dfill, flux, flu1, vol, ale_connect, alpv, flux1, flux2, flux3, flux4, upw, nc1, nc2, nc3, nc4)
Definition amulf2.F:34
ale_connectivity_mod
Definition ale_connectivity_mod.F:225
ale_connectivity_mod::t_ale_connectivity
Definition ale_connectivity_mod.F:256