cr_spline_length.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    cr_spline_length     ../common_source/tools/interpolation/cr_spline_length.F
!||--- called by ------------------------------------------------------
!||    detcord              ../starter/source/initial_conditions/detonation/detcord.F
!||--- calls      -----------------------------------------------------
!||    cr_spline_interpol   ../common_source/tools/interpolation/cr_spline_interpol.F
!||    cr_spline_knots      ../common_source/tools/interpolation/cr_spline_knots.F
!||====================================================================
      SUBROUTINE cr_spline_length(LOCAL_PT,ALPHA,T,LEN)
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
        !compute SPLINE length with third order method (SIMPSON)
        !  INPUT  - LOCAL_PT : 4 control points P0,P1,P2,P3
        !  INPUT  - ALPHA : CCR SPLINE PARAMETER
        !  INPUT  - T : position [0,1] on SPLINE [T1,T2].  1.0 means full spline length
        !  OUTPUT - LEN : length of the curve parametrised with t in [0,T]  T<=1.0
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
        my_real,INTENT(IN)    :: local_pt(4,3),alpha ,t
        my_real,INTENT(INOUT) :: len
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
        my_real               :: knots(4),c(3),c_d(3),c_dd(3),t_
        my_real               :: val(6),k(2)
        INTEGER            :: ITER,NITER
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
        CALL cr_spline_knots(local_pt, knots, alpha)
        len = 0.
        niter=20
        DO iter=1,niter-1
          !first point
          t_=t*(1.*iter-1.)/(niter-1.)
          CALL cr_spline_interpol(local_pt,knots,t_,c,c_d,c_dd)
          val(1)=sqrt(dot_product(c_d(1:3),c_d(1:3)))
          k(1)=knots(2)+t_*(knots(3)-knots(2))
          !middle point
          t_=(1.*iter-1.)/(1.*niter-1.) + 0.5*1./(niter-1.)
          t_=t_*t
          CALL cr_spline_interpol(local_pt,knots,t_,c,c_d,c_dd)
          val(2)=sqrt(dot_product(c_d(1:3),c_d(1:3)))
          !last point
          t_=t*(1.*iter)/(niter-1.)
          CALL cr_spline_interpol(local_pt,knots,t_,c,c_d,c_dd)
          val(3)=sqrt(dot_product(c_d(1:3),c_d(1:3)))
          k(2)=knots(2)+t_*(knots(3)-knots(2))
          !length
          len = len+(k(2)-k(1))/6. * (val(1)+4.*val(2)+val(3))
        ENDDO
      END SUBROUTINE cr_spline_length