check_nan_acc.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
 
!||====================================================================
!||    check_nan_acc      ../engine/source/output/outfile/check_nan_acc.F
!||--- called by ------------------------------------------------------
!||    resol              ../engine/source/engine/resol.F
!||--- calls      -----------------------------------------------------
!||    my_isnan           ../engine/source/system/my_isnan.f
!||    spmd_barrier       ../engine/source/mpi/spmd_mod.F90
!||--- uses       -----------------------------------------------------
!||    nodal_arrays_mod   ../common_source/modules/nodal_arrays.F90
!||    spmd_mod           ../engine/source/mpi/spmd_mod.F90
!||====================================================================
      SUBROUTINE check_nan_acc(NCYCLE,NODES)
      USE spmd_mod, ONLY : spmd_barrier
      USE nodal_arrays_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include "com04_c.inc"
#include "scr07_c.inc"
#include "task_c.inc"
#include "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C----------------------------------------------
!       REAL ou REAL*8
        INTEGER, INTENT(IN) :: NCYCLE
        TYPE(nodal_arrays_), INTENT(IN) :: NODES
!       -*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-**-*-*-*-*-*-*-*-*-*-*-*-*
!       NCYCLE : integer, current cycle
!       A : my_real ; dimension=NUMNOD
!           acceleration
!       AR : my_real ; dimension=numnod
!           R acceleration
!       -*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-**-*-*-*-*-*-*-*-*-*-*-*-*
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
        LOGICAL :: BOOL_NAN,MY_ISNAN
        INTEGER :: N
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
!$COMMENT
!       CHECK_NAN_ACC description
!       check if a NaN appears in A/AR arrays
!       
!       CHECK_NAN_ACC organization :
!       - check if a NaN appears in A/AR arrays 
!       - if a NaN is present, print the ID node, the processor and
!         the cycle and then stop the run with MSTOP=1
!$ENDCOMMENT
 
        bool_nan = .false.
        DO n=1,numnod
                IF(my_isnan(nodes%A(1,n)).OR.my_isnan(nodes%A(2,n)).OR.my_isnan(nodes%A(3,n))) THEN
                        WRITE(iout,1000) ispmd,ncycle
                        WRITE(iout,1001) n,nodes%ITAB(n)
                        WRITE(iout,1002) nodes%A(1,n),nodes%A(2,n),nodes%A(3,n)
 
                        WRITE(istdo,1000) ispmd,ncycle
                        WRITE(istdo,1001) n,nodes%ITAB(n)
                        WRITE(istdo,1002) nodes%A(1,n),nodes%A(2,n),nodes%A(3,n)
 
 
                        bool_nan = .true.
                ENDIF
 
                IF(my_isnan(nodes%AR(1,n)).OR.my_isnan(nodes%AR(2,n)).OR.my_isnan(nodes%AR(3,n))) THEN
                        WRITE(iout,1003) ispmd,ncycle
                        WRITE(iout,1001) n,nodes%ITAB(n)
                        WRITE(iout,1004) nodes%AR(1,n),nodes%AR(2,n),nodes%AR(3,n)
 
                        WRITE(istdo,1003) ispmd,ncycle
                        WRITE(istdo,1001) n,nodes%ITAB(n)
                        WRITE(istdo,1004) nodes%AR(1,n),nodes%AR(2,n),nodes%AR(3,n)
 
                        bool_nan = .true.
                ENDIF
        ENDDO
 
        CALL spmd_barrier()
 
        IF(bool_nan) THEN
                WRITE(iout,1005)
                WRITE(istdo,1005)
                mstop=1
!                CALL FLUSH(6)
!                CALL ARRET(2)
        ENDIF
 
 1000 FORMAT(3x,'NaN detected on A array on processor ID',i10,' at cycle',i10)
 1001 FORMAT(3x,'Local node ID: ',i10,' Global node ID:',i10 )
 1002 FORMAT(3x,'A values: ',1pe10.3,1pe10.3,1pe10.3)
 1003 FORMAT(3x,'NaN detected on AR array on processor ID',i10,' at cycle',i10)
 1004 FORMAT(3x,'AR values: ',1pe10.3,1pe10.3,1pe10.3)
 1005 FORMAT(/,3x,'********************* NaN ********************* ',/,
     .         3x,'******** I"m going to kill the run now ******** ',/,
     .         3x,'********************* NaN ********************* ',/)
 
 
 
        RETURN
        END SUBROUTINE check_nan_acc