aturi3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C
!||====================================================================
!||    aturi3             ../starter/source/ale/ale3d/aturi3.F
!||--- called by ------------------------------------------------------
!||    multifluid_init3   ../starter/source/multifluid/multifluid_init3.F
!||    s4init3            ../starter/source/elements/solid/solide4/s4init3.F
!||    sinit3             ../starter/source/elements/solid/solide/sinit3.F
!||====================================================================
      SUBROUTINE aturi3(IPARG,RHO,PM,IX,X,RK,RE,VOLU)
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C This subroutine is initializing state for
C  turbulency model K-EPS in ALE (3D)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "vect01_c.inc"
#include      "param_c.inc"
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER,INTENT(IN) :: IX(NIXS,*), IPARG(NPARG,NGROUP)
      my_real,INTENT(IN) :: rho(mvsiz), volu(mvsiz),pm(npropm,nummat), x(3,numnod)
      my_real,INTENT(INOUT) :: rk(mvsiz), re(mvsiz)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, II, MAT, NG, MTN2, LLT2, NFT2, LFT2, JJ, J
      my_real xl, xk, c1, xe, d2, x0, y0, z0, x1, y1, z1
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      IF(mtn == 17)THEN
        DO i=lft,llt
         ii=i+nft
         mat=iabs(ix(1,ii))
         rk(i)=rho(i)*pm(87,mat)
         xl=volu(i)**zep333
         xk= max(rk(i),em15)/rho(i)
         c1=pm(81,mat)
         xe=sqrt(xk*sqrt(c1))**3/(zep4187*xl)
         re(i)=rho(i)*xe
        END DO
      ELSE
        DO i=lft,llt
          ii=i+nft
          mat=iabs(ix(1,ii))
          rk(i)=rho(i)*pm(87,mat)
          xl=volu(i)**zep333
          xk= max(rk(i),em15)/rho(i)
          d2=ep30
          x0=x(1,ix(2,ii))+x(1,ix(3,ii))+x(1,ix(4,ii))+x(1,ix(5,ii))+x(1,ix(6,ii))+x(1,ix(7,ii))+x(1,ix(8,ii))+x(1,ix(9,ii))
          y0=x(2,ix(2,ii))+x(2,ix(3,ii))+x(2,ix(4,ii))+x(2,ix(5,ii))+x(2,ix(6,ii))+x(2,ix(7,ii))+x(2,ix(8,ii))+x(2,ix(9,ii))
          z0=x(3,ix(2,ii))+x(3,ix(3,ii))+x(3,ix(4,ii))+x(3,ix(5,ii))+x(3,ix(6,ii))+x(3,ix(7,ii))+x(3,ix(8,ii))+x(3,ix(9,ii))
          DO ng=1,ngroup
            mtn2=iparg(1,ng)
             IF(mtn2 == 17)THEN
               llt2=iparg(2,ng)
               nft2=iparg(3,ng)
               lft2=1
               DO jj=lft2,llt2
                 j=jj+nft2
                 x1=x(1,ix(2,j))+x(1,ix(3,j))+x(1,ix(4,j))+x(1,ix(5,j))+x(1,ix(6,j))+x(1,ix(7,j))+x(1,ix(8,j))+x(1,ix(9,j))
                 y1=x(2,ix(2,j))+x(2,ix(3,j))+x(2,ix(4,j))+x(2,ix(5,j))+x(2,ix(6,j))+x(2,ix(7,j))+x(2,ix(8,j))+x(2,ix(9,j))
                 z1=x(3,ix(2,j))+x(3,ix(3,j))+x(3,ix(4,j))+x(3,ix(5,j))+x(3,ix(6,j))+x(3,ix(7,j))+x(3,ix(8,j))+x(3,ix(9,j))
                 d2= min(d2,(x1-x0)**2+(y1-y0)**2+(z1-z0)**2)
               END DO !JJ=LFT2,LLT2
             ENDIF
          END DO !NG=1,NGROUP
          xl=xl+one_over_8*sqrt(d2)
          xe=zep33*sqrt(xk)**3/xl
          re(i)=rho(i)*xe
        END DO !I=LFT,LLT
      ENDIF
C-----------------------------------------------
      RETURN
      END