czstra3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    czstra3       ../engine/source/elements/shell/coquez/czstra3.f
!||--- called by ------------------------------------------------------
!||    czforc3       ../engine/source/elements/shell/coquez/czforc3.F
!||    czforc3_crk   ../engine/source/elements/xfem/czforc3_crk.F
!||====================================================================
      SUBROUTINE czstra3(JFT    ,JLT    ,NFT   ,VDEF  ,GSTR  ,
     2                   EXX    ,EYY    ,EXY   ,EXZ   ,EYZ   ,  
     3                   KXX    ,KYY    ,KXY   ,DT1C  ,EPSDOT,
     4                   IEPSDOT,ISTRAIN,UX1   ,UX2   ,UX3   ,
     5                   UX4    ,UY1    ,UY2   ,UY3   ,UY4   ,
     6                   PX1    ,PX2    ,PY1   ,PY2   ,AREA  ,
     7                   ISMSTR ,MTN    ,WXY   ,F_DEF ,GSTRW ,
     8                   NEL    )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JFT, JLT, NFT, IEPSDOT, ISTRAIN, ISMSTR, MTN,NEL
      my_real
     .   VDEF(MVSIZ,8), GSTR(NEL,8),
     .   EXX(MVSIZ),EYY(MVSIZ),EXY(MVSIZ),EXZ(MVSIZ),EYZ(MVSIZ),
     .   KXX(MVSIZ),KYY(MVSIZ),KXY(MVSIZ),DT1C(MVSIZ),EPSDOT(6,*),
     .   UX1(*),UX2(*),UX3(*),UX4(*),UY1(*),UY2(*),UY3(*),UY4(*),
     .   PX1(*),PX2(*),PY1(*),PY2(*),AREA(*),F_DEF(MVSIZ,8),WXY(*),GSTRW(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, J
      my_real
     .        FAC1(MVSIZ),UX13,UX24,UY13,UY24,
     .        EXXT,EYYT,EXYT
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7--
C
      IF(IEPSDOT/=0)then
       DO i=jft,jlt
        j = i + nft
        epsdot(1,j) = vdef(i,1)
        epsdot(2,j) = vdef(i,2)
        epsdot(3,j) = vdef(i,3)
        epsdot(4,j) = vdef(i,6)
        epsdot(5,j) = vdef(i,7)
        epsdot(6,j) = vdef(i,8)
       ENDDO
      ENDIF
C
      DO i=jft,jlt
        exx(i) = vdef(i,1) * dt1c(i)
        eyy(i) = vdef(i,2) * dt1c(i)
        exy(i) = vdef(i,3) * dt1c(i)
        eyz(i) = vdef(i,5) * dt1c(i)
        exz(i) = vdef(i,4) * dt1c(i)
        kxx(i) = vdef(i,6) * dt1c(i)
        kyy(i) = vdef(i,7) * dt1c(i)
        kxy(i) = vdef(i,8) * dt1c(i)
      ENDDO
C
      IF (istrain /= 0.OR.ismstr == 10) THEN
       IF(ismstr == 10)THEN
        DO i=jft,jlt
         gstr(i,1)=gstr(i,1)+exx(i)
         gstr(i,2)=gstr(i,2)+eyy(i)
         gstr(i,3)=gstr(i,3)+exy(i)
         gstr(i,4)=gstr(i,4)+eyz(i)
         gstr(i,5)=gstr(i,5)+exz(i)
         gstr(i,6)=gstr(i,6)+kxx(i)
         gstr(i,7)=gstr(i,7)+kyy(i)
         gstr(i,8)=gstr(i,8)+kxy(i)
C-------- WXY         
         gstrw(i)=gstrw(i)+wxy(i)*dt1c(i)
        ENDDO
C-----   
        DO i=jft,jlt 
          f_def(i,6) = gstr(i,6)
          f_def(i,7) = gstr(i,7)
          f_def(i,8) = (gstr(i,8)+gstrw(i))*half
          f_def(i,5) = (gstr(i,8)-gstrw(i))*half
        ENDDO
       ELSEIF(ismstr /= 11)THEN
        DO i=jft,jlt
         gstr(i,1)=gstr(i,1)+exx(i)
         gstr(i,2)=gstr(i,2)+eyy(i)
         gstr(i,3)=gstr(i,3)+exy(i)
         gstr(i,4)=gstr(i,4)+eyz(i)
         gstr(i,5)=gstr(i,5)+exz(i)
         gstr(i,6)=gstr(i,6)+kxx(i)
         gstr(i,7)=gstr(i,7)+kyy(i)
         gstr(i,8)=gstr(i,8)+kxy(i)
        ENDDO
       ELSE
        DO i=jft,jlt
         fac1(i)  =one/area(i)
         ux13=ux1(i)-ux3(i)
         ux24=ux2(i)-ux4(i)
         uy13=uy1(i)-uy3(i)
         uy24=uy2(i)-uy4(i)
         exxt=(px1(i)*ux13+px2(i)*ux24)*fac1(i)
         eyyt=(py1(i)*uy13+py2(i)*uy24)*fac1(i)
         exyt=(py1(i)*ux13+py2(i)*ux24
     .        +px1(i)*uy13+px2(i)*uy24)*fac1(i)
         gstr(i,1)=exxt
         gstr(i,2)=eyyt
         gstr(i,3)=exyt
         gstr(i,4)=gstr(i,4)+eyz(i)
         gstr(i,5)=gstr(i,5)+exz(i)
         gstr(i,6)=gstr(i,6)+kxx(i)
         gstr(i,7)=gstr(i,7)+kyy(i)
         gstr(i,8)=gstr(i,8)+kxy(i)
        ENDDO
       ENDIF
      ENDIF
C
      RETURN
      END