create_surface_from_element.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    create_surface_from_element   ../starter/source/model/sets/create_surface_from_element.F
!||--- called by ------------------------------------------------------
!||    create_box_clause             ../starter/source/model/sets/create_box_clause.F
!||    hm_set                        ../starter/source/model/sets/hm_set.F
!||    insert_clause_in_set          ../starter/source/model/sets/insert_clause_in_set.F
!||--- calls      -----------------------------------------------------
!||    surface_buffer                ../starter/source/model/sets/surface_buffer.F
!||--- uses       -----------------------------------------------------
!||    message_mod                   ../starter/share/message_module/message_mod.F
!||    surf_mod                      ../starter/share/modules1/surf_mod.F
!||====================================================================
      SUBROUTINE create_surface_from_element(
     .                       IXS       ,IXS10    ,SH4TREE   ,SH3TREE   ,IXC       ,
     .                       IXTG      ,KNOD2ELS ,NOD2ELS   ,KNOD2ELC  ,NOD2ELC   ,
     .                       KNOD2ELTG ,NOD2ELTG ,IPARTC    ,IPARTG    ,IPARTS    ,
     .                       IPART     ,CLAUSE   ,OPT_A     ,OPT_O     ,IXQ       ,
     .                       KNOD2ELQ  ,NOD2ELQ  ,X         ,KEYSET    ,DELBUF    ,
     .                       GO_IN_ARRAY,IPARTQ)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE my_alloc_mod
      USE setdef_mod
      USE message_mod
      USE set_scratch_mod
      USE names_and_titles_mod , ONLY : ncharfield
      USE surf_mod , ONLY : ext_surf,all_surf
            use element_mod , only : nixs,nixq,nixc,nixtg
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "com04_c.inc"
#include      "scr17_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER  OPT_A,OPT_O
      INTEGER, INTENT(IN) :: IXS(NIXS,*),IXS10(6,*),IXC(NIXC,*),IXTG(NIXTG,*),
     .  KNOD2ELS(*),KNOD2ELC(*),KNOD2ELTG(*),NOD2ELS(*),NOD2ELC(*),
     .  NOD2ELTG(*),IPARTS(*),IPARTC(*),IPARTG(*),SH4TREE(*),SH3TREE(*),
     .  IPART(LIPART1,*),KNOD2ELQ(*),NOD2ELQ(*),IXQ(NIXQ,*),IPARTQ(NUMELQ)
      my_real X(3,*)
      CHARACTER(LEN=NCHARFIELD) :: KEYSET
!
      TYPE (SET_) :: CLAUSE
      TYPE (SET_SCRATCH) ::  DELBUF
      LOGICAL GO_IN_ARRAY
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER IEXT, L, NIX, SZELMAX, IAD_SURF, NSEG, NFACES
      INTEGER IWORK(70000)
!
      INTEGER, ALLOCATABLE, DIMENSION(:,:) :: ITRI
      INTEGER, ALLOCATABLE, DIMENSION(:) :: INDEX, BUFTMPSURF
C=======================================================================
      delbuf%SZ_SURF = 0
      delbuf%SZ_LINE = 0
!
!!      SZELMAX = MAX(CLAUSE%NB_SOLID,CLAUSE%NB_QUAD,CLAUSE%NB_SH4N,CLAUSE%NB_SH3N)
      szelmax = clause%NB_SOLID + clause%NB_QUAD + clause%NB_SH4N + clause%NB_SH3N
      IF (szelmax == 0) RETURN
!
      nfaces = 6  ! HEXA_8
      IF (numels > numels8) nfaces = 16 ! TETRA_10
!
      ALLOCATE(buftmpsurf(szelmax*nfaces*6))
      ALLOCATE(itri(5,szelmax*nfaces))
      ALLOCATE(index(2*szelmax*nfaces))
!
      iad_surf = 1
!------------------
      iext = ext_surf  ! by default (external surface)
      IF ( opt_a == 1 )  iext = all_surf ! all surfaces (internal + external)
      clause%EXT_ALL = iext
