dchksy.f

Go to the documentation of this file.

*> \brief \b DCHKSY
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE DCHKSY( DOTYPE, NN, NVAL, NNB, NBVAL, NNS, NSVAL,
*                          THRESH, TSTERR, NMAX, A, AFAC, AINV, B, X,
*                          XACT, WORK, RWORK, IWORK, NOUT )
*
*       .. Scalar Arguments ..
*       LOGICAL            TSTERR
*       INTEGER            NMAX, NN, NNB, NNS, NOUT
*       DOUBLE PRECISION   THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            IWORK( * ), NBVAL( * ), NSVAL( * ), NVAL( * )
*       DOUBLE PRECISION   A( * ), AFAC( * ), AINV( * ), B( * ),
*      $                   RWORK( * ), WORK( * ), X( * ), XACT( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DCHKSY tests DSYTRF, -TRI2, -TRS, -TRS2, -RFS, and -CON.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          The matrix types to be used for testing.  Matrices of type j
*>          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
*>          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER
*>          The number of values of N contained in the vector NVAL.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NN)
*>          The values of the matrix dimension N.
*> \endverbatim
*>
*> \param[in] NNB
*> \verbatim
*>          NNB is INTEGER
*>          The number of values of NB contained in the vector NBVAL.
*> \endverbatim
*>
*> \param[in] NBVAL
*> \verbatim
*>          NBVAL is INTEGER array, dimension (NNB)
*>          The values of the blocksize NB.
*> \endverbatim
*>
*> \param[in] NNS
*> \verbatim
*>          NNS is INTEGER
*>          The number of values of NRHS contained in the vector NSVAL.
*> \endverbatim
*>
*> \param[in] NSVAL
*> \verbatim
*>          NSVAL is INTEGER array, dimension (NNS)
*>          The values of the number of right hand sides NRHS.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is DOUBLE PRECISION
*>          The threshold value for the test ratios.  A result is
*>          included in the output file if RESULT >= THRESH.  To have
*>          every test ratio printed, use THRESH = 0.
*> \endverbatim
*>
*> \param[in] TSTERR
*> \verbatim
*>          TSTERR is LOGICAL
*>          Flag that indicates whether error exits are to be tested.
*> \endverbatim
*>
*> \param[in] NMAX
*> \verbatim
*>          NMAX is INTEGER
*>          The maximum value permitted for N, used in dimensioning the
*>          work arrays.
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is DOUBLE PRECISION array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] AFAC
*> \verbatim
*>          AFAC is DOUBLE PRECISION array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] AINV
*> \verbatim
*>          AINV is DOUBLE PRECISION array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] B
*> \verbatim
*>          B is DOUBLE PRECISION array, dimension (NMAX*NSMAX)
*>          where NSMAX is the largest entry in NSVAL.
*> \endverbatim
*>
*> \param[out] X
*> \verbatim
*>          X is DOUBLE PRECISION array, dimension (NMAX*NSMAX)
*> \endverbatim
*>
*> \param[out] XACT
*> \verbatim
*>          XACT is DOUBLE PRECISION array, dimension (NMAX*NSMAX)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension (NMAX*max(3,NSMAX))
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is DOUBLE PRECISION array, dimension (max(NMAX,2*NSMAX))
*> \endverbatim
*>
*> \param[out] IWORK
*> \verbatim
*>          IWORK is INTEGER array, dimension (2*NMAX)
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The unit number for output.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup double_lin
*
*  =====================================================================
      SUBROUTINE dchksy( DOTYPE, NN, NVAL, NNB, NBVAL, NNS, NSVAL,
     $                   THRESH, TSTERR, NMAX, A, AFAC, AINV, B, X,
     $                   XACT, WORK, RWORK, IWORK, NOUT )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NMAX, NN, NNB, NNS, NOUT
      DOUBLE PRECISION   THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            IWORK( * ), NBVAL( * ), NSVAL( * ), NVAL( * )
      DOUBLE PRECISION   A( * ), AFAC( * ), AINV( * ), B( * ),
     $                   rwork( * ), work( * ), x( * ), xact( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO
      PARAMETER          ( ZERO = 0.0d+0 )
      INTEGER            NTYPES
      parameter( ntypes = 10 )
      INTEGER            NTESTS
      parameter( ntests = 9 )
*     ..
*     .. Local Scalars ..
      LOGICAL            TRFCON, ZEROT
      CHARACTER          DIST, TYPE, UPLO, XTYPE
      CHARACTER*3        PATH
      INTEGER            I, I1, I2, IMAT, IN, INB, INFO, IOFF, IRHS,
     $                   iuplo, izero, j, k, kl, ku, lda, lwork, mode,
     $                   n, nb, nerrs, nfail, nimat, nrhs, nrun, nt
      DOUBLE PRECISION   ANORM, CNDNUM, RCOND, RCONDC
*     ..
*     .. Local Arrays ..
      CHARACTER          UPLOS( 2 )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      DOUBLE PRECISION   RESULT( NTESTS )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DGET06, DLANSY
      EXTERNAL           DGET06, DLANSY
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, derrsy, dget04, dlacpy,
     $                   dlarhs, dlatb4, dlatms, dpot02, dpot03, dpot05,
     $                   dsycon, dsyrfs, dsyt01, dsytrf,
     $                   dsytri2, dsytrs, dsytrs2, xlaenv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
      DATA               uplos / 'U', 'L' /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      path( 1: 1 ) = 'Double precision'
      path( 2: 3 ) = 'SY'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL derrsy( path, nout )
      infot = 0
*
*     Set the minimum block size for which the block routine should
*     be used, which will be later returned by ILAENV
*
      CALL xlaenv( 2, 2 )
*
*     Do for each value of N in NVAL
*
      DO 180 in = 1, nn
         n = nval( in )
         lda = max( n, 1 )
         xtype = 'N'
         nimat = ntypes
         IF( n.LE.0 )
     $      nimat = 1
*
         izero = 0
*
*        Do for each value of matrix type IMAT
*
         DO 170 imat = 1, nimat
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 170
*
*           Skip types 3, 4, 5, or 6 if the matrix size is too small.
*
            zerot = imat.GE.3 .AND. imat.LE.6
            IF( zerot .AND. n.LT.imat-2 )
     $         GO TO 170
*
*           Do first for UPLO = 'U', then for UPLO = 'L'
*
            DO 160 iuplo = 1, 2
               uplo = uplos( iuplo )
*
*              Begin generate the test matrix A.
*
*
*              Set up parameters with DLATB4 for the matrix generator
*              based on the type of matrix to be generated.
*
               CALL dlatb4( path, imat, n, n, TYPE, kl, KU, anorm, mode,
     $                      cndnum, dist )
*
*              Generate a matrix with DLATMS.
*
               srnamt = 'DLATMS'
               CALL dlatms( n, n, dist, iseed, TYPE, RWORK, mode,
     $                      cndnum, anorm, kl, ku, uplo, a, lda, work,
     $                      info )
*
*              Check error code from DLATMS and handle error.
*
               IF( info.NE.0 ) THEN
                  CALL alaerh( path, 'DLATMS', info, 0, uplo, n, n, -1,
     $                         -1, -1, imat, nfail, nerrs, nout )
*
*                    Skip all tests for this generated matrix
*
                  GO TO 160
               END IF
*
*              For matrix types 3-6, zero one or more rows and
*              columns of the matrix to test that INFO is returned
*              correctly.
*
               IF( zerot ) THEN
                  IF( imat.EQ.3 ) THEN
                     izero = 1
                  ELSE IF( imat.EQ.4 ) THEN
                     izero = n
                  ELSE
                     izero = n / 2 + 1
                  END IF
*
                  IF( imat.LT.6 ) THEN
*
*                    Set row and column IZERO to zero.
*
                     IF( iuplo.EQ.1 ) THEN
                        ioff = ( izero-1 )*lda
                        DO 20 i = 1, izero - 1
                           a( ioff+i ) = zero
   20                   CONTINUE
                        ioff = ioff + izero
                        DO 30 i = izero, n
                           a( ioff ) = zero
                           ioff = ioff + lda
   30                   CONTINUE
                     ELSE
                        ioff = izero
                        DO 40 i = 1, izero - 1
                           a( ioff ) = zero
                           ioff = ioff + lda
   40                   CONTINUE
                        ioff = ioff - izero
                        DO 50 i = izero, n
                           a( ioff+i ) = zero
   50                   CONTINUE
                     END IF
                  ELSE
                     IF( iuplo.EQ.1 ) THEN
*
*                       Set the first IZERO rows and columns to zero.
*
                        ioff = 0
                        DO 70 j = 1, n
                           i2 = min( j, izero )
                           DO 60 i = 1, i2
                              a( ioff+i ) = zero
   60                      CONTINUE
                           ioff = ioff + lda
   70                   CONTINUE
                     ELSE
*
*                       Set the last IZERO rows and columns to zero.
*
                        ioff = 0
                        DO 90 j = 1, n
                           i1 = max( j, izero )
                           DO 80 i = i1, n
                              a( ioff+i ) = zero
   80                      CONTINUE
                           ioff = ioff + lda
   90                   CONTINUE
                     END IF
                  END IF
               ELSE
                  izero = 0
               END IF
*
*              End generate the test matrix A.
*
*              Do for each value of NB in NBVAL
*
               DO 150 inb = 1, nnb
*
*                 Set the optimal blocksize, which will be later
*                 returned by ILAENV.
*
                  nb = nbval( inb )
                  CALL xlaenv( 1, nb )
*
*                 Copy the test matrix A into matrix AFAC which
*                 will be factorized in place. This is needed to
*                 preserve the test matrix A for subsequent tests.
*
                  CALL dlacpy( uplo, n, n, a, lda, afac, lda )
*
*                 Compute the L*D*L**T or U*D*U**T factorization of the
*                 matrix. IWORK stores details of the interchanges and
*                 the block structure of D. AINV is a work array for
*                 block factorization, LWORK is the length of AINV.
*
                  lwork = max( 2, nb )*lda
                  srnamt = 'DSYTRF'
                  CALL dsytrf( uplo, n, afac, lda, iwork, ainv, lwork,
     $                         info )
*
*                 Adjust the expected value of INFO to account for
*                 pivoting.
*
                  k = izero
                  IF( k.GT.0 ) THEN
  100                CONTINUE
                     IF( iwork( k ).LT.0 ) THEN
                        IF( iwork( k ).NE.-k ) THEN
                           k = -iwork( k )
                           GO TO 100
                        END IF
                     ELSE IF( iwork( k ).NE.k ) THEN
                        k = iwork( k )
                        GO TO 100
                     END IF
                  END IF
*
*                 Check error code from DSYTRF and handle error.
*
                  IF( info.NE.k )
     $               CALL alaerh( path, 'DSYTRF', info, k, uplo, n, n,
     $                            -1, -1, nb, imat, nfail, nerrs, nout )
*
*                 Set the condition estimate flag if the INFO is not 0.
*
                  IF( info.NE.0 ) THEN
                     trfcon = .true.
                  ELSE
                     trfcon = .false.
                  END IF
*
*+    TEST 1
*                 Reconstruct matrix from factors and compute residual.
*
                  CALL dsyt01( uplo, n, a, lda, afac, lda, iwork, ainv,
     $                         lda, rwork, result( 1 ) )
                  nt = 1
*
*+    TEST 2
*                 Form the inverse and compute the residual,
*                 if the factorization was competed without INFO > 0
*                 (i.e. there is no zero rows and columns).
*                 Do it only for the first block size.
*
                  IF( inb.EQ.1 .AND. .NOT.trfcon ) THEN
                     CALL dlacpy( uplo, n, n, afac, lda, ainv, lda )
                     srnamt = 'DSYTRI2'
                     lwork = (n+nb+1)*(nb+3)
                     CALL dsytri2( uplo, n, ainv, lda, iwork, work,
     $                            lwork, info )
*
*                    Check error code from DSYTRI2 and handle error.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'DSYTRI2', info, -1, uplo, n,
     $                               n, -1, -1, -1, imat, nfail, nerrs,
     $                               nout )
