cmumps_iXamax.F

Go to the documentation of this file.

C
C  This file is part of MUMPS 5.5.1, released
C  on Tue Jul 12 13:17:24 UTC 2022
C
C
C  Copyright 1991-2022 CERFACS, CNRS, ENS Lyon, INP Toulouse, Inria,
C  Mumps Technologies, University of Bordeaux.
C
C  This version of MUMPS is provided to you free of charge. It is
C  released under the CeCILL-C license 
C  (see doc/CeCILL-C_V1-en.txt, doc/CeCILL-C_V1-fr.txt, and
C  https://cecill.info/licences/Licence_CeCILL-C_V1-en.html)
C
      INTEGER FUNCTION cmumps_ixamax(N,X,INCX,GRAIN)
!$    USE OMP_LIB
      IMPLICIT NONE
      COMPLEX, intent(in) :: x(*)
      INTEGER, intent(in) :: incx,n
      INTEGER, intent(in) :: grain
      REAL absmax
      INTEGER :: i
      INTEGER(8) :: ix
!$    INTEGER :: NOMP, CHUNK
!$    INTEGER :: IMAX
!$    REAL    :: XMAX, VALABS
!$    REAL, PARAMETER :: RZERO = 0.0E0
!$    NOMP = OMP_GET_MAX_THREADS()
      cmumps_ixamax = 0
      IF ( n.LT.1 ) RETURN
      cmumps_ixamax = 1
      IF ( n.EQ.1 .OR. incx.LE.0 ) RETURN
!$    IF (NOMP.GT.1 .AND. N.GE.GRAIN*2) THEN
!$    IF ( INCX.EQ.1 ) THEN
!$      CHUNK = max(GRAIN,(N+NOMP-1)/NOMP)
!$      ABSMAX = RZERO
!$OMP PARALLEL PRIVATE(I, VALABS, XMAX, IMAX)
!$OMP& FIRSTPRIVATE(N, CHUNK)
!$      XMAX = RZERO
!$OMP DO SCHEDULE(static, CHUNK)
!$      DO I = 1, N
!$        VALABS = abs(X(I))
!$        IF ( VALABS .GT. XMAX ) THEN
!$          XMAX = VALABS
!$          IMAX = I
!$        ENDIF
!$      ENDDO
!$OMP END DO
!$      IF (XMAX .GT. RZERO) THEN
!$OMP CRITICAL
!$        IF (XMAX .GT. ABSMAX) THEN
!$          CMUMPS_IXAMAX = IMAX
!$          ABSMAX = XMAX
!$        ENDIF
!$OMP END CRITICAL
!$      ENDIF
!$OMP END PARALLEL
!$    ELSE
!$      CHUNK = max(GRAIN,(N+NOMP-1)/NOMP)
!$      ABSMAX = RZERO
!$OMP PARALLEL PRIVATE(I, VALABS, XMAX, IMAX, IX)
!$OMP& FIRSTPRIVATE(N, CHUNK, INCX)
!$      XMAX = RZERO
!$OMP DO SCHEDULE(static, CHUNK)
!$      DO I = 1, N
!$        IX = 1 + int((I-1),8)*int(INCX,8)
!$        VALABS = abs(X(IX))
!$        IF ( VALABS .GT. XMAX ) THEN
!$          XMAX = VALABS
!$          imax = i
!$        ENDIF
!$      ENDDO
!$OMP END DO
!$      IF (XMAX .GT. RZERO) THEN
!$OMP CRITICAL
!$        IF (XMAX .GT. ABSMAX) THEN
!$          CMUMPS_IXAMAX = IMAX
!$          ABSMAX = XMAX
!$        ENDIF
!$OMP END CRITICAL
!$      ENDIF
!$OMP END PARALLEL
!$    ENDIF
!$    ELSE
      IF ( incx.EQ.1 ) THEN
        absmax = abs(x(1))
        DO i = 2, n
          IF ( abs(x(i)) .LE. absmax ) cycle
          cmumps_ixamax = i
          absmax = abs(x(i))
        ENDDO
      ELSE
        ix = 1
        absmax = abs(x(1))
        ix = ix + incx
        DO i = 2, n
           IF ( abs(x(ix)).LE.absmax ) GOTO 5
           cmumps_ixamax = i
           absmax = abs(x(ix))
   5       ix = ix + incx
        ENDDO
      ENDIF
!$    ENDIF
      RETURN
      END FUNCTION cmumps_ixamax