c3fint3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    c3fint3       ../engine/source/elements/sh3n/coque3n/c3fint3.F
!||--- called by ------------------------------------------------------
!||    c3forc3       ../engine/source/elements/sh3n/coque3n/c3forc3.f
!||    c3forc3_crk   ../engine/source/elements/xfem/c3forc3_crk.F
!||====================================================================
      SUBROUTINE c3fint3(JFT  ,JLT  ,FOR  ,MOM  ,THK,
     2                   PX1  ,PY1  ,PY2  ,FX1  ,FX2,
     3                   FX3  ,FY1  ,FY2  ,FY3  ,FZ1,
     4                   FZ2  ,FZ3  ,MX1  ,MX2  ,MX3,
     5                   MY1  ,MY2  ,MY3  ,NEL  )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JFT, JLT, NEL
C     REAL
      my_real
     .   FOR(NEL,5), MOM(NEL,3), THK(*),
     .   px1(*), py1(*), py2(*),
     .   fx1(mvsiz), fx2(mvsiz), fx3(mvsiz),
     .   fy1(mvsiz), fy2(mvsiz), fy3(mvsiz),
     .   fz1(mvsiz), fz2(mvsiz), fz3(mvsiz),
     .   mx1(mvsiz), mx2(mvsiz), mx3(mvsiz),
     .   my1(mvsiz), my2(mvsiz), my3(mvsiz)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
C     REAL
      my_real
     .   F1, F2, F3, F4, F5, M1, M2, M3, M4, M5, TH2
C-----------------------------------------------
C
      DO i=jft,jlt
C
      f1 = for(i,1)*thk(i)
      f3 = for(i,3)*thk(i)
      fx1(i) =  f1 * px1(i) + f3 * py1(i)
      fx2(i) = -f1 * px1(i) + f3 * py2(i)
      fx3(i) = -fx1(i) - fx2(i)
C
      f2 = for(i,2)*thk(i)
      fy1(i) =  f2 * py1(i) + f3 * px1(i)
      fy2(i) =  f2 * py2(i) - f3 * px1(i)
      fy3(i) = -fy1(i) - fy2(i)
C
      f4 = for(i,4)*thk(i)
      f5 = for(i,5)*thk(i)
      fz1(i) =  f5 * px1(i) + f4 * py1(i)
      fz2(i) = -f5 * px1(i) + f4 * py2(i)
      fz3(i) = -fz1(i) - fz2(i)
C
      th2 = thk(i)*thk(i)
      m2 = mom(i,2)*th2
      m3 = mom(i,3)*th2
C
      mx1(i) = -m2 * py1(i) - m3 * px1(i)
      mx2(i) = -m2 * py2(i) + m3 * px1(i)
      mx3(i) = -mx1(i) - mx2(i)
C
      m1 = mom(i,1)*th2
      my1(i) =  m1 * px1(i) + m3 * py1(i)
      my2(i) = -m1 * px1(i) + m3 * py2(i)
      my3(i) = -my1(i) - my2(i)
C
      m4 = f4 * third
      m5 = f5 * third
      m5 = m5 * px1(i)
C
      my1(i) = my1(i) + m5 * (two*py1(i)+three*py2(i))
     .                + m4 * py1(i) * (py1(i)+two*py2(i))
      my2(i) = my2(i) + m5 * (three*py1(i)+two*py2(i))
     .                - m4 * py2(i) * (two*py1(i)+py2(i))
      my3(i) = my3(i) + m5 * (py1(i)+py2(i))
     .                + m4 * (py2(i)**2 - py1(i)**2)
C
      m5 = m5 * px1(i)
      m4 = m4 * px1(i)
C
      mx1(i) = mx1(i) - m5 - m4 * (two*py1(i)+py2(i)) 
      mx2(i) = mx2(i) + m5 - m4 * (py1(i)+two*py2(i)) 
      mx3(i) = mx3(i)      - m4 * three*(py1(i)+py2(i))       
      ENDDO
C
      RETURN
      END
!||====================================================================
!||    c3fintrz      ../engine/source/elements/sh3n/coque3n/c3fint3.F
!||--- called by ------------------------------------------------------
!||    c3forc3       ../engine/source/elements/sh3n/coque3n/c3forc3.F
!||    c3forc3_crk   ../engine/source/elements/xfem/c3forc3_crk.F
!||====================================================================
        SUBROUTINE c3fintrz(JFT  ,JLT  ,THK  ,AREA ,PX1  ,
     2                      PY1  ,PY2  ,F11  ,F12  ,F13  ,
     3                      F21  ,F22  ,F23  ,WXY  ,VSTRE,
     4                      VSRZ ,VMZ  ,BM0RZ,B0RZ ,BKRZ ,
     5                      BERZ ,KRZ  ,RLZ  ,DT1C ,EINT ,
     6                      OFF  ,VOL  ,NEL  )
C-----------------------------------------------
C   I M P L I C I T   T Y P E S
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D U M M Y   A R G U M E N T S
C-----------------------------------------------
        INTEGER JFT ,JLT,NEL
        my_real 
     .     THK(*)   ,AREA(*)   ,PX1(*)     ,PY1(*)    ,
     .     PY2(*)   ,F11(*)    ,F12(*)     ,F13(*)    ,
     .     F21(*)   ,F22(*)    ,F23(*)     ,WXY(*)   ,
     .     VSTRE(NEL,5),VSRZ(NEL,5) ,VMZ(MVSIZ,3),
     .     BM0RZ(MVSIZ,3,2),B0RZ(MVSIZ,3),BKRZ(MVSIZ,2),BERZ(MVSIZ,2),KRZ(*),
     .     RLZ(MVSIZ,3),DT1C,EINT(NEL,2),OFF(*),VOL(*)