!------------------
 
!
!----
!     ! temporary surface segments got from elements
      nseg = 0
      CALL surface_buffer(
     .             ixs       ,ixs10    ,ixc       ,sh4tree   ,sh3tree   ,
     .             ixtg      ,knod2els ,nod2els   ,knod2elc  ,nod2elc   ,
     .             knod2eltg ,nod2eltg ,nseg      ,iext      ,ipartc    ,
     .             iparts    ,ipartg   ,clause    ,buftmpsurf,iad_surf  ,
     .             opt_o     ,ipart    ,knod2elq  ,nod2elq   ,x         ,
     .             ixq       ,keyset   ,ipartq)
!----
!
      nix = 6
!
      DO  l=1,nseg
        index(l)=l
        itri(1,l) = buftmpsurf((l-1)*nix+1)
        itri(2,l) = buftmpsurf((l-1)*nix+2)
        itri(3,l) = buftmpsurf((l-1)*nix+3)
        itri(4,l) = buftmpsurf((l-1)*nix+4)
        itri(5,l) = buftmpsurf((l-1)*nix+6)
      ENDDO
      iwork(1:70000) = 0
      CALL my_orders(0,iwork,itri,index,nseg,5)
!---
!     clause surf allocation
!---
!------------------
!
! Decide whether the result is stored in an array or in the clause.
! In certain cases it is useful to store in ARRAY.
! Example : Clause with delete clause. Surfaces must be recreated & merged...
! ----------------------------------------------------------------------------
      IF (go_in_array .EQV. .true.) THEN
        delbuf%SZ_SURF = nseg
        ALLOCATE(delbuf%SURF(nseg,6))
        DO l=1,nseg
          delbuf%SURF(l,1) = buftmpsurf((index(l)-1)*nix+1)
          delbuf%SURF(l,2) = buftmpsurf((index(l)-1)*nix+2)
          delbuf%SURF(l,3) = buftmpsurf((index(l)-1)*nix+3)
          delbuf%SURF(l,4) = buftmpsurf((index(l)-1)*nix+4)
          delbuf%SURF(l,5) = buftmpsurf((index(l)-1)*nix+5)
          delbuf%SURF(l,6) = buftmpsurf((index(l)-1)*nix+6)
        ENDDO
      ELSE
        IF (ALLOCATED(clause%SURF_NODES)) DEALLOCATE(clause%SURF_NODES)
        IF (ALLOCATED(clause%SURF_ELTYP)) DEALLOCATE(clause%SURF_ELTYP)
        IF (ALLOCATED(clause%SURF_ELEM))  DEALLOCATE(clause%SURF_ELEM)
!
        clause%NB_SURF_SEG = nseg
        CALL my_alloc(clause%SURF_NODES,nseg,4)
        CALL my_alloc(clause%SURF_ELTYP,nseg)
        CALL my_alloc(clause%SURF_ELEM,nseg)
!
        DO l=1,nseg
          clause%SURF_NODES(l,1) = buftmpsurf((index(l)-1)*nix+1)
          clause%SURF_NODES(l,2) = buftmpsurf((index(l)-1)*nix+2)
          clause%SURF_NODES(l,3) = buftmpsurf((index(l)-1)*nix+3)
          clause%SURF_NODES(l,4) = buftmpsurf((index(l)-1)*nix+4)
          clause%SURF_ELTYP(l)   = buftmpsurf((index(l)-1)*nix+5)
          clause%SURF_ELEM(l)    = buftmpsurf((index(l)-1)*nix+6)
        ENDDO
      ENDIF ! IF (GO_IN_ARRAY .EQV. .TRUE.)
!------------------
      IF(ALLOCATED(itri))       DEALLOCATE(itri)
      IF(ALLOCATED(index))      DEALLOCATE(index)
      IF(ALLOCATED(buftmpsurf)) DEALLOCATE(buftmpsurf)
C-----------
!-----------
      RETURN
      END