carm24.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    carm24   ../engine/source/materials/mat/mat024/carm24.F
!||--- called by ------------------------------------------------------
!||    conc24   ../engine/source/materials/mat/mat024/conc24.F
!||====================================================================
      SUBROUTINE carm24(NEL  ,YMS  ,Y0S  ,ETS  ,EPXA ,SIGA ,
     .                  DEPS1,DEPS2,DEPS3,DEPS4,DEPS5,DEPS6)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NEL
      my_real, INTENT(IN) :: yms,y0s,ets
      my_real, DIMENSION(NEL,3) ,INTENT(INOUT) :: siga,epxa
      my_real, DIMENSION(NEL), INTENT(IN) :: deps1,deps2,deps3,
     .  deps4,deps5,deps6
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER  I
      my_real hs
      my_real, DIMENSION(NEL) :: s01,s02,s03,s1,s2,s3,
     .   de1,de2,de3,scle1,scle2,scle3,scal1,scal2,scal3
C=======================================================================
         hs = yms*ets / max(yms-ets,em20)
c
         DO i = 1,nel
            s1(i) = siga(i,1)+yms*deps1(i)
            s2(i) = siga(i,2)+yms*deps2(i)
            s3(i) = siga(i,3)+yms*deps3(i)
            s01(i) = y0s+hs*abs(epxa(i,1))
            s02(i) = y0s+hs*abs(epxa(i,2))
            s03(i) = y0s+hs*abs(epxa(i,3))
            scle1(i) = half+sign(half,abs(s1(i))-s01(i) )
            scle2(i) = half+sign(half,abs(s2(i))-s02(i) )
            scle3(i) = half+sign(half,abs(s3(i))-s03(i) )
         ENDDO
         DO i = 1,nel
            s01(i) = sign(s01(i),s1(i))
            s02(i) = sign(s02(i),s2(i))
            s03(i) = sign(s03(i),s3(i))
            scal1(i) = abs(s1(i)-s01(i))/max(abs(yms*deps1(i)),em20)
            scal2(i) = abs(s2(i)-s02(i))/max(abs(yms*deps2(i)),em20)
            scal3(i) = abs(s3(i)-s03(i))/max(abs(yms*deps3(i)),em20)
            de1(i) = scle1(i)*scal1(i)*(one-ets/(yms+em10))*deps1(i)
            de2(i) = scle2(i)*scal2(i)*(one-ets/(yms+em10))*deps2(i)
            de3(i) = scle3(i)*scal3(i)*(one-ets/(yms+em10))*deps3(i)
            epxa(i,1) = epxa(i,1)+de1(i)
            epxa(i,2) = epxa(i,2)+de2(i)
            epxa(i,3) = epxa(i,3)+de3(i)
         ENDDO
         DO i = 1,nel
            s01(i) = s01(i)+hs*de1(i)
            s02(i) = s02(i)+hs*de2(i)
            s03(i) = s03(i)+hs*de3(i)
            siga(i,1) = (one-scle1(i))*s1(i)+scle1(i)*s01(i)
            siga(i,2) = (one-scle2(i))*s2(i)+scle2(i)*s02(i)
            siga(i,3) = (one-scle3(i))*s3(i)+scle3(i)*s03(i) 
         ENDDO
c--------------
         RETURN
         END