anioff6.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    anioffs           ../engine/source/output/anim/generate/anioff6.F
!||--- called by ------------------------------------------------------
!||    genani            ../engine/source/output/anim/generate/genani.F
!||--- calls      -----------------------------------------------------
!||    spmd_iget_partn   ../engine/source/mpi/anim/spmd_iget_partn.F
!||    write_c_c         ../common_source/tools/input_output/write_routines.c
!||--- uses       -----------------------------------------------------
!||    elbufdef_mod      ../common_source/modules/mat_elem/elbufdef_mod.F90
!||    my_alloc_mod      ../common_source/tools/memory/my_alloc.F90
!||====================================================================
      SUBROUTINE anioffs(ELBUF_TAB,IPARG   ,IOFF    ,EL2FA   ,NBF      ,
     .                   NBPART  ,IADG    ,ISPH3D  )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE elbufdef_mod
      USE my_alloc_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "sphcom.inc"
#include      "param_c.inc"
#include      "task_c.inc"
#include      "spmd_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
C     REAL
      INTEGER IPARG(NPARG,*),EL2FA(*),NBF,IOFF(*),
     .        nbpart, iadg(nspmd,*),
     .        isph3d
      TYPE (ELBUF_STRUCT_), DIMENSION(NGROUP), TARGET :: ELBUF_TAB
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
C     REAL
      INTEGER I, NG, NEL, NFT, IAD, ITY, LFT,
     .        n, j, llt, mlw, 
     .        isolnod,nn1,nn2,nn3,nn4,nn5
      INTEGER RBUF
      INTEGER,DIMENSION(:),ALLOCATABLE :: IOFFBUF
      TYPE(g_bufel_)  ,POINTER :: GBUF     
C=======================================================================
      CALL my_alloc(ioffbuf,nbf)
      nn1 = 1
      nn2 = 1
      nn3 = nn2 + numels
      nn4 = nn3 + isph3d*(numsph+maxpjet)
      nn5 = nn4 + numelig3d
C-----------------------------------------------
C
      DO 490 ng=1,ngroup
        mlw   =iparg(1,ng)
        nel   =iparg(2,ng)
        ity   =iparg(5,ng)
        nft   =iparg(3,ng)
        iad   =iparg(4,ng)
        isolnod = iparg(28,ng)
        lft=1
        llt=nel
C-----------------------------------------------
C       SOLIDES 16N
C-----------------------------------------------
        IF(ity==1.AND.isolnod==16)THEN
          IF(mlw == 0 .OR. mlw == 13)THEN
            DO i=lft,llt
              n = nft + i
              ioff(el2fa(nn2+n)) = 1
              ioff(el2fa(nn2+n)+1) = 1
              ioff(el2fa(nn2+n)+2) = 1
              ioff(el2fa(nn2+n)+3) = 1
            ENDDO
          ELSE
            gbuf => elbuf_tab(ng)%GBUF
            DO i=lft,llt
              n = nft + i
              ioff(el2fa(nn2+n))   = nint(min(gbuf%OFF(i),one))
              ioff(el2fa(nn2+n)+1) = nint(min(gbuf%OFF(i),one))
              ioff(el2fa(nn2+n)+2) = nint(min(gbuf%OFF(i),one))
              ioff(el2fa(nn2+n)+3) = nint(min(gbuf%OFF(i),one))
            ENDDO
          ENDIF
C-----------------------------------------------
C       AUTRES SOLIDES
C-----------------------------------------------
        ELSEIF(ity==1)THEN
          IF(mlw == 0 .OR. mlw == 13)THEN
            DO i=lft,llt
              n = nft + i
              ioff(el2fa(nn2+n)) = 1
            ENDDO
          ELSE
            gbuf => elbuf_tab(ng)%GBUF
            DO i=lft,llt
              n = nft + i
              ioff(el2fa(nn2+n)) = nint(min(gbuf%OFF(i),one))
            ENDDO
          ENDIF
        ELSEIF(isph3d==1.AND.ity==51)THEN
C-----------------------------------------------
C         TETRAS SPH.
C-----------------------------------------------
          IF(mlw==0)THEN
            DO i=lft,llt
              n = nft + i
              ioff(el2fa(nn3+n)) = 0
            ENDDO
          ELSE
            gbuf => elbuf_tab(ng)%GBUF
            DO i=lft,llt
              n = nft + i
              ioff(el2fa(nn3+n)) = nint(min(gbuf%OFF(i),one))
            ENDDO
          ENDIF
        ELSEIF(ity==101)THEN
C-----------------------------------------------
C ISO GEO ELEMS
C-----------------------------------------------
          IF(mlw==0)THEN
            DO i=lft,llt
              n = nft + i
              ioff(el2fa(nn4+n)) = 0
            ENDDO
          ELSE
            gbuf => elbuf_tab(ng)%GBUF
            DO i=lft,llt
             n = nft + i
             DO j=1,27
              ioff(el2fa(nn4+n)+j-1) = nint(min(gbuf%OFF(i),one))
             ENDDO
            ENDDO
          ENDIF
        ELSE
        ENDIF
C-----------------------------------------------
 490  CONTINUE
C-----------------------------------------------
      IF (nspmd==1) THEN
        CALL write_c_c(ioff,nbf)
      ELSE
        DO i = 1, nbf
          ioffbuf(i) = ioff(i)
        ENDDO
        IF (ispmd==0) THEN
          rbuf = numelsg + 3*numels16g + numsphg
        ELSE
          rbuf = 1
        ENDIF
 
        CALL spmd_iget_partn(1,nbf,ioffbuf,nbpart,iadg,rbuf,2)
      ENDIF
C
      DEALLOCATE(ioffbuf)
      RETURN
      END