cdkdefo3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    cdkdefo3   ../engine/source/elements/sh3n/coquedk/cdkdefo3.F
!||--- called by ------------------------------------------------------
!||    cdkforc3   ../engine/source/elements/sh3n/coquedk/cdkforc3.F
!||====================================================================
      SUBROUTINE cdkdefo3(JFT,JLT,VLX,VLY,PX2,PY2,PX3,PY3,
     1                    EXX,EYY,EXY,EXZ,EYZ,DT1,EPSDOT,NFT,
     2                    ISTRAIN,GSTR,VDEF,NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "scr14_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
C  ds007  18/2/00   +1
      INTEGER JFT, JLT,NFT,ISTRAIN,NEL
C     REAL
      my_real
     .   px2(*), py2(*), px3(*), py3(*), 
     .   vlx(mvsiz,2),vly(mvsiz,2),exx(*),eyy(*),exy(*),exz(*),eyz(*),
     .   gstr(nel,8),epsdot(6,*),vdef(mvsiz,8),dt1
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, J
C     REAL
C      my_real
C     .     DT1V4, TMP1, TMP2, TMP3, 
C     .     DT1V4B,TMP11,TMP22,VX10,VX20,VX30
C-----------------------------------------------
C
      DO i=jft,jlt
       vdef(i,1)=px2(i)*vlx(i,1)+px3(i)*vlx(i,2)
       vdef(i,2)=py2(i)*vly(i,1)+py3(i)*vly(i,2)
C
       vdef(i,3)=px2(i)*vly(i,1)+px3(i)*vly(i,2)+
     .        py2(i)*vlx(i,1)+py3(i)*vlx(i,2)
       exz(i)=zero
       eyz(i)=zero
      ENDDO
C
      IF(iepsdot/=0)THEN
       DO i=jft,jlt
        j = i + nft
        epsdot(1,j)=vdef(i,1)
        epsdot(2,j)=vdef(i,2)
        epsdot(3,j)=vdef(i,3)
       ENDDO
      ENDIF
C
      DO i=jft,jlt
       exx(i)=vdef(i,1)*dt1
       eyy(i)=vdef(i,2)*dt1
       exy(i)=vdef(i,3)*dt1
      ENDDO
C
      IF(istrain/=0)THEN
       DO i=jft,jlt
        gstr(i,1)=gstr(i,1)+exx(i)
        gstr(i,2)=gstr(i,2)+eyy(i)
        gstr(i,3)=gstr(i,3)+exy(i)
       ENDDO
      ENDIF
C
      RETURN
      END
!||====================================================================
!||    cdkcurv3   ../engine/source/elements/sh3n/coquedk/cdkdefo3.F
!||--- called by ------------------------------------------------------
!||    cdkforc3   ../engine/source/elements/sh3n/coquedk/cdkforc3.F
!||====================================================================
      SUBROUTINE cdkcurv3(JFT,JLT,BZ1,BZ2,BZ3,BRX1,BRX2,BRX3,BRY1,
     1                   BRY2,BRY3,VLZ,RLX,RLY,KXX, KYY, KXY)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JFT, JLT
      my_real
     .    BZ1(MVSIZ,2),BZ2(MVSIZ,2),BZ3(MVSIZ,2), BRX1(MVSIZ,3),
     .    brx2(mvsiz,3),brx3(mvsiz,3),bry1(mvsiz,3),bry2(mvsiz,3),bry3(mvsiz,3),
     .    vlz(mvsiz,2),rlx(mvsiz,3),rly(mvsiz,3),kxx(*),kyy(*),kxy(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
C-----------------------------------------------
C
      DO i=jft,jlt
       kxx(i)=bz1(i,1)*vlz(i,1)+bz1(i,2)*vlz(i,2)+
     .        brx1(i,1)*rlx(i,1)+brx1(i,2)*rlx(i,2)+brx1(i,3)*rlx(i,3)+
     .        bry1(i,1)*rly(i,1)+bry1(i,2)*rly(i,2)+bry1(i,3)*rly(i,3)
C
       kyy(i)=bz2(i,1)*vlz(i,1)+bz2(i,2)*vlz(i,2)+
     .        brx2(i,1)*rlx(i,1)+brx2(i,2)*rlx(i,2)+brx2(i,3)*rlx(i,3)+
     .        bry2(i,1)*rly(i,1)+bry2(i,2)*rly(i,2)+bry2(i,3)*rly(i,3)
C
       kxy(i)=bz3(i,1)*vlz(i,1)+bz3(i,2)*vlz(i,2)+
     .        brx3(i,1)*rlx(i,1)+brx3(i,2)*rlx(i,2)+brx3(i,3)*rlx(i,3)+
     .        bry3(i,1)*rly(i,1)+bry3(i,2)*rly(i,2)+bry3(i,3)*rly(i,3)
      ENDDO
C
      RETURN
      END