cdlen3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    cdlen3       ../engine/source/elements/shell/coque/cdlen3.F
!||--- called by ------------------------------------------------------
!||    cforc3       ../engine/source/elements/shell/coque/cforc3.F
!||    cforc3_crk   ../engine/source/elements/xfem/cforc3_crk.F
!||====================================================================
      SUBROUTINE cdlen3(JFT,JLT ,PM  ,OFF,AREA, 
     2                  X2 ,X3  ,X4  ,Y2 ,Y3  ,  
     3                  Y4 ,ALDT,MAT,GEO ,PID ,
     4                  IHBE)
C  _clean     3                  Y4 ,ALDT,MAT,GEO ,PID)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER MAT(MVSIZ),JFT, JLT,PID(*),
     .                  IHBE
C     REAL
      my_real
     .   pm(npropm,*), off(*), geo(npropg,*)
      my_real
     .   x2(mvsiz), x3(mvsiz), x4(mvsiz),
     .     y2(mvsiz), y3(mvsiz), y4(mvsiz),
     .     area(mvsiz), aldt(mvsiz)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER  I, MX,IPID
C     REAL
      my_real
     .     al1(mvsiz), al2(mvsiz), al3(mvsiz),
     .     al4(mvsiz), al5(mvsiz), al6(mvsiz),
     .     almin(mvsiz),
     .     alquad, dtdyn, h1, h2, dthour
C-----------------------------------------------
      DO i=jft,jlt
        al1(i)= x2(i)       * x2(i)       + y2(i)       * y2(i)
        al2(i)=(x3(i)-x2(i))*(x3(i)-x2(i))+(y3(i)-y2(i))*(y3(i)-y2(i))
        al6(i)= x3(i)       * x3(i)       + y3(i)       * y3(i)
        al3(i)=(x4(i)-x3(i))*(x4(i)-x3(i))+(y4(i)-y3(i))*(y4(i)-y3(i))
        al4(i)= x4(i)       * x4(i)       + y4(i)       * y4(i)
        al5(i)=(x4(i)-x2(i))*(x4(i)-x2(i))+(y4(i)-y2(i))*(y4(i)-y2(i))
      ENDDO
C
      DO i=jft,jlt
        almin(i)= min(al1(i),al2(i),al4(i))
        alquad  = min(al3(i),al5(i),al6(i))
        IF(al3(i)/=zero) almin(i)= min(almin(i),alquad)
        dtdyn= area(i)*area(i) / max(al5(i),al6(i),em20)
        aldt(i)= max( dtdyn , almin(i) )
      ENDDO
C---------------------------------------------------------
C     DT COMPATIBLE AVEC FONCTIONS DE FORMES SUR HOURGLASS
C---------------------------------------------------------
        IF(ihbe/=0)THEN
            mx = mat(jft)
            DO  i=jft,jlt
                IF(invstr>=35)THEN
                    ipid=pid(i)
                    h1 =geo(13,ipid)
                    h2 =geo(14,ipid)
                ELSE
                    h1 =pm( 5,mx)
                    h2 =pm( 6,mx)
                ENDIF
            dthour = half * (almin(i)+aldt(i)) / max(h1,h2)
C Bug HP            ALDT(I)  = MIN(ALDT(I),DTHOUR)
            IF (dthour<aldt(i)) aldt(i)=dthour
          ENDDO
        ELSE
          mx = mat(jft)
          DO  i=jft,jlt
          IF(invstr>=35)THEN
           ipid=pid(i)
           h1 =geo(13,ipid)
           h2 =geo(14,ipid)
          ELSE
           h1 =pm( 5,mx)
           h2 =pm( 6,mx)
          ENDIF
            dthour = half * (almin(i)+aldt(i)) / max(h1,h2)
            aldt(i)  = min(aldt(i),dthour)
          ENDDO
        ENDIF
C---------------------------------------------------------
      DO i=jft,jlt
        aldt(i)= sqrt( aldt(i) )
      ENDDO
C
      RETURN
      END