clskew.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    clskew3    ../starter/source/elements/shell/coque/clskew.F
!||--- called by ------------------------------------------------------
!||    cdkevec3   ../starter/source/elements/sh3n/coquedk/cdkevec3.F
!||    cneveci    ../starter/source/elements/shell/coqueba/cneveci.F
!||    spcoor3    ../starter/source/elements/solid/sconnect/spcoor3.F
!||    xyzloc3n   ../starter/source/elements/xfem/lslocal.F
!||====================================================================
      SUBROUTINE clskew3(JFT,JLT,IREP,
     .           RX, RY, RZ,SX, SY, SZ, 
     .           E1X, E2X, E3X, E1Y, E2Y, E3Y, E1Z, E2Z, E3Z, DET)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JFT,JLT,IREP
      my_real
     .   rx(mvsiz) , ry(mvsiz) , rz(mvsiz), 
     .   sx(mvsiz) , sy(mvsiz) , sz(mvsiz),
     .   e1x(mvsiz), e1y(mvsiz), e1z(mvsiz),
     .   e2x(mvsiz), e2y(mvsiz), e2z(mvsiz),
     .   e3x(mvsiz), e3y(mvsiz), e3z(mvsiz), det(mvsiz)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
      MY_REAL C1,C2,CC
C=======================================================================
C IREP=0 ->QEPH IREP=1 ->Q4, IREP=2-> E1=R(ISHFRAM=1)
C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
      DO i=jft,jlt
C---------E3------------
       e3x(i) = ry(i) * sz(i) - rz(i) * sy(i) 
       e3y(i) = rz(i) * sx(i) - rx(i) * sz(i) 
       e3z(i) = rx(i) * sy(i) - ry(i) * sx(i) 
       det(i) = sqrt(e3x(i)*e3x(i) + e3y(i)*e3y(i) + e3z(i)*e3z(i))
       det(i) = max(em20,det(i))
       cc = one / det(i)
       e3x(i) = e3x(i) * cc 
       e3y(i) = e3y(i) * cc 
       e3z(i) = e3z(i) * cc 
      ENDDO 
C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
      IF (irep==2) THEN
       DO i=jft,jlt
        e1x(i) = rx(i)
        e1y(i) = ry(i)
        e1z(i) = rz(i)
       ENDDO 
      ELSEIF (irep==1) THEN
       DO i=jft,jlt
        c2 = sqrt(sx(i)*sx(i) + sy(i)*sy(i) + sz(i)*sz(i))
        e1x(i) = rx(i)*c2+(sy(i)*e3z(i)-sz(i)*e3y(i))
        e1y(i) = ry(i)*c2+(sz(i)*e3x(i)-sx(i)*e3z(i))
        e1z(i) = rz(i)*c2+(sx(i)*e3y(i)-sy(i)*e3x(i))
       ENDDO 
      ELSE
       DO i=jft,jlt
        c1 = sqrt(rx(i)*rx(i) + ry(i)*ry(i) + rz(i)*rz(i))
        c2 = sqrt(sx(i)*sx(i) + sy(i)*sy(i) + sz(i)*sz(i))
        e1x(i) = rx(i)*c2+(sy(i)*e3z(i)-sz(i)*e3y(i))*c1
        e1y(i) = ry(i)*c2+(sz(i)*e3x(i)-sx(i)*e3z(i))*c1
        e1z(i) = rz(i)*c2+(sx(i)*e3y(i)-sy(i)*e3x(i))*c1
       ENDDO 
      ENDIF 
C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
       DO i=jft,jlt
        c1 = sqrt(e1x(i)*e1x(i) + e1y(i)*e1y(i) + e1z(i)*e1z(i))
        IF (c1/=zero) c1 = one / c1
        e1x(i) = e1x(i)*c1
        e1y(i) = e1y(i)*c1
        e1z(i) = e1z(i)*c1
        e2x(i) = e3y(i) * e1z(i) - e3z(i) * e1y(i)
        e2y(i) = e3z(i) * e1x(i) - e3x(i) * e1z(i)
        e2z(i) = e3x(i) * e1y(i) - e3y(i) * e1x(i)
       ENDDO 
c-----------
      RETURN
      END