cndint.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    cndint        ../engine/source/model/remesh/cndint.F
!||--- called by ------------------------------------------------------
!||    resol         ../engine/source/engine/resol.F
!||--- calls      -----------------------------------------------------
!||    my_barrier    ../engine/source/system/machine.F
!||--- uses       -----------------------------------------------------
!||    element_mod   ../common_source/modules/elements/element_mod.F90
!||    remesh_mod    ../engine/share/modules/remesh_mod.F
!||====================================================================
      SUBROUTINE cndint(IXC ,IPARTC ,IXTG ,IPARTTG,IPART,
     2              ITASK   ,A      ,V    ,AR     ,VR   , 
     3              MS      ,IN     ,NODFT,NODLT  ,X    ,
     4              SH4TREE ,SH3TREE,ITAB ,STIFN ,STIFR ,
     5              MSCND   ,INCND  )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE remesh_mod
      use element_mod , only : nixc,nixtg
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "scr17_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "remesh_c.inc"
#include      "scr02_c.inc"
#include      "scr18_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IXC(NIXC,*), IPARTC(*), IXTG(NIXTG,*), IPARTTG(*),
     .        IPART(LIPART1,*), ITASK, NODFT, NODLT,SH4TREE(KSH4TREE,*),
     .        SH3TREE(KSH3TREE,*), ITAB(*)
       my_real
     .        a(3,*),v(3,*),
     .        ar(3,*),vr(3,*), ms(*), in(*), x(3,*),
     .        stifn(*), stifr(*), mscnd(*), incnd(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER SH4FT, SH4LT, SH3FT, SH3LT
      INTEGER N, NN, LEVEL, IP, NLEV, LL, IERR
      INTEGER SON,M1,M2,M3,M4,MC,N1,N2,N3,N4,J,NA,NB
      my_real
     .        vv, ax(3,numnod), arx(3,numnod), fac,
     .        dt2p, mas, iner, dtn
C-----------------------------------------------
C
C     allocation tag
      tagnod(nodft:nodlt)=0
C
C     Retrieve forces on nodes (static nodes would be enough).
      ax(1:3,nodft:nodlt)=acnd(1:3,nodft:nodlt)
      arx(1:3,nodft:nodlt)=arcnd(1:3,nodft:nodlt)
C
      CALL my_barrier
C
      ll=psh4upl(1)
      sh4ft = 1+itask*ll/ nthread
      sh4lt = (itask+1)*ll/nthread
 
      DO nn=sh4ft,sh4lt
        n    =lsh4upl(nn)
C
        n1=ixc(2,n)
        n2=ixc(3,n)
        n3=ixc(4,n)
        n4=ixc(5,n)
C
        IF(tagnod(n1)==0)THEN
          tagnod(n1)=1
          DO j=1,3
            acnd(j,n1)  =a(j,n1)
          END DO
          DO j=1,3
            arcnd(j,n1) =ar(j,n1)
          END DO
        END IF
C
        IF(tagnod(n2)==0)THEN
          tagnod(n2)=1
          DO j=1,3
            acnd(j,n2)  =a(j,n2)
          END DO
          DO j=1,3
            arcnd(j,n2) =ar(j,n2)
          END DO
        END IF
C
        IF(tagnod(n3)==0)THEN
          tagnod(n3)=1
          DO j=1,3
            acnd(j,n3)  =a(j,n3)
          END DO
          DO j=1,3
            arcnd(j,n3) =ar(j,n3)
          END DO
        END IF
C
        IF(tagnod(n4)==0)THEN
          tagnod(n4)=1
          DO j=1,3
            acnd(j,n4)  =a(j,n4)
          END DO
          DO j=1,3
            arcnd(j,n4) =ar(j,n4)
          END DO
        END IF
C
      END DO
C
      ll=psh3upl(1)
      sh3ft = 1+itask*ll/ nthread
      sh3lt = (itask+1)*ll/nthread
 
      DO nn=sh3ft,sh3lt
        n    =lsh3upl(nn)
C
        n1=ixtg(2,n)
        n2=ixtg(3,n)
        n3=ixtg(4,n)
C
        IF(tagnod(n1)==0)THEN
          tagnod(n1)=1
          DO j=1,3
            acnd(j,n1)  =a(j,n1)
          END DO
          DO j=1,3
            arcnd(j,n1) =ar(j,n1)
          END DO
        END IF
C
        IF(tagnod(n2)==0)THEN
          tagnod(n2)=1
          DO j=1,3
            acnd(j,n2)  =a(j,n2)
          END DO
          DO j=1,3
            arcnd(j,n2) =ar(j,n2)
          END DO
        END IF
C
        IF(tagnod(n3)==0)THEN
          tagnod(n3)=1
          DO j=1,3
            acnd(j,n3)  =a(j,n3)
          END DO
          DO j=1,3
            arcnd(j,n3) =ar(j,n3)
          END DO
        END IF
C
      END DO
C
      CALL my_barrier
C
      tagnod(nodft:nodlt)=0
C
      CALL my_barrier
C
C-------
C     interpolation of v, a
      DO level=0,levelmax-1
 
        ll=psh4upl(level+1)-psh4upl(level)
        sh4ft = psh4upl(level)+ 1+itask*ll/ nthread
        sh4lt = psh4upl(level)+ (itask+1)*ll/nthread
 
        DO nn=sh4ft,sh4lt
          n    =lsh4upl(nn)
C
          n1=ixc(2,n)
          n2=ixc(3,n)
          n3=ixc(4,n)
          n4=ixc(5,n)
C
          son=sh4tree(2,n)
C
          mc=ixc(3,son+3)
 
          IF(tagnod(mc)==0)THEN
 
             tagnod(mc)=1
             DO j=1,3
              vv = 
     .           fourth*(acnd(j,n1)+acnd(j,n2)+acnd(j,n3)+acnd(j,n4))
              acnd(j,mc) =vv
            END DO
 
            DO j=1,3
              vv = 
     .           fourth*(arcnd(j,n1)+arcnd(j,n2)+arcnd(j,n3)+arcnd(j,n4))
              arcnd(j,mc)=vv
            END DO
 
          END IF
C
          m1=ixc(3,son  )
          m2=ixc(4,son+1)
          m3=ixc(5,son+2)
          m4=ixc(2,son+3)
 
          IF(tagnod(m1)==0)THEN
             tagnod(m1)=1
             na=min(n1,n2)
             nb=max(n1,n2)
 
             DO j=1,3
              vv     = half*(acnd(j,na)+acnd(j,nb))
              acnd(j,m1) =vv
             END DO
 
            DO j=1,3
              vv     = half*(arcnd(j,na)+arcnd(j,nb))
              arcnd(j,m1)=vv
            END DO
 
          END IF
 
          IF(tagnod(m2)==0)THEN
             tagnod(m2)=1
             na=min(n2,n3)
             nb=max(n2,n3)
 
             DO j=1,3
              vv     = half*(acnd(j,na)+acnd(j,nb))
              acnd(j,m2) =vv
            END DO
 
            DO j=1,3
              vv     = half*(arcnd(j,na)+arcnd(j,nb))
              arcnd(j,m2)=vv
            END DO
 
          END IF
 
          IF(tagnod(m3)==0)THEN
             tagnod(m3)=1
             na=min(n3,n4)
             nb=max(n3,n4)
 
             DO j=1,3
              vv     = half*(acnd(j,na)+acnd(j,nb))
              acnd(j,m3) =vv
            END DO
 
            DO j=1,3
              vv     = half*(arcnd(j,na)+arcnd(j,nb))
              arcnd(j,m3)=vv
            END DO
 
          END IF
 
          IF(tagnod(m4)==0)THEN
             tagnod(m4)=1
             na=min(n4,n1)
             nb=max(n4,n1)
 
             DO j=1,3
              vv     = half*(acnd(j,na)+acnd(j,nb))
              acnd(j,m4) =vv
            END DO
 
            DO j=1,3
              vv     = half*(arcnd(j,na)+arcnd(j,nb))
              arcnd(j,m4)=vv
            END DO
 
          END IF
 
        END DO
C
        ll=psh3upl(level+1)-psh3upl(level)
        sh3ft = psh3upl(level)+ 1+itask*ll/ nthread
        sh3lt = psh3upl(level)+ (itask+1)*ll/nthread
 
        DO nn=sh3ft,sh3lt
          n    =lsh3upl(nn)
C
          n1=ixtg(2,n)
          n2=ixtg(3,n)
          n3=ixtg(4,n)
C
          son=sh3tree(2,n)
C
          m1=ixtg(4,son+3)
          m2=ixtg(2,son+3)
          m3=ixtg(3,son+3)
 
          IF(tagnod(m1)==0)THEN
            tagnod(m1)=1
            na=min(n1,n2)
            nb=max(n1,n2)
 
             DO j=1,3
              vv     = half*(acnd(j,na)+acnd(j,nb))
              acnd(j,m1) =vv
            END DO
            DO j=1,3
              vv     = half*(arcnd(j,na)+arcnd(j,nb))
              arcnd(j,m1)=vv
            END DO
 
          END IF
 
          IF(tagnod(m2)==0)THEN
            tagnod(m2)=1
            na=min(n2,n3)
            nb=max(n2,n3)
             DO j=1,3
              vv     = half*(acnd(j,na)+acnd(j,nb))
              acnd(j,m2) =vv
            END DO
            DO j=1,3
              vv     = half*(arcnd(j,na)+arcnd(j,nb))
              arcnd(j,m2)=vv
            END DO
 
          END IF
 
          IF(tagnod(m3)==0)THEN
            tagnod(m3)=1
            na=min(n3,n1)
            nb=max(n3,n1)
             DO j=1,3
              vv     = half*(acnd(j,na)+acnd(j,nb))
              acnd(j,m3) =vv
            END DO
            DO j=1,3
              vv     = half*(arcnd(j,na)+arcnd(j,nb))
              arcnd(j,m3)=vv
            END DO
 
          END IF
 
        END DO
C
        CALL my_barrier
C
C-------
      END DO
C
C-------
      IF(nodadt /= 0.OR.i7kglo/=0.AND.(idtmin(11)==3.OR.idtmin(11)==8))THEN
        dt2p = dtmin1(11)/dtfac1(11)
        DO n=nodft,nodlt
          IF(tagnod(n)/=0)THEN
            mas     = half * stifn(n) * dt2p * dt2p * onep00001
            mscnd(n)=max(mscnd(n),mas)
          END IF
        END DO
      END IF
      IF(nodadt /= 0.AND.(idtmin(11)==3.OR.idtmin(11)==8))THEN
        dt2p = dtmin1(11)/dtfac1(11)
        DO n=nodft,nodlt
          IF(tagnod(n)/=0)THEN
            iner = half * stifr(n) * dt2p * dt2p * onep00001
            incnd(n)=max(incnd(n),iner)
          END IF
        END DO
      END IF
 
c for debug
c      DT2P=DT2*ZEP999
c      DO N=NODFT,NODLT
c        IF(TAGNOD(N)/=0)THEN
c          DTN     = DTFAC1(11)*SQRT(2. * MSCND(N) / STIFN(N))
c          IF(DTN < DT2P)THEN
c#include "lockon.inc"
c            WRITE(IOUT,*)
c     .' **WARNING : TIME STEP LESS OR EQUAL DT2 FOR CONDENSED NODE N=',
c     .              ITAB(N),DT2,DTN
c            WRITE(ISTDO,*)
c     .' **WARNING : TIME STEP LESS OR EQUAL DT2 FOR CONDENSED NODE N=',
c     .              ITAB(N),DT2,DTN
c#include "lockoff.inc"
c          END IF
c          DTN     = DTFAC1(11)*SQRT(2. * INCND(N) / STIFR(N))
c          IF(DTN < DT2P)THEN
c#include "lockon.inc"
c            WRITE(IOUT,*)
c     .' **WARNING : TIME STEP LESS OR EQUAL DT2 FOR CONDENSED NODE N=',
c     .              ITAB(N),DT2,DTN
c            WRITE(ISTDO,*)
c     .' **WARNING : TIME STEP LESS OR EQUAL DT2 FOR CONDENSED NODE N=',
c     .              ITAB(N),DT2,DTN
c#include "lockoff.inc"
c          END IF
c        END IF
c      END DO
C
C-------
      DO n=nodft,nodlt
        IF(tagnod(n)/=0)THEN
 
          fac=one/max(mscnd(n),em20)
          a(1,n) = ax(1,n)*fac+acnd(1,n)
          a(2,n) = ax(2,n)*fac+acnd(2,n)
          a(3,n) = ax(3,n)*fac+acnd(3,n)
 
          fac=one/max(incnd(n),em20)
          ar(1,n) = arx(1,n)*fac+arcnd(1,n)
          ar(2,n) = arx(2,n)*fac+arcnd(2,n)
          ar(3,n) = arx(3,n)*fac+arcnd(3,n)
 
        END IF
      END DO
  
      RETURN
      END