dset.f

Go to the documentation of this file.

      SUBROUTINE dset( N, ALPHA, X, INCX )
*
*  -- PBLAS auxiliary routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      INTEGER            INCX, N
      DOUBLE PRECISION   ALPHA
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   X( * )
*     ..
*
*  Purpose
*  =======
*
*  DSET sets the entries of an n vector x to the scalar alpha.
*
*  Arguments
*  =========
*
*  N       (input) INTEGER
*          On entry, N specifies the length of the vector x. N  must  be
*          at least zero.
*
*  ALPHA   (input) DOUBLE PRECISION
*          On entry, ALPHA specifies the scalar alpha.
*
*  X       (input/output) DOUBLE PRECISION array of dimension at least
*          ( 1 + ( n - 1 )*abs( INCX ) ). Before entry,  the incremented
*          array  X  must  contain the vector x. On exit, entries of the
*          incremented array X are set to alpha.
*
*  INCX    (input) INTEGER
*          On entry, INCX specifies the increment for the elements of X.
*          INCX must not be zero.
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            I, INFO, IX, M, MP1
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          mod
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF( n.LT.0 ) THEN
         info = 1
      ELSE IF( incx.EQ.0 ) THEN
         info = 4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DSET', info )
         RETURN
      END IF
*
*     Quick return if possible.
*
      IF( n.LE.0 )
     $   RETURN
*
*     Form  x := alpha
*
      IF( incx.EQ.1 )
     $   GO TO 20
*
*     code for increments not equal to 1
*
*     Set up the start point in  X.
*
      IF( incx.GT.0 ) THEN
         ix = 1
      ELSE
         ix = 1 - ( n - 1 ) * incx
      END IF
*
      DO 10 i = 1, n
        x( ix ) = alpha
        ix = ix + incx
   10 CONTINUE
*
      RETURN
*
*     code for increment equal to 1
*
*     clean-up loop
*
   20 m = mod( n, 4 )
*
      IF( m.EQ.0 )
     $   GO TO 40
*
      DO 30 i = 1, m
        x( i ) = alpha
   30 CONTINUE
      IF( n.LT.4 )
     $   RETURN
*
   40 mp1 = m + 1
      DO 50 i = mp1, n, 4
         x( i     ) = alpha
         x( i + 1 ) = alpha
         x( i + 2 ) = alpha
         x( i + 3 ) = alpha
   50 CONTINUE
*
      RETURN
*
*     End of DSET
*
      END