cutcnt.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    cutcnt        ../engine/source/tools/sect/cutcnt.F
!||--- called by ------------------------------------------------------
!||    genani        ../engine/source/output/anim/generate/genani.F
!||--- uses       -----------------------------------------------------
!||    element_mod   ../common_source/modules/elements/element_mod.F90
!||    output_mod    ../common_source/modules/output/output_mod.F90
!||====================================================================
      SUBROUTINE cutcnt(OUTPUT,ICUT,XCUT,IXS,XYZ0,D,LEN)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE output_mod
      use element_mod , only : nixs  
C------------------------------------------
C NUMBERING CUT ELEMS
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "scrcut_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      type(output_), intent(inout) :: output
      my_real xcut(7,*),xyz0(3,*),d(3,*)
      INTEGER ICUT(44,*),IXS(NIXS,*),LEN
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER IC,I,J,K,ITYP
      my_real dist,dist0,distmin,distmax,dd,dx1,dy1,dz1,dx2,dy2,dz2,vnx,vny,vnz,x,y,z 
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      len=0
      DO ic=1,ncuts
        ityp=icut(1,ic)
        IF(ityp==1)THEN
         dd=output%DTANIM*xcut(7,ic)
         xcut(1,ic)=xcut(1,ic)+dd*xcut(4,ic)
         xcut(2,ic)=xcut(2,ic)+dd*xcut(5,ic)
         xcut(3,ic)=xcut(3,ic)+dd*xcut(6,ic)   
        ELSEIF(ityp==3)THEN
         xcut(1,ic)=xyz0(1,icut(2,ic))
         xcut(2,ic)=xyz0(2,icut(2,ic))
         xcut(3,ic)=xyz0(3,icut(2,ic))
         dx1=xyz0(1,icut(3,ic))-xcut(1,ic)
         dy1=xyz0(2,icut(3,ic))-xcut(2,ic)
         dz1=xyz0(3,icut(3,ic))-xcut(3,ic)
         dx2=xyz0(1,icut(4,ic))-xcut(1,ic)
         dy2=xyz0(2,icut(4,ic))-xcut(2,ic)
         dz2=xyz0(3,icut(4,ic))-xcut(3,ic)
         vnx=dy1*dz2-dy2*dz1
         vny=dz1*dx2-dz2*dx1
         vnz=dx1*dy2-dx2*dy1
         dd=sqrt(vnx**2+vny**2+vnz**2)
         IF(dd>em10)THEN
           xcut(4,ic)=vnx/dd
           xcut(5,ic)=vny/dd
           xcut(6,ic)=vnz/dd
         ENDIF
        ENDIF
C  
        dist0=xcut(4,ic)*xcut(1,ic)+xcut(5,ic)*xcut(2,ic)+xcut(6,ic)*xcut(3,ic)
        DO i=1,numels
          distmin= ep30
          distmax=-ep30
          DO j=1,8
            k=ixs(j+1,i)
            x=xyz0(1,k)
            y=xyz0(2,k)
            z=xyz0(3,k)
            IF(ityp==2)THEN
              x=x-d(1,k)
              y=y-d(2,k)
              z=z-d(3,k)
            ENDIF
            dist=x*xcut(4,ic)+y*xcut(5,ic)+z*xcut(6,ic)-dist0
            distmin=min(dist,distmin)
            distmax=max(dist,distmax)
          enddo!next J
          IF(distmin*distmax<= zero)len=len+1
        enddo!next I
C
      enddo!next IC
      RETURN
      END