C-----------------------------------------------
c FUNCTION: strains relative to the drilling dof for Tria
c
c Note:
c ARGUMENTS:  (I: input, O: output, IO: input * output, W: workspace)
c
c TYPE NAME                FUNCTION
c  I   JFT,JLT           - element id limit
c  I   AREA,THK(NEL)         - element area A, thickness
c  IO  FIJ(NEL)     - internal force in local system (J=1-3 node)
c  I   VSTRE(NEL,5) - stress Sxx,Syy,Sxy,Syz,Sxz
C  I   PX1,PY1,PX2=-PX1,PY2(NEL): standard [B] of Tria
c  O   VSRZ(NEL,NG)        asymmetrical stress Srz using 3of 5 places
c  O   VMZ(J,NEL)        -internal moment Mz(nodal) due to drilling dof
c  O   BM0RZ(NEL,I,J)   - constant terms of derivations for membrane
C                       I=1:A*Nx,x;I=2:A*Ny,y;I=3:A*(Nx,y+Ny,x); J=1,2(node)
C                        only store J=1,2 as f(j=3)=-f(j=1)-f(j=2)
C  O   B0RZ(NEL,J)       A*(-Nx,y+Ny,x -2Ni) for asymmetric rotation
c  O   BKRZ(NEL,J)     - Ksi terms of derivation : A*(-Nx,y+Ny,x -2Ni)
c  O   BERZ(NEL,J)    - Eta terms of derivation : A*(-Nx,y+Ny,x -2Ni)
c  I   WXY(NEL)        - asymmetric strain : 0.5*(-NxJ,y*VxJ+NyJ,x*VyJ)
c  I   KRZ(NEL)         -drilling dof modulus
c  I   RLZ(NEL,J)       - nodal Rz rotation velocity (J=1-3)
c  I   DT1C,EINT(NEL,2) - time step and internal energy (1:membrane 2:moment)
c  I   VOL,OFF(NEL)    - element volume and activation flag value
C-----------------------------------------------
C   L O C A L   V A R I A B L E S
C-----------------------------------------------
        INTEGER I ,J ,NG,NPG
       PARAMETER (NPG = 3)
        my_real
     .      c2, erz,off05(mvsiz),brz(mvsiz,3),vrlz(mvsiz),
     .     fx1,fx2,fy1,srzm(mvsiz),a_hammer(npg,2),a05(mvsiz),
     .     thk_6(mvsiz),bn1rz,bn2rz,bn3rz
      DATA a_hammer /
     1 0.166666666666667,0.666666666666667,0.166666666666667,
     2 0.166666666666667,0.166666666666667,0.666666666666667/
C--------------------------------c
       DO i=jft,jlt
        vmz(i,1)=(bm0rz(i,1,1)*vstre(i,1)+bm0rz(i,2,1)*vstre(i,2)
     .           +bm0rz(i,3,1)*vstre(i,3))*thk(i)
        vmz(i,2)=(bm0rz(i,1,2)*vstre(i,1)+bm0rz(i,2,2)*vstre(i,2)
     .           +bm0rz(i,3,2)*vstre(i,3))*thk(i)
        vmz(i,3)=-vmz(i,1)-vmz(i,2)
       ENDDO
c
       DO i=jft,jlt
        srzm(i)=zero
        off05(i)=one_over_6*off(i)*vol(i)
        a05(i)=half/area(i)
        thk_6(i)=one_over_6*thk(i)
       ENDDO
C--------NxI,x *A------pay attention Bi*A--- RLZ: VRZ--
      DO ng =1,npg
       DO i=jft,jlt
        bn1rz=bkrz(i,1)*a_hammer(ng,1)+berz(i,1)*a_hammer(ng,2)
        bn2rz=bkrz(i,2)*a_hammer(ng,1)+berz(i,2)*a_hammer(ng,2)
        bn3rz=-bn1rz-bn2rz
        brz(i,1)=b0rz(i,1)+bn1rz
        brz(i,2)=b0rz(i,2)+bn2rz
        brz(i,3)=b0rz(i,3)+bn3rz
        vrlz(i)= wxy(i)+(brz(i,1)*rlz(i,1)+
     1                   brz(i,2)*rlz(i,2)+brz(i,3)*rlz(i,3))*a05(i)
       ENDDO
       DO i=jft,jlt
        erz= vrlz(i)*dt1c
        eint(i,1) = eint(i,1)+ vsrz(i,ng)*erz*off05(i)
        vsrz(i,ng)= vsrz(i,ng)+krz(i)*erz*off(i)
        eint(i,1) = eint(i,1)+ vsrz(i,ng)*erz*off05(i)
        srzm(i)=srzm(i)+vsrz(i,ng)
       ENDDO
C        
        DO j=1,3
         DO i=jft,jlt
          c2=thk_6(i)*vsrz(i,ng)
          vmz(i,j)= vmz(i,j)+brz(i,j)*c2
         ENDDO
        ENDDO
      END DO !NG =1,NPG
C-------------------------------------------------
C        Constant Part PX2 = -PX1
C-------------------------------------------------
        DO i=jft,jlt
          c2=thk(i)*srzm(i)*one_over_6
          fx1=-c2*py1(i)
          fx2=-c2*py2(i)
C
          f11(i) = f11(i) + fx1
          f12(i) = f12(i) + fx2
          f13(i) = f13(i) - fx1 - fx2
C
          fy1=c2*px1(i)
          f21(i) = f21(i) + fy1
          f22(i) = f22(i) - fy1
C          F23(I) = F23(I) - FY1
        ENDDO
C
       RETURN
       END