dampdtnoda.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    dampdtnoda          ../starter/source/general_controls/damping/dampdtnoda.F
!||--- called by ------------------------------------------------------
!||    lectur              ../starter/source/starter/lectur.F
!||--- calls      -----------------------------------------------------
!||    read_engine_dtmin   ../starter/source/general_controls/damping/read_engine_dtmin.F
!||--- uses       -----------------------------------------------------
!||====================================================================
      SUBROUTINE dampdtnoda(MS ,IN  ,STIFN ,STIFR ,IGRNOD   ,DAMPR )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE groupdef_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
C-----------------------------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
C     REAL
      my_real , DIMENSION(NUMNOD), INTENT(IN) ::ms 
      my_real , DIMENSION(NUMNOD*IRODDL), INTENT(IN) ::in 
      my_real , DIMENSION(NUMNOD), INTENT(INOUT) ::stifn 
      my_real , DIMENSION(NUMNOD), INTENT(INOUT) ::stifr 
      my_real , DIMENSION(NRDAMP,NDAMP), INTENT(IN) ::dampr 
C-----------------------------------------------
      TYPE (GROUP_) ,DIMENSION(NGRNOD), INTENT(IN) :: IGRNOD
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER N,I,J,ISK,IGR,ND,K,L,LL,FL_FREQ_RANGE
      my_real factb,dampbr,dampar,d_tstart,d_tstop,dampt,
     .   dt2n(numnod),bb,coeff,dtn,dtn2,dampai,dampbi,dt0,dampa3,
     .   alpha05,beta1,dtmax,fac,dtmi1,fac0    
C----------------------------------------------------------
        CALL read_engine_dtmin(dtmi1)
        dtmax = ep04
        dt0 = dtmax
        DO i=1,ndamp
          fl_freq_range = nint(dampr(31,i))
          IF ((dampr(19,i)/=0).OR.(fl_freq_range > 0)) cycle                                                
          igr   = nint(dampr(2,i))
          dtn = dtmax
          DO j=1,igrnod(igr)%NENTITY
            nd=igrnod(igr)%ENTITY(j)
            dt2n(nd) = dtmax
            IF(stifn(nd)>em20 .AND. ms(nd)>zero)THEN
              dt2n(nd) = sqrt(two*ms(nd)/stifn(nd))
              dt2n(nd) = min(dtmax,dt2n(nd))
              dtn = min(dt2n(nd),dtn)
            END IF                               
          END DO      
          IF (iroddl/=0) THEN
            DO j=1,igrnod(igr)%NENTITY
              nd=igrnod(igr)%ENTITY(j)
              IF(stifr(nd)>em20 .AND. in(nd)>zero)THEN
                dtn2 = sqrt(two*in(nd)/stifr(nd))
                dt2n(nd) = min(dt2n(nd),dtn2)
                dtn = min(dt2n(nd),dtn)
              END IF                               
            END DO      
          END IF                               
          dt0=min(dt0,dtn)
          dampai = max(dampr(3,i),dampr(5,i),dampr(7,i))
          dampai = max(dampai,dampr(9,i),dampr(11,i),dampr(13,i))
          dampbi = max(dampr(4,i),dampr(6,i),dampr(8,i))
          dampbi = max(dampbi,dampr(10,i),dampr(12,i),dampr(14,i))
          dampt = dt0*dampr(16,i)
          dampbi = min(dampbi,dampt)
C--  
          DO j=1,igrnod(igr)%NENTITY
            nd=igrnod(igr)%ENTITY(j)
            bb=dampbi/dt2n(nd)+half*dampai*dt2n(nd)
            fac = sqrt(bb*bb+one) -bb
            IF (fac*dt2n(nd) < dtmi1) THEN
              bb=dampbi/dtmi1+half*dampai*dtmi1
              fac = max(fac,sqrt(bb*bb+one) -bb)
            END IF
            coeff =one/fac**2
            IF(stifn(nd)>em20 .AND. ms(nd)>zero)THEN
              stifn(nd) =stifn(nd)*coeff
            END IF                               
            IF (iroddl/=0) THEN
              IF(stifr(nd)>em20 .AND. in(nd)>zero)THEN
                stifr(nd) =stifr(nd)*coeff
              END IF                               
            END IF                               
          END DO      
        END DO !I=1,NDAMP
C        
      RETURN 
      END SUBROUTINE dampdtnoda