*
*                    Compute the residual for a symmetric matrix times
*                    its inverse.
*
                     CALL dpot03( uplo, n, a, lda, ainv, lda, work, lda,
     $                            rwork, rcondc, result( 2 ) )
                     nt = 2
                  END IF
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  DO 110 k = 1, nt
                     IF( result( k ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9999 )uplo, n, nb, imat, k,
     $                     result( k )
                        nfail = nfail + 1
                     END IF
  110             CONTINUE
                  nrun = nrun + nt
*
*                 Skip the other tests if this is not the first block
*                 size.
*
                  IF( inb.GT.1 )
     $               GO TO 150
*
*                 Do only the condition estimate if INFO is not 0.
*
                  IF( trfcon ) THEN
                     rcondc = zero
                     GO TO 140
                  END IF
*
*                 Do for each value of NRHS in NSVAL.
*
                  DO 130 irhs = 1, nns
                     nrhs = nsval( irhs )
*
*+    TEST 3 ( Using TRS)
*                 Solve and compute residual for  A * X = B.
*
*                    Choose a set of NRHS random solution vectors
*                    stored in XACT and set up the right hand side B
*
                     srnamt = 'DLARHS'
                     CALL dlarhs( path, xtype, uplo, ' ', n, n, kl, ku,
     $                            nrhs, a, lda, xact, lda, b, lda,
     $                            iseed, info )
                     CALL dlacpy( 'Full', n, nrhs, b, lda, x, lda )
*
                     srnamt = 'DSYTRS'
                     CALL dsytrs( uplo, n, nrhs, afac, lda, iwork, x,
     $                            lda, info )
*
*                    Check error code from DSYTRS and handle error.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'DSYTRS', info, 0, uplo, n,
     $                               n, -1, -1, nrhs, imat, nfail,
     $                               nerrs, nout )
