szderi3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    szderi3     ../engine/source/elements/solid/solidez/szderi3.F
!||--- called by ------------------------------------------------------
!||    szforc3     ../engine/source/elements/solid/solidez/szforc3.f
!||--- calls      -----------------------------------------------------
!||    schkjabt3   ../engine/source/elements/solid/solide4/schkjabt3.F
!||====================================================================
      SUBROUTINE szderi3(
     1   OFF,     DET,     NGL,     ISMSTR,
     2   X1,      X2,      X3,      X4,
     3   X5,      X6,      X7,      X8,
     4   Y1,      Y2,      Y3,      Y4,
     5   Y5,      Y6,      Y7,      Y8,
     6   Z1,      Z2,      Z3,      Z4,
     7   Z5,      Z6,      Z7,      Z8,
     8   PX1,     PX2,     PX3,     PX4,
     9   PY1,     PY2,     PY3,     PY4,
     A   PZ1,     PZ2,     PZ3,     PZ4,
     B   PX1H1,   PX1H2,   PX1H3,   PX1H4,
     C   PX2H1,   PX2H2,   PX2H3,   PX2H4,
     D   PX3H1,   PX3H2,   PX3H3,   PX3H4,
     E   PX4H1,   PX4H2,   PX4H3,   PX4H4,
     F   JAC1,    JAC2,    JAC3,    JAC4,
     G   JAC5,    JAC6,    JAC9,    SAV,
     H   OFFG,    NEL,     VOLDP,   JLAG)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: JLAG
      INTEGER :: ISMSTR,NEL,NGL(*)
      DOUBLE PRECISION
     .   X1(*), X2(*), X3(*), X4(*), X5(*), X6(*), X7(*), X8(*),
     .   Y1(*), Y2(*), Y3(*), Y4(*), Y5(*), Y6(*), Y7(*), Y8(*),  
     .   Z1(*), Z2(*), Z3(*), Z4(*), Z5(*), Z6(*), Z7(*), Z8(*),
     .   SAV(NEL,21),VOLDP(*)
