agaug3q.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    agaug3q                ../engine/source/ale/agaug3q.F
!||--- called by ------------------------------------------------------
!||    agauge                 ../engine/source/ale/agauge.F
!||--- uses       -----------------------------------------------------
!||    ale_connectivity_mod   ../common_source/modules/ale/ale_connectivity_mod.F
!||    element_mod            ../common_source/modules/elements/element_mod.F90
!||====================================================================
      SUBROUTINE agaug3q(LGAUGE,GAUGE,PHI,IXQ  ,X    ,ALE_CONNECT )
      USE ale_connectivity_mod
      use element_mod , only : nixq
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "vect01_c.inc"
#include      "param_c.inc"
#include      "tabsiz_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: IXQ(NIXQ,NUMELQ)
      INTEGER, INTENT(INOUT) :: LGAUGE(3,NBGAUGE)
      my_real, INTENT(IN) :: phi(sphi),x(3,numnod)
      my_real, INTENT(INOUT) :: gauge(llgauge,nbgauge)
      TYPE(t_ale_connectivity), INTENT(IN) :: ALE_CONNECT
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,II,J,N,IG,IAD2
      my_real alpha,xg,yg,zg,
     . det_12_1p,det_23_2p,det_34_3p,det_41_4p,
     . y1,z1,y2,z2,y3,z3,y4,z4
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------     
c--------------------------------------------------------------
c  Searching for the new element associated to the gauge
c--------------------------------------------------------------
      DO i=1,llt
        ii=i+nft  
        iad2 = ale_connect%ee_connect%iad_connect(ii)
        DO j=1,4
          n= ale_connect%ee_connect%connected(iad2 + j - 1)
          IF(n<=0)cycle
          ig=nint(phi(n))
          IF(ig==0)cycle
 
C            
            xg     = gauge(2,ig)
            yg     = gauge(3,ig)
            zg     = gauge(4,ig)
C                    
!           check if gauge is changing of element
            y1 = x(2,ixq(2,ii))
            z1 = x(3,ixq(2,ii))
            y2 = x(2,ixq(3,ii))
            z2 = x(3,ixq(3,ii))
            y3 = x(2,ixq(4,ii))
            z3 = x(3,ixq(4,ii))
            y4 = x(2,ixq(5,ii))
            z4 = x(3,ixq(5,ii))
 
            det_12_1p = (y2-y1)*(zg-z1)-(z2-z1)*(yg-y1)
            det_23_2p = (y3-y2)*(zg-z2)-(z3-z2)*(yg-y2)
            det_34_3p = (y4-y3)*(zg-z3)-(z4-z3)*(yg-y3)
            det_41_4p = (y1-y4)*(zg-z4)-(z1-z4)*(yg-y4)
 
            alpha = zero
            IF ((det_12_1p >=0 .AND. det_23_2p >=0 .AND.
     .           det_34_3p >=0 .AND. det_41_4p >=0) .OR.
     .          (det_12_1p <=0 .AND. det_23_2p <=0 .AND.
     .           det_34_3p <=0 .AND. det_41_4p <=0)) alpha = one
 
#include "lockon.inc"            
            IF(alpha == one .AND. alpha >= gauge(5,ig))THEN
c the gauge is changing of element
c element associated to the gauge
              lgauge(1,ig)=-ii
              gauge(5,ig)=alpha 
            ENDIF
#include "lockoff.inc"
          ENDDO
      ENDDO
 
 
      RETURN
      END