*
                     CALL dlacpy( 'Full', n, nrhs, b, lda, work, lda )
*
*                    Compute the residual for the solution
*
                     CALL dpot02( uplo, n, nrhs, a, lda, x, lda, work,
     $                            lda, rwork, result( 3 ) )
*
*+    TEST 4 (Using TRS2)
*
*                 Solve and compute residual for  A * X = B.
*
*                    Choose a set of NRHS random solution vectors
*                    stored in XACT and set up the right hand side B
*
                     srnamt = 'DLARHS'
                     CALL dlarhs( path, xtype, uplo, ' ', n, n, kl, ku,
     $                            nrhs, a, lda, xact, lda, b, lda,
     $                            iseed, info )
                     CALL dlacpy( 'Full', n, nrhs, b, lda, x, lda )
*
                     srnamt = 'DSYTRS2'
                     CALL dsytrs2( uplo, n, nrhs, afac, lda, iwork, x,
     $                            lda, work, info )
*
*                    Check error code from DSYTRS2 and handle error.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'DSYTRS2', info, 0, uplo, n,
     $                               n, -1, -1, nrhs, imat, nfail,
     $                               nerrs, nout )
*
                     CALL dlacpy( 'Full', n, nrhs, b, lda, work, lda )
*
*                    Compute the residual for the solution
*
                     CALL dpot02( uplo, n, nrhs, a, lda, x, lda, work,
     $                            lda, rwork, result( 4 ) )
