ccurv3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    ccurv3       ../engine/source/elements/shell/coque/ccurv3.F
!||--- called by ------------------------------------------------------
!||    cforc3       ../engine/source/elements/shell/coque/cforc3.F
!||    cforc3_crk   ../engine/source/elements/xfem/cforc3_crk.F
!||====================================================================
      SUBROUTINE ccurv3(JFT,JLT,VRL1,VRL2,VRL3,VRL4,
     1   PX1,PX2 ,PY1 ,PY2 ,AREA,
     2   RX1 ,RX2 ,RX3 ,RX4 ,RY1 ,RY2 ,RY3 ,RY4,
     3   E1X ,E1Y ,E1Z ,E2X ,E2Y ,E2Z ,E3X ,E3Y,
     4   E3Z ,KXX ,KYY ,KXY ,EXZ,EYZ,
     5   WXY ,ISMSTR)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JFT, JLT, ISMSTR
      my_real
     .     RX1(MVSIZ),  RX2(MVSIZ),  RX3(MVSIZ),  RX4(MVSIZ),
     .     RY1(MVSIZ),  RY2(MVSIZ),  RY3(MVSIZ),  RY4(MVSIZ),
     .     PX1(MVSIZ),  PX2(MVSIZ),  PY1(MVSIZ),  PY2(MVSIZ),
     .     e1x(mvsiz),  e1y(mvsiz),  e1z(mvsiz),  e2x(mvsiz),
     .     e2y(mvsiz),  e2z(mvsiz),  e3x(mvsiz),  e3y(mvsiz),
     .     e3z(mvsiz),
     .     vrl1(mvsiz,3), vrl2(mvsiz,3), vrl3(mvsiz,3), vrl4(mvsiz,3),
     .     kxx(mvsiz),  kyy(mvsiz),
     .     kxy(mvsiz),  area(mvsiz), exz(mvsiz),  eyz(mvsiz),wxy(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
      my_real
     .     RXAVTA,RX13TA,RX24TA,RY13TA,RYAVTA,RY24TA
C=======================================================================
      DO I=jft,jlt
      rx1(i)=e1x(i)*vrl1(i,1)+e1y(i)*vrl1(i,2)+e1z(i)*vrl1(i,3)
      rx2(i)=e1x(i)*vrl2(i,1)+e1y(i)*vrl2(i,2)+e1z(i)*vrl2(i,3)
      rx3(i)=e1x(i)*vrl3(i,1)+e1y(i)*vrl3(i,2)+e1z(i)*vrl3(i,3)
      rx4(i)=e1x(i)*vrl4(i,1)+e1y(i)*vrl4(i,2)+e1z(i)*vrl4(i,3)
      ry1(i)=e2x(i)*vrl1(i,1)+e2y(i)*vrl1(i,2)+e2z(i)*vrl1(i,3)
      ry2(i)=e2x(i)*vrl2(i,1)+e2y(i)*vrl2(i,2)+e2z(i)*vrl2(i,3)
      ry3(i)=e2x(i)*vrl3(i,1)+e2y(i)*vrl3(i,2)+e2z(i)*vrl3(i,3)
      ry4(i)=e2x(i)*vrl4(i,1)+e2y(i)*vrl4(i,2)+e2z(i)*vrl4(i,3)
      ENDDO
C
      DO i=jft,jlt
        rx13ta =rx1(i)-rx3(i)
        rxavta =rx1(i)+rx2(i)+rx3(i)+rx4(i)
        rx24ta =rx2(i)-rx4(i)
C
        kyy(i)=-py1(i)*rx13ta-py2(i)*rx24ta
        kxy(i)= px1(i)*rx13ta+px2(i)*rx24ta
C
        ry13ta = ry1(i)-ry3(i)
        ryavta = ry1(i)+ry2(i)+ry3(i)+ry4(i)
        ry24ta = ry2(i)-ry4(i)
C
        kxx(i)= px1(i)*ry13ta+px2(i)*ry24ta
        kxy(i)= py1(i)*ry13ta+py2(i)*ry24ta
     +       -kxy(i)
C
        exz(i)=exz(i)+ryavta*(.25*area(i))
        eyz(i)=eyz(i)-rxavta*(.25*area(i))
      ENDDO
C
C      
       IF (ismstr==10) THEN
        DO i=jft,jlt
        rx13ta =rx1(i)-rx3(i)
        rx24ta =rx2(i)-rx4(i)
C
        ry13ta = ry1(i)-ry3(i)
        ry24ta = ry2(i)-ry4(i)
C
         wxy(i) = py1(i)*ry13ta+py2(i)*ry24ta + 
     +            px1(i)*rx13ta+px2(i)*rx24ta
        ENDDO 
       ENDIF
c-----------
      RETURN
      END