cbavarnl.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    cbavarnl         ../engine/source/elements/shell/coqueba/cbavarnl.F
!||--- called by ------------------------------------------------------
!||    cbaforc3         ../engine/source/elements/shell/coqueba/cbaforc3.F
!||--- uses       -----------------------------------------------------
!||    element_mod      ../common_source/modules/elements/element_mod.F90
!||    nlocal_reg_mod   ../common_source/modules/nlocal_reg_mod.F
!||====================================================================
      SUBROUTINE cbavarnl(JFT      ,JLT      ,NG       ,IXC      ,NLOC_DMG ,
     .                    VARNL    ,NDDL     ,NC1      ,NC2      ,NC3      ,
     .                    NC4      ,NEL      )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------      
      USE nlocal_reg_mod
      use element_mod , only : nixc
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JFT,JLT,NG,IXC(NIXC,*),NDDL,NEL
      INTEGER, INTENT(INOUT) :: 
     .   nc1(*), nc2(*), nc3(*), nc4(*)
      my_real, INTENT(INOUT) ::
     .   varnl(nel,nddl)
      TYPE(nlocal_str_), TARGET :: NLOC_DMG
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,  K, 
     .        INOD(4), IPOS(4),L_NLOC
      my_real 
     .   vpg(2,4),pg1,pg,ksi,eta,sf1,sf2,sf3,sf4
       parameter(pg=.577350269189626)
       parameter(pg1=-.577350269189626)
      my_real, 
     .   DIMENSION(:), POINTER :: dnl 
C--------------------------
C     INITIALIZATION
C-------------------------
      DATA vpg/pg1,pg1,pg,pg1,pg,pg,pg1,pg/
C---------------------------------------------------------------------------------------------------------------
C --- Non-local variable varnl in Gauss point ng
C    
C --- Position of the Gauss point
       ksi = vpg(1,ng)
       eta = vpg(2,ng)
C --- Shape function value
       sf1 = (1-ksi)*(1-eta)
       sf2 = (1+ksi)*(1-eta)
       sf3 = (1+ksi)*(1+eta)
       sf4 = (1-ksi)*(1+eta)
C --- Length of the non-local vector       
       l_nloc = nloc_dmg%L_NLOC
       dnl  => nloc_dmg%DNL(1:l_nloc) ! DNL = non local variable increment
C --- Loop over 
       DO i=jft,jlt       
         nc1(i)  = ixc(2,i)
         nc2(i)  = ixc(3,i)
         nc3(i)  = ixc(4,i)
         nc4(i)  = ixc(5,i)
       ENDDO
       DO k = 1,nddl
#include "vectorize.inc"
         DO i=jft,jlt
           inod(1) = nloc_dmg%IDXI(nc1(i))
           inod(2) = nloc_dmg%IDXI(nc2(i))
           inod(3) = nloc_dmg%IDXI(nc3(i))
           inod(4) = nloc_dmg%IDXI(nc4(i)) 
           ipos(1) = nloc_dmg%POSI(inod(1)) 
           ipos(2) = nloc_dmg%POSI(inod(2)) 
           ipos(3) = nloc_dmg%POSI(inod(3)) 
           ipos(4) = nloc_dmg%POSI(inod(4)) 
           varnl(i,k) = zero
           varnl(i,k) = fourth*(sf1*dnl(ipos(1)+k-1) + sf2*dnl(ipos(2)+k-1) 
     .                       + sf3*dnl(ipos(3)+k-1) + sf4*dnl(ipos(4)+k-1))
         ENDDO
       ENDDO
C
      END