create_node_from_seg.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    create_node_from_seg   ../starter/source/model/sets/create_node_from_seg.f
!||--- called by ------------------------------------------------------
!||    hm_set                 ../starter/source/model/sets/hm_set.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod     ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod            ../starter/share/message_module/message_mod.F
!||    submodel_mod           ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE create_node_from_seg( CLAUSE )
C-----------------------------------------------
C   ROUTINE DESCRIPTION :
C   ===================
C   Create PART Clause from LIST
C------------------------------------------------------------------
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME          DESCRIPTION                         
C
C     CLAUSE        (SET structure) Clause to be treated
C============================================================================
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE setdef_mod
      USE submodel_mod
      USE message_mod
      USE hm_option_read_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (SET_) ::  CLAUSE
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,IND,NOD(4),NB_SEG_NODE,NB_SEG,LIMIT
      INTEGER, ALLOCATABLE, DIMENSION(:) :: TAGNOD,CLAUSE_NODE
      INTEGER IWORK(70000)
      INTEGER, DIMENSION(:),ALLOCATABLE:: IDX,SORT
C=======================================================================
!
      nb_seg_node = 4 ! by default surf SEG
      nb_seg = clause%NB_SURF_SEG  ! only one surf seg par CLAUSE
 
      IF (clause%NB_SURF_SEG == 0) THEN
        nb_seg_node = 2 ! line SEG
        nb_seg = clause%NB_LINE_SEG  ! only one line seg par CLAUSE
      ENDIF
!
      ALLOCATE(tagnod(numnod))
      tagnod(:) = 0
      ALLOCATE(clause_node(numnod))
 
      ind = 0
 
      IF (clause%NB_SURF_SEG > 0) THEN
       ! none from surf of SEG
        DO i=1,nb_seg
          DO j=1,nb_seg_node
            nod(j) = clause%SURF_NODES(i,j)
            IF(tagnod(nod(j)) == 0)THEN
              tagnod(nod(j)) = 1
              ind = ind+1
              clause_node(ind) = nod(j)
            ENDIF
          ENDDO
        ENDDO
 
      ELSE
       ! none from line of SEG
        DO i=1,nb_seg
          DO j=1,nb_seg_node
            nod(j) = clause%LINE_NODES(i,j)
            IF(tagnod(nod(j)) == 0)THEN
              tagnod(nod(j)) = 1
              ind = ind+1
              clause_node(ind) = nod(j)
            ENDIF
          ENDDO
        ENDDO
 
      ENDIF ! IF (CLAUSE%NB_SURF_SEG > 0)
 
!-------
      limit = numnod/2
      IF (ind < limit)THEN                                  ! cheaper to use Order on small node groups
        ALLOCATE(idx(2*ind))
        ALLOCATE(sort(ind))
        sort(1:ind) = clause_node(1:ind)
        CALL my_orders(0,iwork,sort,idx,ind,1)
 
        DO i=1,ind
          clause_node(i) = sort(idx(i))
        ENDDO
        DEALLOCATE(idx)
        DEALLOCATE(sort)
      ELSE
       ind = 0
       DO i=1,numnod
         IF (tagnod(i) == 1) THEN
           ind = ind + 1
           clause_node(ind) = i
         ENDIF
       ENDDO
      ENDIF
 
!
      ! clause node allocation
      clause%NB_NODE = ind
      IF(ALLOCATED( clause%NODE )) DEALLOCATE( clause%NODE )
      ALLOCATE( clause%NODE(ind) )
      clause%NODE(1:ind) = clause_node(1:ind)
 
C-----------
      DEALLOCATE(tagnod)
      DEALLOCATE(clause_node)
C-----------
      RETURN
      END