create_node_from_rbody.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    create_node_from_rbody   ../starter/source/model/sets/create_node_from_rbody.F
!||--- called by ------------------------------------------------------
!||    hm_set                   ../starter/source/model/sets/hm_set.F
!||--- calls      -----------------------------------------------------
!||    tag_node_from_rbody      ../starter/source/model/sets/tag_node_from_rbody.F
!||--- uses       -----------------------------------------------------
!||    message_mod              ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE create_node_from_rbody(RBY_MSN,CLAUSE)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE setdef_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN), DIMENSION(2,NRBODY) :: RBY_MSN
!
      TYPE (SET_) ::  CLAUSE
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,IND,LIMIT
      INTEGER, ALLOCATABLE, DIMENSION(:) :: TAGNOD,CLAUSE_NODE
      INTEGER IWORK(70000)
      INTEGER, DIMENSION(:),ALLOCATABLE:: IDX,SORT
C=======================================================================
!
      ALLOCATE(tagnod(numnod))
      tagnod(:) = 0
      ALLOCATE(clause_node(numnod))
 
      ind=0
!
      ! RBODY
      IF ( clause%NB_RBODY > 0 )
     . CALL tag_node_from_rbody(
     .                          clause%NB_RBODY ,clause%RBODY ,clause_node,ind,
     .                          tagnod          ,rby_msn      )
C-----------
      limit = numnod/2
      IF (ind < limit)THEN     ! cheaper to use Order on small node groups
        ALLOCATE(idx(2*ind))
        ALLOCATE(sort(ind))
        sort(1:ind) = clause_node(1:ind)
        CALL my_orders(0,iwork,sort,idx,ind,1)
 
        DO i=1,ind
          clause_node(i) = sort(idx(i))
        ENDDO
        DEALLOCATE(idx)
        DEALLOCATE(sort)
      ELSE
       ind = 0
       DO i=1,numnod
         IF (tagnod(i) == 1) THEN
           ind = ind + 1
           clause_node(ind) = i
         ENDIF
       ENDDO
      ENDIF
!
! Decide whether the result is stored in an array or in the clause.
! In certain cases it is useful to store in ARRAY.
! Example : Clause with delete clause. Nodes must be recreated & merged...
! ----------------------------------------------------------------------------
      clause%NB_NODE = ind
      IF(ALLOCATED( clause%NODE )) DEALLOCATE( clause%NODE )
      ALLOCATE( clause%NODE(ind) )
      clause%NODE(1:ind) = clause_node(1:ind)
C-----------
      DEALLOCATE(tagnod)
      DEALLOCATE(clause_node)
C-----------
      RETURN
      END