connectivity.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    build_connectivity     ../engine/source/multifluid/connectivity.F
!||--- called by ------------------------------------------------------
!||    alemain                ../engine/source/ale/alemain.F
!||--- calls      -----------------------------------------------------
!||    arret                  ../engine/source/system/arret.F
!||--- uses       -----------------------------------------------------
!||    ale_connectivity_mod   ../common_source/modules/ale/ale_connectivity_mod.F
!||    multi_fvm_mod          ../common_source/modules/ale/multi_fvm_mod.F90
!||====================================================================
      SUBROUTINE build_connectivity(ITASK, MULTI_FVM, ALE_CONNECTIVITY, IPARG)
C-----------------------------------------------
C     D e s c r i p t i o n
C-----------------------------------------------
C     Builds array KVOIS that contains the number kface2 of
C     the face by which an element J is a neighbor of an 
C     element I of tab IVOIS.
C     If I is an element and KFACE a face number, if J the neighbor
C     of I by face KFACE, that is to say J = IVOIS (KFACE, I)
C     then, KFACE2 is such that I = IVOIS (KFACE2, J)
C-----------------------------------------------
C     M o d u l e s
C-----------------------------------------------
      USE multi_fvm_mod
      USE ale_connectivity_mod
C-----------------------------------------------
C     I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
! NGROUP
#include      "com01_c.inc"
! NUMELQ, NUMELS, NUMELTG
#include      "com04_c.inc"
! NTHREAD
#include      "task_c.inc"
! NPARG
#include      "param_c.inc"
C-----------------------------------------------
C     D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE(multi_fvm_struct), INTENT(INOUT) :: MULTI_FVM
      INTEGER, INTENT(IN) :: ITASK
      INTEGER, INTENT(IN) :: IPARG(NPARG, *)
      TYPE(t_ale_connectivity), INTENT(IN) :: ALE_CONNECTIVITY
C-----------------------------------------------
C     L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: NB_FACE, KFACE, KFACE2, II, I, J, MATLAW
      INTEGER :: ITY, NFT, NEL, NG, NUMEL_SPMD
      LOGICAL :: IDBG 
      INTEGER :: IAD, IAD2, LGTH, LGTH2
      nb_face = 0
      numel_spmd = 0
 
      DO ng = itask + 1, ngroup, nthread
         matlaw = iparg(1, ng)
         IF (matlaw == 151) THEN
            nel = iparg(2, ng)
            nft = iparg(3, ng)
            ity = iparg(5, ng)
            SELECT CASE (multi_fvm%SYM)
            CASE (0)
               nb_face = 6
               numel_spmd = numels
            CASE (1, 2)
               IF (ity == 2) THEN
C     QUADS
                  nb_face = 4
                  numel_spmd = numelq
               ELSEIF (ity == 7) THEN
C     TRIANGLES
                  nb_face = 3
                  numel_spmd = numeltg
               ENDIF
            CASE DEFAULT
               CALL arret(2)
            END SELECT                  
            DO ii = 1, nel
               i = ii + nft
               iad = ale_connectivity%ee_connect%iad_connect(i)
               lgth = ale_connectivity%ee_connect%iad_connect(i+1) - 
     .              ale_connectivity%ee_connect%iad_connect(i)
               DO kface = 1, lgth
                  j = ale_connectivity%ee_connect%connected(iad + kface - 1)
                  IF (j > 0 .AND. j <= numel_spmd) THEN
                     iad2 = ale_connectivity%ee_connect%iad_connect(j)
                     lgth2 = ale_connectivity%ee_connect%iad_connect(j+1) - 
     .                    ale_connectivity%ee_connect%iad_connect(j)
                     DO kface2 = 1, lgth2
                        IF (i == ale_connectivity%ee_connect%connected(iad2 + kface2 - 1)) THEN
                           EXIT
                        ENDIF
                     ENDDO
                     multi_fvm%FVM_CONNECTIVITY%KVOIS(nb_face * (i - 1) + kface) = kface2
                  ENDIF
               ENDDO
            ENDDO
         ENDIF
      ENDDO
 
      idbg = .false.
C     Verification (debug only)
      IF (idbg) THEN
         DO ng = itask + 1, ngroup, nthread
            matlaw = iparg(1, ng)
            IF (matlaw == 151) THEN
               nel = iparg(2, ng)
               nft = iparg(3, ng)
               ity = iparg(5, ng)
               SELECT CASE (multi_fvm%SYM)
               CASE (0)
                  nb_face = 6
                  numel_spmd = numels
               CASE (1, 2)
                  IF (ity == 2) THEN
C     QUADS
                     nb_face = 4
                     numel_spmd = numelq
                  ELSEIF (ity == 7) THEN
C     TRIANGLES
                     nb_face = 3
                     numel_spmd = numeltg
                  ENDIF
               CASE DEFAULT
                  CALL arret(2)
               END SELECT                  
               DO ii = 1, nel
                  i = ii + nft
                  iad = ale_connectivity%ee_connect%iad_connect(i)
                  lgth = ale_connectivity%ee_connect%iad_connect(i+1) - 
     .                 ale_connectivity%ee_connect%iad_connect(i)
                  DO kface = 1, lgth
                     j = ale_connectivity%ee_connect%connected(iad + kface - 1)
                     IF (j> 0 .AND. j <= numel_spmd) THEN
                        iad2 = ale_connectivity%ee_connect%iad_connect(j)
                        kface2 = multi_fvm%FVM_CONNECTIVITY%KVOIS(nb_face * (i - 1) + kface)
                        IF (ale_connectivity%ee_connect%connected(iad2 + kface2 - 1) /= i) THEN
                           print*, "OUPS"
                        ENDIF
                     ENDIF
                  ENDDO
               ENDDO
            ENDIF
         ENDDO         
      ENDIF
  
      END SUBROUTINE build_connectivity