*
*+    TEST 5
*                 Check solution from generated exact solution.
*
                     CALL dget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                            result( 5 ) )
*
*+    TESTS 6, 7, and 8
*                 Use iterative refinement to improve the solution.
*
                     srnamt = 'DSYRFS'
                     CALL dsyrfs( uplo, n, nrhs, a, lda, afac, lda,
     $                            iwork, b, lda, x, lda, rwork,
     $                            rwork( nrhs+1 ), work, iwork( n+1 ),
     $                            info )
*
*                    Check error code from DSYRFS and handle error.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'DSYRFS', info, 0, uplo, n,
     $                               n, -1, -1, nrhs, imat, nfail,
     $                               nerrs, nout )
*
                     CALL dget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                            result( 6 ) )
                     CALL dpot05( uplo, n, nrhs, a, lda, b, lda, x, lda,
     $                            xact, lda, rwork, rwork( nrhs+1 ),
     $                            result( 7 ) )
*
*                    Print information about the tests that did not pass
*                    the threshold.
*
                     DO 120 k = 3, 8
                        IF( result( k ).GE.thresh ) THEN
                           IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                        CALL alahd( nout, path )
                           WRITE( nout, fmt = 9998 )uplo, n, nrhs,
     $                        imat, k, result( k )
                           nfail = nfail + 1
                        END IF
  120                CONTINUE
                     nrun = nrun + 6
*
*                 End do for each value of NRHS in NSVAL.
*
  130             CONTINUE
*
*+    TEST 9
*                 Get an estimate of RCOND = 1/CNDNUM.
*
  140             CONTINUE
                  anorm = dlansy( '1', uplo, n, a, lda, rwork )
                  srnamt = 'DSYCON'
                  CALL dsycon( uplo, n, afac, lda, iwork, anorm, rcond,
     $                         work, iwork( n+1 ), info )
*
*                 Check error code from DSYCON and handle error.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'DSYCON', info, 0, uplo, n, n,
     $                            -1, -1, -1, imat, nfail, nerrs, nout )
*
*                 Compute the test ratio to compare values of RCOND
*
                  result( 9 ) = dget06( rcond, rcondc )
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  IF( result( 9 ).GE.thresh ) THEN
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                  CALL alahd( nout, path )
                     WRITE( nout, fmt = 9997 )uplo, n, imat, 9,
     $                  result( 9 )
                     nfail = nfail + 1
                  END IF
                  nrun = nrun + 1
  150          CONTINUE
*
  160       CONTINUE
  170    CONTINUE
  180 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ', NB =', i4, ', type ',
     $      i2, ', test ', i2, ', ratio =', g12.5 )
 9998 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ', NRHS=', i3, ', type ',
     $      i2, ', test(', i2, ') =', g12.5 )
 9997 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ',', 10x, ' type ', i2,
     $      ', test(', i2, ') =', g12.5 )
      RETURN
*
*     End of DCHKSY
*
      END