s6cortho3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    s6cortho3   ../engine/source/elements/thickshell/solide6c/s6cortho3.F
!||--- called by ------------------------------------------------------
!||    s6rcoor3    ../engine/source/elements/thickshell/solide6c/s6rcoor3.F
!||    s6rcoork    ../engine/source/elements/thickshell/solide6c/s6rcoork.F
!||====================================================================
      SUBROUTINE s6cortho3(
     1   X1,      X2,      X3,      X4,
     2   X5,      X6,      Y1,      Y2,
     3   Y3,      Y4,      Y5,      Y6,
     4   Z1,      Z2,      Z3,      Z4,
     5   Z5,      Z6,      E1X,     E2X,
     6   E3X,     E1Y,     E2Y,     E3Y,
     7   E1Z,     E2Z,     E3Z,     RX,
     8   RY,      RZ,      SX,      SY,
     9   SZ,      TX,      TY,      TZ,
     A   NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
C     REAL
      my_real, INTENT(IN),  DIMENSION(MVSIZ) ::
     .   X1, X2, X3, X4, X5, X6, 
     .   Y1, Y2, Y3, Y4, Y5, Y6,   
     .   Z1, Z2, Z3, Z4, Z5, Z6
      my_real, INTENT(OUT),  DIMENSION(MVSIZ) ::
     .   RX, RY, RZ, SX, SY, SZ, TX, TY, TZ,
     .   E1X, E1Y, E1Z, E2X, E2Y, E2Z, E3X, E3Y, E3Z
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
C     REAL
      my_real
     .   x14 ,y14 , z14
      my_real
     .   det,c1,c2 
C-----------------------------------------------
      DO i=1,nel
        x14=x1(i)+x4(i)
        y14=y1(i)+y4(i)
        z14=z1(i)+z4(i)
C--------ksi---------
        tx(i)=x2(i)+x5(i)-x14
        ty(i)=y2(i)+y5(i)-y14
        tz(i)=z2(i)+z5(i)-z14
C--------eta---------
        rx(i)=x3(i)+x6(i)-x14
        ry(i)=y3(i)+y6(i)-y14
        rz(i)=z3(i)+z6(i)-z14
       ENDDO
      DO i=1,nel
        sx(i)= (x4(i)+x5(i)+x6(i)-x1(i)-x2(i)-x3(i))*third
        sy(i)= (y4(i)+y5(i)+y6(i)-y1(i)-y2(i)-y3(i))*third
        sz(i)= (z4(i)+z5(i)+z6(i)-z1(i)-z2(i)-z3(i))*third
      ENDDO
c~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
      DO 100 i=1,nel
C
       e3x(i) = ty(i) * rz(i) - tz(i) * ry(i) 
       e3y(i) = tz(i) * rx(i) - tx(i) * rz(i) 
       e3z(i) = tx(i) * ry(i) - ty(i) * rx(i) 
C
       det = sqrt(e3x(i)*e3x(i) + e3y(i)*e3y(i) + e3z(i)*e3z(i))
       IF ( det/=zero) det = one / det
       e3x(i) = e3x(i) * det
       e3y(i) = e3y(i) * det
       e3z(i) = e3z(i) * det
C
       c1=sqrt(tx(i)*tx(i)+ty(i)*ty(i)+tz(i)*tz(i))
       c2=sqrt(rx(i)*rx(i)+ry(i)*ry(i)+rz(i)*rz(i))
       e1x(i)=tx(i)*c2 +(ry(i) * e3z(i) - rz(i) * e3y(i))*c1  
       e1y(i)=ty(i)*c2 +(rz(i) * e3x(i) - rx(i) * e3z(i))*c1  
       e1z(i)=tz(i)*c2 +(rx(i) * e3y(i) - ry(i) * e3x(i))*c1
       det = sqrt(e1x(i)*e1x(i) + e1y(i)*e1y(i) + e1z(i)*e1z(i))
       IF ( det/=zero) det = one / det
       e1x(i) = e1x(i)*det
       e1y(i) = e1y(i)*det
       e1z(i) = e1z(i)*det
C
       e2x(i) = e3y(i) * e1z(i) - e3z(i) * e1y(i)
       e2y(i) = e3z(i) * e1x(i) - e3x(i) * e1z(i)
       e2z(i) = e3x(i) * e1y(i) - e3y(i) * e1x(i)
 100  CONTINUE
c~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
      RETURN
      END