c3deri3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    c3deri3       ../engine/source/elements/sh3n/coque3n/c3deri3.F
!||--- called by ------------------------------------------------------
!||    c3forc3       ../engine/source/elements/sh3n/coque3n/c3forc3.F
!||    c3forc3_crk   ../engine/source/elements/xfem/c3forc3_crk.F
!||====================================================================
      SUBROUTINE c3deri3(JFT      ,JLT      ,PX1     ,PY1      ,PY2      ,
     .                   SMSTR    ,OFFG     ,ISMSTR  ,ALPE     ,ALDT     ,
     .                   UX1      ,UX2      ,UX3     ,UY1      ,UY2      ,
     .                   UY3      ,NEL      ,AREA    ,X21G     ,Y21G     ,
     .                   Z21G     ,X31G     ,Y31G    ,Z31G     ,X2       ,
     .                   Y2       ,X3       ,Y3      , 
     .                   E1X      ,E1Y      ,E1Z     ,E2X      ,                 
     .                   E2Y      ,E2Z      ,E3X     ,E3Y      ,E3Z      )       
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JFT, JLT,ISMSTR,NEL
      my_real
     .   PX1(*),PY1(*),PY2(*),OFFG(*),ALPE(MVSIZ),AREA(MVSIZ),
     .   E1X(MVSIZ), E1Y(MVSIZ), E1Z(MVSIZ),
     .   E2X(MVSIZ), E2Y(MVSIZ), E2Z(MVSIZ),
     .   E3X(MVSIZ), E3Y(MVSIZ), E3Z(MVSIZ),
     .   UX1(MVSIZ),UX2(MVSIZ),UX3(MVSIZ),UY1(MVSIZ),
     .   x2(mvsiz),y2(mvsiz),x3(mvsiz),y3(mvsiz),
     .   x21g(mvsiz), y21g(mvsiz), z21g(mvsiz),
     .   x31g(mvsiz), y31g(mvsiz), z31g(mvsiz),
     .   uy2(mvsiz),uy3(mvsiz),aldt(mvsiz)
      DOUBLE PRECISION SMSTR(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, II(3)
      my_real AL1, AL2, AL3, ALMAX
C=======================================================================
      DO i=jft,jlt
        x2(i)=e1x(i)*x21g(i)+e1y(i)*y21g(i)+e1z(i)*z21g(i)
        y2(i)=e2x(i)*x21g(i)+e2y(i)*y21g(i)+e2z(i)*z21g(i)
        x3(i)=e1x(i)*x31g(i)+e1y(i)*y31g(i)+e1z(i)*z31g(i)
        y3(i)=e2x(i)*x31g(i)+e2y(i)*y31g(i)+e2z(i)*z31g(i)
      ENDDO
C
      DO i=1,3
        ii(i) = nel*(i-1)
      ENDDO
C
      IF (ismstr == 11) THEN
        DO i=jft,jlt
          IF (abs(offg(i)) == one) offg(i)=sign(two,offg(i))
        ENDDO
        DO i=jft,jlt
          ux1(i) = zero
          uy1(i) = zero
          ux2(i) = zero
          uy2(i) = zero
          ux3(i) = zero
          uy3(i) = zero
          IF(abs(offg(i)) == two)THEN
            ux2(i) = x2(i)-smstr(ii(1)+i)
            ux3(i) = x3(i)-smstr(ii(2)+i)
            uy3(i) = y3(i)-smstr(ii(3)+i)
            x2(i)  = smstr(ii(1)+i)
            x3(i)  = smstr(ii(2)+i)
            y3(i)  = smstr(ii(3)+i)
            area(i) = half*x2(i)*y3(i)
          ELSE
            smstr(ii(1)+i)=x2(i)
            smstr(ii(2)+i)=x3(i)
            smstr(ii(3)+i)=y3(i)
          ENDIF
        ENDDO
      ELSEIF (ismstr == 1.OR.ismstr == 2) THEN
        DO i=jft,jlt
          IF(offg(i) == two)THEN
            x2(i)=smstr(ii(1)+i)
            x3(i)=smstr(ii(2)+i)
            y3(i)=smstr(ii(3)+i)
            area(i) = half*x2(i)*y3(i)
          ELSE
            smstr(ii(1)+i)=x2(i)
            smstr(ii(2)+i)=x3(i)
            smstr(ii(3)+i)=y3(i)
          ENDIF
        ENDDO
      ENDIF
      IF (ismstr == 1) THEN
        DO i=jft,jlt
          IF (offg(i) == one) offg(i)=two
        ENDDO
      ENDIF
C
      DO i=jft,jlt
        y3(i) = sign(max(em15,abs(y3(i))),y3(i))
        px1(i)=-half*y3(i)
        py1(i)= half*(x3(i)-x2(i))
        py2(i)=-half*x3(i)      
      ENDDO
C
      DO i=jft,jlt
        al1 = x2(i) * x2(i)      
        al2 = (x3(i)-x2(i)) * (x3(i)-x2(i)) + y3(i) * y3(i)
        al3 = x3(i) * x3(i) + y3(i) * y3(i)
        almax = max(al1,al2,al3)
        aldt(i)= two*area(i) / sqrt(almax)
        alpe(i)=one
      ENDDO
C---------------------------------------------------------
      RETURN
C
      END