cbatherm.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    cbatherm      ../engine/source/elements/shell/coqueba/cbatherm.F
!||--- called by ------------------------------------------------------
!||    cbaforc3      ../engine/source/elements/shell/coqueba/cbaforc3.F
!||--- uses       -----------------------------------------------------
!||    element_mod   ../common_source/modules/elements/element_mod.f90
!||====================================================================
      SUBROUTINE cbatherm(JFT  ,JLT    ,PM    ,THK    ,IXC   , 
     2                  BM     ,AREA   ,DTIME ,TEMPNC ,TEL   ,DHEAT  ,
     3                  NPLAT  ,IPLAT  ,FPHI  ,THEACCFACT)
      use element_mod , only : nixc
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER :: JFT,JLT,NPLAT
      INTEGER :: IXC(NIXC,*),IPLAT(*)
      my_real ,INTENT(IN) :: theaccfact
      my_real ,INTENT(IN) :: dtime
      my_real :: area(*), 
     .   tempnc(*), fphi(mvsiz,4), pm(npropm),dheat(*),
     .   thk(*),tel(*),bm(mvsiz,*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,EP,N1,N2,N3,N4
      my_real
     .  ca,cb ,kc ,phix,phiy,a,temp1,temp2,temp3,temp4,
     .  temp13,temp24,temph
C------------------------------------------
        ca = pm(75)
        cb = pm(76)
 
        DO ep=jft,nplat 
          i=iplat(ep)
 
          kc = ( ca + cb*tel(i))*dtime*theaccfact
C
          n1 = ixc(2,i)
          n2 = ixc(3,i)
          n3 = ixc(4,i)
          n4 = ixc(5,i)
 
          temp13 = tempnc(n1)-tempnc(n3)
          temp24 = tempnc(n2)-tempnc(n4)
          temph  = tempnc(n1)-tempnc(n2)+tempnc(n3)-tempnc(n4)
C 
C - flux : K gradT = B * T
C   
 
          phix =  temp13*bm(i,1) + temp24*bm(i,2)+bm(i,3)*temph
          
          phiy =  temp13*bm(i,5) + temp24*bm(i,6)+bm(i,7)*temph
C     
          phix = kc*phix*thk(i)*area(i)
          phiy = kc*phiy*thk(i)*area(i)
C
C Thermal nodal Force
C
 
          a = fourth *fourth * dheat(i)
 
          fphi(i,1) = a - (phix*(bm(i,1)+bm(i,3)) + phiy*(bm(i,5)+bm(i,7)))
          fphi(i,2) = a - (phix*(bm(i,2)-bm(i,3)) + phiy*(bm(i,6)-bm(i,7)))
          fphi(i,3) = a - (phix*(bm(i,3)-bm(i,1)) + phiy*(bm(i,7)-bm(i,5)))
          fphi(i,4) = a + (phix*(bm(i,2)+bm(i,3)) + phiy*(bm(i,6)+bm(i,7)))
 
        END DO
 
        DO ep=nplat+1,jlt 
 
          i=iplat(ep)
 
          kc = ( ca + cb*tel(i))*dtime
C
          n1 = ixc(2,i)
          n2 = ixc(3,i)
          n3 = ixc(4,i)
          n4 = ixc(5,i)
 
          temp1 = tempnc(n1)
          temp2 = tempnc(n2)
          temp3 = tempnc(n3)
          temp4 = tempnc(n4)
C 
C - flux : K gradT = B * T
C
          phix =  (bm(i,1)+bm(i,4))*temp1 + (bm(i,10)+bm(i,13))*temp2
     .         +  (bm(i,19)+bm(i,22))*temp3 + (bm(i,28)+bm(i,31))*temp2  
 
          phiy =  (bm(i,2)+bm(i,5))*temp1 + (bm(i,11)+bm(i,14))*temp2
     .         +  (bm(i,20)+bm(i,23))*temp3 + (bm(i,29)+bm(i,32))*temp2  
 
          phix = kc*phix*thk(i)*area(i)
          phiy = kc*phiy*thk(i)*area(i)    
C
C Thermal nodal Force
C          
          a = fourth *fourth * dheat(i)
 
          fphi(i,1) = a - (phix*(bm(i,1)+bm(i,4))   + phiy*(bm(i,2)+bm(i,5)))
          fphi(i,2) = a - (phix*(bm(i,10)+bm(i,13)) + phiy*(bm(i,11)+bm(i,14)))
          fphi(i,3) = a - (phix*(bm(i,19)+bm(i,22)) + phiy*(bm(i,20)+bm(i,23)))
          fphi(i,4) = a - (phix*(bm(i,28)+bm(i,31))  + phiy*(bm(i,29)+bm(i,32)))
 
        END DO
!----------- 
      RETURN
      END