C
      my_real
     .   OFF(*),DET(*),  
     .   PX1(*), PX2(*), PX3(*), PX4(*),  
     .   PY1(*), PY2(*), PY3(*), PY4(*),  
     .   PZ1(*), PZ2(*), PZ3(*), PZ4(*),  
     .   PX1H1(*), PX1H2(*), PX1H3(*),PX1H4(*),  
     .   PX2H1(*), PX2H2(*), PX2H3(*),PX2H4(*),  
     .   PX3H1(*), PX3H2(*), PX3H3(*),PX3H4(*),  
     .   PX4H1(*), PX4H2(*), PX4H3(*),PX4H4(*),  
     .   jac1(*),jac2(*),jac3(*),
     .   jac4(*),jac5(*),jac6(*),jac9(*),offg(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I,J,NNEGA,INDEX(MVSIZ)
C
      my_real
     .   dett ,  jac7(mvsiz), jac8(mvsiz) , 
     .   jaci1, jaci2, jaci3,
     .   jaci4, jaci5, jaci6,
     .   jaci7, jaci8, jaci9,
     .   jac_59_68(mvsiz), jac_67_49(mvsiz), jac_48_57(mvsiz),
     .   jaci12, jaci45, jaci78,
     .   x_17_46 , x_28_35 ,
     .   y_17_46 , y_28_35 ,
     .   z_17_46 , z_28_35 ,
     .   hx,hy,hz
      double precision
     .   x17 , x28 , x35 , x46,
     .   y17 , y28 , y35 , y46,
     .   z17 , z28 , z35 , z46
C-----------------------------------------------
      DO i=1,nel
        x17=x7(i)-x1(i)
        x28=x8(i)-x2(i)
        x35=x5(i)-x3(i)
        x46=x6(i)-x4(i)
        y17=y7(i)-y1(i)
        y28=y8(i)-y2(i)
        y35=y5(i)-y3(i)
        y46=y6(i)-y4(i)
        z17=z7(i)-z1(i)
        z28=z8(i)-z2(i)
        z35=z5(i)-z3(i)
        z46=z6(i)-z4(i)
C
        jac4(i)=x17+x28-x35-x46
        jac5(i)=y17+y28-y35-y46
        jac6(i)=z17+z28-z35-z46
        x_17_46=x17+x46
        x_28_35=x28+x35
        y_17_46=y17+y46
        y_28_35=y28+y35
        z_17_46=z17+z46
        z_28_35=z28+z35
        jac7(i)=x_17_46+x_28_35
        jac8(i)=y_17_46+y_28_35
        jac9(i)=z_17_46+z_28_35
        jac1(i)=x_17_46-x_28_35
        jac2(i)=y_17_46-y_28_35
        jac3(i)=z_17_46-z_28_35
      ENDDO
C
      DO i=1,nel
      jac_59_68(i)=jac5(i)*jac9(i)-jac6(i)*jac8(i)
      jac_67_49(i)=jac6(i)*jac7(i)-jac4(i)*jac9(i)
      jac_48_57(i)=jac4(i)*jac8(i)-jac5(i)*jac7(i)
      END DO
C
      DO i=1,nel
      voldp(i)=one_over_64*(jac1(i)*jac_59_68(i)+jac2(i)*jac_67_49(i)+jac3(i)*jac_48_57(i))
      det(i)=voldp(i)
      END DO
C
      CALL schkjabt3(
     1   off,     det,     ngl,     offg,
     2   nnega,   index,   nel,     ismstr,
     3   jlag)
      IF (nnega>0) THEN
        IF (ismstr==10.OR.ismstr==12) THEN
#include "vectorize.inc"
         DO j=1,nnega
          i = index(j)
            x1(i)=sav(i,1)
            y1(i)=sav(i,8)
            z1(i)=sav(i,15)
            x2(i)=sav(i,2)
            y2(i)=sav(i,9)
            z2(i)=sav(i,16)
            x3(i)=sav(i,3)
            y3(i)=sav(i,10)
            z3(i)=sav(i,17)
            x4(i)=sav(i,4)
            y4(i)=sav(i,11)
            z4(i)=sav(i,18)
            x5(i)=sav(i,5)
            y5(i)=sav(i,12)
            z5(i)=sav(i,19)
            x6(i)=sav(i,6)
            y6(i)=sav(i,13)
            z6(i)=sav(i,20)
            x7(i)=sav(i,7)
            y7(i)=sav(i,14)
            z7(i)=sav(i,21)
            x8(i)=zero
            y8(i)=zero
            z8(i)=zero
         ENDDO
        ELSE
         DO j=1,nnega
          i = index(j)
            x1(i)=sav(i,1)
            y1(i)=sav(i,2)
            z1(i)=sav(i,3)
            x2(i)=sav(i,4)
            y2(i)=sav(i,5)
            z2(i)=sav(i,6)
            x3(i)=sav(i,7)
            y3(i)=sav(i,8)
            z3(i)=sav(i,9)
            x4(i)=sav(i,10)
            y4(i)=sav(i,11)
            z4(i)=sav(i,12)
            x5(i)=sav(i,13)
            y5(i)=sav(i,14)
            z5(i)=sav(i,15)
            x6(i)=sav(i,16)
            y6(i)=sav(i,17)
            z6(i)=sav(i,18)
            x7(i)=sav(i,19)
            y7(i)=sav(i,20)
            z7(i)=sav(i,21)
            x8(i)=zero
            y8(i)=zero
            z8(i)=zero
         ENDDO
        END IF
#include "vectorize.inc"
         DO j=1,nnega
          i = index(j)
C
            x17=x7(i)-x1(i)
            x28=x8(i)-x2(i)
            x35=x5(i)-x3(i)
            x46=x6(i)-x4(i)
            y17=y7(i)-y1(i)
            y28=y8(i)-y2(i)
            y35=y5(i)-y3(i)
            y46=y6(i)-y4(i)
            z17=z7(i)-z1(i)
            z28=z8(i)-z2(i)
            z35=z5(i)-z3(i)
            z46=z6(i)-z4(i)
C
            jac4(i)=x17+x28-x35-x46
            jac5(i)=y17+y28-y35-y46
            jac6(i)=z17+z28-z35-z46
            jac7(i)=x17+x46+x28+x35
            jac8(i)=y17+y46+y28+y35
            jac9(i)=z17+z46+z28+z35
            jac1(i)=x17+x46-x28-x35
            jac2(i)=y17+y46-y28-y35
            jac3(i)=z17+z46-z28-z35
C      
            jac_59_68(i)=jac5(i)*jac9(i)-jac6(i)*jac8(i)
            jac_67_49(i)=jac6(i)*jac7(i)-jac4(i)*jac9(i)
            jac_48_57(i)=jac4(i)*jac8(i)-jac5(i)*jac7(i)
C
           voldp(i)=one_over_64*(jac1(i)*jac_59_68(i)+jac2(i)*jac_67_49(i)+jac3(i)*jac_48_57(i))
           det(i)=voldp(i)
           offg(i) = two
         ENDDO
      END IF
C
C Jacobian matrix inverse and shape functions derivatives Pij
      DO i=1,nel
         dett=one_over_64/det(i)
         jaci1=dett*jac_59_68(i)
         jaci4=dett*jac_67_49(i)
         jaci7=dett*jac_48_57(i)
         jaci2=dett*(-jac2(i)*jac9(i)+jac3(i)*jac8(i))
         jaci5=dett*( jac1(i)*jac9(i)-jac3(i)*jac7(i))
         jaci8=dett*(-jac1(i)*jac8(i)+jac2(i)*jac7(i))
         jaci3=dett*( jac2(i)*jac6(i)-jac3(i)*jac5(i))
         jaci6=dett*(-jac1(i)*jac6(i)+jac3(i)*jac4(i))
         jaci9=dett*( jac1(i)*jac5(i)-jac2(i)*jac4(i))
 
         jaci12=jaci1-jaci2
         jaci45=jaci4-jaci5
         jaci78=jaci7-jaci8
         px2(i)= jaci12-jaci3
         py2(i)= jaci45-jaci6
         pz2(i)= jaci78-jaci9
         px4(i)=-jaci12-jaci3
         py4(i)=-jaci45-jaci6
         pz4(i)=-jaci78-jaci9
 
         jaci12=jaci1+jaci2
         jaci45=jaci4+jaci5
         jaci78=jaci7+jaci8
         px1(i)=-jaci12-jaci3
         py1(i)=-jaci45-jaci6
         pz1(i)=-jaci78-jaci9
         px3(i)=jaci12-jaci3
         py3(i)=jaci45-jaci6
         pz3(i)=jaci78-jaci9
       ENDDO
C
       DO i=1,nel
C 1 -1 1 -1 1 -1 1 -1
         hx=one_over_8*(x1(i)-x2(i)+x3(i)-x4(i)+x5(i)-x6(i)+x7(i)-x8(i))
         hy=one_over_8*(y1(i)-y2(i)+y3(i)-y4(i)+y5(i)-y6(i)+y7(i)-y8(i))
         hz=one_over_8*(z1(i)-z2(i)+z3(i)-z4(i)+z5(i)-z6(i)+z7(i)-z8(i))   
         px1h3(i)=px1(i)*hx+ py1(i)*hy+pz1(i)*hz
         px2h3(i)=px2(i)*hx+ py2(i)*hy+pz2(i)*hz
         px3h3(i)=px3(i)*hx+ py3(i)*hy+pz3(i)*hz
         px4h3(i)=px4(i)*hx+ py4(i)*hy+pz4(i)*hz
       END DO
C 1 1 -1 -1 -1 -1 1 1
       DO i=1,nel
         hx=one_over_8*(x1(i)+x2(i)-x3(i)-x4(i)-x5(i)-x6(i)+x7(i)+x8(i))
         hy=one_over_8*(y1(i)+y2(i)-y3(i)-y4(i)-y5(i)-y6(i)+y7(i)+y8(i))
         hz=one_over_8*(z1(i)+z2(i)-z3(i)-z4(i)-z5(i)-z6(i)+z7(i)+z8(i))   
         px1h1(i)=px1(i)*hx+ py1(i)*hy+pz1(i)*hz
         px2h1(i)=px2(i)*hx+ py2(i)*hy+pz2(i)*hz
         px3h1(i)=px3(i)*hx+ py3(i)*hy+pz3(i)*hz
         px4h1(i)=px4(i)*hx+ py4(i)*hy+pz4(i)*hz
       END DO
C 1 -1 -1 1 -1 1 1 -1
       DO i=1,nel
         hx=one_over_8*(x1(i)-x2(i)-x3(i)+x4(i)-x5(i)+x6(i)+x7(i)-x8(i))
         hy=one_over_8*(y1(i)-y2(i)-y3(i)+y4(i)-y5(i)+y6(i)+y7(i)-y8(i))
         hz=one_over_8*(z1(i)-z2(i)-z3(i)+z4(i)-z5(i)+z6(i)+z7(i)-z8(i))   
         px1h2(i)=px1(i)*hx+ py1(i)*hy+pz1(i)*hz
         px2h2(i)=px2(i)*hx+ py2(i)*hy+pz2(i)*hz
         px3h2(i)=px3(i)*hx+ py3(i)*hy+pz3(i)*hz
         px4h2(i)=px4(i)*hx+ py4(i)*hy+pz4(i)*hz
       END DO
C -1 1 -1 1 1 -1 1 -1
       DO i=1,nel
         hx=one_over_8*(-x1(i)+x2(i)-x3(i)+x4(i)+x5(i)-x6(i)+x7(i)-x8(i))
         hy=one_over_8*(-y1(i)+y2(i)-y3(i)+y4(i)+y5(i)-y6(i)+y7(i)-y8(i))
         hz=one_over_8*(-z1(i)+z2(i)-z3(i)+z4(i)+z5(i)-z6(i)+z7(i)-z8(i))   
         px1h4(i)=px1(i)*hx+ py1(i)*hy+pz1(i)*hz
         px2h4(i)=px2(i)*hx+ py2(i)*hy+pz2(i)*hz
         px3h4(i)=px3(i)*hx+ py3(i)*hy+pz3(i)*hz
         px4h4(i)=px4(i)*hx+ py4(i)*hy+pz4(i)*hz
       END DO
      RETURN
C
      END SUBROUTINE szderi3
!||====================================================================
!||    szderit3   ../engine/source/elements/solid/solidez/szderi3.F
!||--- called by ------------------------------------------------------
!||    szforc3    ../engine/source/elements/solid/solidez/szforc3.F
!||--- calls      -----------------------------------------------------
!||    schkjab3   ../engine/source/elements/solid/solide/schkjab3.F
!||====================================================================
      SUBROUTINE szderit3(
     1   OFF,     DET,     NGL,     NEL,
     2   X1,      X2,      X3,      X4,
     3   X5,      X6,      X7,      X8,
     4   Y1,      Y2,      Y3,      Y4,
     5   Y5,      Y6,      Y7,      Y8,
     6   Z1,      Z2,      Z3,      Z4,
     7   Z5,      Z6,      Z7,      Z8,
     8   PX1,     PX2,     PX3,     PX4,
     9   PY1,     PY2,     PY3,     PY4,
     A   PZ1,     PZ2,     PZ3,     PZ4,
     B   PX1H1,   PX1H2,   PX1H3,   PX1H4,
     C   PX2H1,   PX2H2,   PX2H3,   PX2H4,
     D   PX3H1,   PX3H2,   PX3H3,   PX3H4,
     E   PX4H1,   PX4H2,   PX4H3,   PX4H4,
     F   JAC1,    JAC2,    JAC3,    JAC4,
     G   JAC5,    JAC6,    JAC9,    JLAG)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: JLAG
      INTEGER :: NEL,NGL(*)
      DOUBLE PRECISION
     .   X1(*), X2(*), X3(*), X4(*), X5(*), X6(*), X7(*), X8(*),
     .   y1(*), y2(*), y3(*), y4(*), y5(*), y6(*), y7(*), y8(*),  
     .   z1(*), z2(*), z3(*), z4(*), z5(*), z6(*), z7(*), z8(*)
      my_real
     .   off(*),det(*),  
     .   px1(*), px2(*), px3(*), px4(*),  
     .   py1(*), py2(*), py3(*), py4(*),  
     .   pz1(*), pz2(*), pz3(*), pz4(*),  
     .   px1h1(*), px1h2(*), px1h3(*),px1h4(*),  
     .   px2h1(*), px2h2(*), px2h3(*),px2h4(*),  
     .   px3h1(*), px3h2(*), px3h3(*),px3h4(*),  
     .   px4h1(*), px4h2(*), px4h3(*),px4h4(*),  
     .   jac1(*),jac2(*),jac3(*),
     .   jac4(*),jac5(*),jac6(*),jac9(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I
C                                                                     12
      my_real
     .   DETT ,  JAC7(MVSIZ), JAC8(MVSIZ) , 
     .   JACI1, JACI2, JACI3,
     .   JACI4, JACI5, JACI6,
     .   JACI7, JACI8, JACI9,
     .   X17 , X28 , X35 , X46,
     .   Y17 , Y28 , Y35 , Y46,
     .   Z17 , Z28 , Z35 , Z46,
     .   JAC_59_68(MVSIZ), JAC_67_49(MVSIZ), JAC_48_57(MVSIZ),
     .   JACI12, JACI45, JACI78,
     .   X_17_46 , X_28_35 ,
     .   y_17_46 , y_28_35 ,
     .   z_17_46 , z_28_35 ,
     .   hx,hy,hz
C-----------------------------------------------
C
C Jacobian matrix
      DO i=1,nel
       x17=x7(i)-x1(i)
       x28=x8(i)-x2(i)
       x35=x5(i)-x3(i)
       x46=x6(i)-x4(i)
       y17=y7(i)-y1(i)
       y28=y8(i)-y2(i)
       y35=y5(i)-y3(i)
       y46=y6(i)-y4(i)
       z17=z7(i)-z1(i)
       z28=z8(i)-z2(i)
       z35=z5(i)-z3(i)
       z46=z6(i)-z4(i)
C
       jac4(i)=x17+x28-x35-x46
       jac5(i)=y17+y28-y35-y46
       jac6(i)=z17+z28-z35-z46
C
       x_17_46=x17+x46
       x_28_35=x28+x35
       y_17_46=y17+y46
       y_28_35=y28+y35
       z_17_46=z17+z46
       z_28_35=z28+z35
C
       jac7(i)=x_17_46+x_28_35
       jac8(i)=y_17_46+y_28_35
       jac9(i)=z_17_46+z_28_35
       jac1(i)=x_17_46-x_28_35
       jac2(i)=y_17_46-y_28_35
       jac3(i)=z_17_46-z_28_35
      ENDDO
C
      DO i=1,nel
      jac_59_68(i)=jac5(i)*jac9(i)-jac6(i)*jac8(i)
      jac_67_49(i)=jac6(i)*jac7(i)-jac4(i)*jac9(i)
      jac_48_57(i)=jac4(i)*jac8(i)-jac5(i)*jac7(i)
      END DO
C
      DO i=1,nel
      det(i)=one_over_64*(jac1(i)*jac_59_68(i)+jac2(i)*jac_67_49(i)+jac3(i)*jac_48_57(i))
      END DO
C
      CALL schkjab3(
     1   off,     det,     ngl,     nel)
C
C Jacobian matrix inverse and shape functions derivatives Pij
      DO i=1,nel
        dett=one_over_64/det(i)
        jaci1=dett*jac_59_68(i)
        jaci4=dett*jac_67_49(i)
        jaci7=dett*jac_48_57(i)
        jaci2=dett*(-jac2(i)*jac9(i)+jac3(i)*jac8(i))
        jaci5=dett*( jac1(i)*jac9(i)-jac3(i)*jac7(i))
        jaci8=dett*(-jac1(i)*jac8(i)+jac2(i)*jac7(i))
        jaci3=dett*( jac2(i)*jac6(i)-jac3(i)*jac5(i))
        jaci6=dett*(-jac1(i)*jac6(i)+jac3(i)*jac4(i))
        jaci9=dett*( jac1(i)*jac5(i)-jac2(i)*jac4(i))
C
        jaci12=jaci1-jaci2
        jaci45=jaci4-jaci5
        jaci78=jaci7-jaci8
 
        px2(i)= jaci12-jaci3
        py2(i)= jaci45-jaci6
        pz2(i)= jaci78-jaci9
        px4(i)=-jaci12-jaci3
        py4(i)=-jaci45-jaci6
        pz4(i)=-jaci78-jaci9
 
        jaci12=jaci1+jaci2
        jaci45=jaci4+jaci5
        jaci78=jaci7+jaci8
 
        px1(i)=-jaci12-jaci3
        py1(i)=-jaci45-jaci6
        pz1(i)=-jaci78-jaci9
        px3(i)=jaci12-jaci3
        py3(i)=jaci45-jaci6
        pz3(i)=jaci78-jaci9
      ENDDO
C
      DO i=1,nel
C 1 -1 1 -1 1 -1 1 -1
         hx=one_over_8*(x1(i)-x2(i)+x3(i)-x4(i)+x5(i)-x6(i)+x7(i)-x8(i))
         hy=one_over_8*(y1(i)-y2(i)+y3(i)-y4(i)+y5(i)-y6(i)+y7(i)-y8(i))
         hz=one_over_8*(z1(i)-z2(i)+z3(i)-z4(i)+z5(i)-z6(i)+z7(i)-z8(i))   
         px1h3(i)=px1(i)*hx+ py1(i)*hy+pz1(i)*hz
         px2h3(i)=px2(i)*hx+ py2(i)*hy+pz2(i)*hz
         px3h3(i)=px3(i)*hx+ py3(i)*hy+pz3(i)*hz
         px4h3(i)=px4(i)*hx+ py4(i)*hy+pz4(i)*hz
      END DO
C 1 1 -1 -1 -1 -1 1 1
      DO i=1,nel
         hx=one_over_8*(x1(i)+x2(i)-x3(i)-x4(i)-x5(i)-x6(i)+x7(i)+x8(i))
         hy=one_over_8*(y1(i)+y2(i)-y3(i)-y4(i)-y5(i)-y6(i)+y7(i)+y8(i))
         hz=one_over_8*(z1(i)+z2(i)-z3(i)-z4(i)-z5(i)-z6(i)+z7(i)+z8(i))   
         px1h1(i)=px1(i)*hx+ py1(i)*hy+pz1(i)*hz
         px2h1(i)=px2(i)*hx+ py2(i)*hy+pz2(i)*hz
         px3h1(i)=px3(i)*hx+ py3(i)*hy+pz3(i)*hz
         px4h1(i)=px4(i)*hx+ py4(i)*hy+pz4(i)*hz
      END DO
C 1 -1 -1 1 -1 1 1 -1
      DO i=1,nel
         hx=one_over_8*(x1(i)-x2(i)-x3(i)+x4(i)-x5(i)+x6(i)+x7(i)-x8(i))
         hy=one_over_8*(y1(i)-y2(i)-y3(i)+y4(i)-y5(i)+y6(i)+y7(i)-y8(i))
         hz=one_over_8*(z1(i)-z2(i)-z3(i)+z4(i)-z5(i)+z6(i)+z7(i)-z8(i))   
         px1h2(i)=px1(i)*hx+ py1(i)*hy+pz1(i)*hz
         px2h2(i)=px2(i)*hx+ py2(i)*hy+pz2(i)*hz
         px3h2(i)=px3(i)*hx+ py3(i)*hy+pz3(i)*hz
         px4h2(i)=px4(i)*hx+ py4(i)*hy+pz4(i)*hz
      END DO
C -1 1 -1 1 1 -1 1 -1
      DO i=1,nel
         hx=one_over_8*(-x1(i)+x2(i)-x3(i)+x4(i)+x5(i)-x6(i)+x7(i)-x8(i))
         hy=one_over_8*(-y1(i)+y2(i)-y3(i)+y4(i)+y5(i)-y6(i)+y7(i)-y8(i))
         hz=one_over_8*(-z1(i)+z2(i)-z3(i)+z4(i)+z5(i)-z6(i)+z7(i)-z8(i))   
         px1h4(i)=px1(i)*hx+ py1(i)*hy+pz1(i)*hz
         px2h4(i)=px2(i)*hx+ py2(i)*hy+pz2(i)*hz
         px3h4(i)=px3(i)*hx+ py3(i)*hy+pz3(i)*hz
         px4h4(i)=px4(i)*hx+ py4(i)*hy+pz4(i)*hz
      END DO
      RETURN
C
      END SUBROUTINE szderit3
!||====================================================================
!||    szderito3   ../engine/source/elements/solid/solidez/szderi3.F
!||--- called by ------------------------------------------------------
!||    szforc3     ../engine/source/elements/solid/solidez/szforc3.F
!||====================================================================
      SUBROUTINE szderito3(
     1   OFF,     DET,     PX1,     PX2,
     2   PX3,     PX4,     PY1,     PY2,
     3   PY3,     PY4,     PZ1,     PZ2,
     4   PZ3,     PZ4,     JAC_I,   NEL,
     5   JLAG)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: JLAG
      INTEGER :: NEL
      my_real
     .   off(*),det(*),  
     .   px1(*), px2(*), px3(*), px4(*),  
     .   py1(*), py2(*), py3(*), py4(*),  
     .   pz1(*), pz2(*), pz3(*), pz4(*),  
     .   jac_i(10,mvsiz)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
C                                                                     12
      my_real
     .   jaci1, jaci2, jaci3,
     .   jaci4, jaci5, jaci6,
     .   jaci7, jaci8, jaci9,
     .   jaci12, jaci45, jaci78
C-----------------------------------------------
C----JAC_I is calculated based on H8, permutation :[t,r,s]:[r,s,t]
      DO i=1,nel
        jaci1=jac_i(3,i)
        jaci4=jac_i(6,i)
        jaci7=jac_i(9,i)
        jaci2=jac_i(1,i)
        jaci5=jac_i(4,i)
        jaci8=jac_i(7,i)
        jaci3=jac_i(2,i)
        jaci6=jac_i(5,i)
        jaci9=jac_i(8,i)
        det(i) =jac_i(10,i)
C      
        jaci12=jaci1-jaci2
        jaci45=jaci4-jaci5
        jaci78=jaci7-jaci8
        px2(i)= jaci12-jaci3
        py2(i)= jaci45-jaci6
        pz2(i)= jaci78-jaci9
        px4(i)=-jaci12-jaci3
        py4(i)=-jaci45-jaci6
        pz4(i)=-jaci78-jaci9
C
        jaci12=jaci1+jaci2
        jaci45=jaci4+jaci5
        jaci78=jaci7+jaci8
        px1(i)=-jaci12-jaci3
        py1(i)=-jaci45-jaci6
        pz1(i)=-jaci78-jaci9
        px3(i)= jaci12-jaci3
        py3(i)= jaci45-jaci6
        pz3(i)= jaci78-jaci9
      ENDDO
C
      RETURN
C
      END SUBROUTINE szderito3