sdlensh14.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    sdlensh14   ../engine/source/elements/thickshell/solide8c/sdlensh14.F
!||--- called by ------------------------------------------------------
!||    s8cforc3    ../engine/source/elements/thickshell/solide8c/s8cforc3.f
!||====================================================================
      SUBROUTINE sdlensh14(
     1   VOLN,    LLSH, AREA, X1,      X2,
     2   X3,      X4,      X5,      X6,
     3   X7,      X8,      Y1,      Y2,
     4   Y3,      Y4,      Y5,      Y6,
     5   Y7,      Y8,      Z1,      Z2,
     6   Z3,      Z4,      Z5,      Z6,
     7   Z7,      Z8,      ICS ,   NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL,ICS
      my_real, DIMENSION(MVSIZ) , INTENT(OUT)  :: AREA,LLSH 
      my_real, DIMENSION(MVSIZ) , INTENT(IN)  ::  
     .   VOLN,
     .   X1, X2, X3, X4, X5, X6, X7, X8,
     .   Y1, Y2, Y3, Y4, Y5, Y6, Y7, Y8,  
     .   Z1, Z2, Z3, Z4, Z5, Z6, Z7, Z8
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, J, N
      my_real
     .   RX(MVSIZ),RY(MVSIZ),RZ(MVSIZ),SX(MVSIZ),SY(MVSIZ),SZ(MVSIZ),
     .   XN(MVSIZ,4) , YN(MVSIZ,4) , ZN(MVSIZ,4) 
      my_real
     .   AL1,AL2,E3X,E3Y,E3Z,DET
C=======================================================================
        SELECT CASE(ics)
          CASE (1)
            DO i=1,nel
              xn(i,1) = half*(x1(i)+x4(i))
              yn(i,1) = half*(y1(i)+y4(i))
              zn(i,1) = half*(z1(i)+z4(i))
              xn(i,2) = half*(x2(i)+x3(i))
              yn(i,2) = half*(y2(i)+y3(i))
              zn(i,2) = half*(z2(i)+z3(i))
              xn(i,3) = half*(x6(i)+x7(i))
              yn(i,3) = half*(y6(i)+y7(i))
              zn(i,3) = half*(z6(i)+z7(i))
              xn(i,4) = half*(x5(i)+x8(i))
              yn(i,4) = half*(y5(i)+y8(i))
              zn(i,4) = half*(z5(i)+z8(i))
            ENDDO 
          CASE (10)
            DO i=1,nel
              xn(i,1) = half*(x1(i)+x5(i))
              yn(i,1) = half*(y1(i)+y5(i))
              zn(i,1) = half*(z1(i)+z5(i))
              xn(i,2) = half*(x2(i)+x6(i))
              yn(i,2) = half*(y2(i)+y6(i))
              zn(i,2) = half*(z2(i)+z6(i))
              xn(i,3) = half*(x3(i)+x7(i))
              yn(i,3) = half*(y3(i)+y7(i))
              zn(i,3) = half*(z3(i)+z7(i))
              xn(i,4) = half*(x4(i)+x8(i))
              yn(i,4) = half*(y4(i)+y8(i))
              zn(i,4) = half*(z4(i)+z8(i))
            ENDDO 
          CASE (100)
            DO i=1,nel
              xn(i,1) = half*(x1(i)+x2(i))
              yn(i,1) = half*(y1(i)+y2(i))
              zn(i,1) = half*(z1(i)+z2(i))
              xn(i,2) = half*(x5(i)+x6(i))
              yn(i,2) = half*(y5(i)+y6(i))
              zn(i,2) = half*(z5(i)+z6(i))
              xn(i,3) = half*(x8(i)+x7(i))
              yn(i,3) = half*(y8(i)+y7(i))
              zn(i,3) = half*(z8(i)+z7(i))
              xn(i,4) = half*(x4(i)+x3(i))
              yn(i,4) = half*(y4(i)+y3(i))
              zn(i,4) = half*(z4(i)+z3(i))
            ENDDO 
        END SELECT
C------g1,g2 :
        DO i=1,nel
          rx(i)=xn(i,2)+xn(i,3)-xn(i,1)-xn(i,4)
          ry(i)=yn(i,2)+yn(i,3)-yn(i,1)-yn(i,4)
          rz(i)=zn(i,2)+zn(i,3)-zn(i,1)-zn(i,4)
          sx(i)=xn(i,3)+xn(i,4)-xn(i,1)-xn(i,2)
          sy(i)=yn(i,3)+yn(i,4)-yn(i,1)-yn(i,2)
          sz(i)=zn(i,3)+zn(i,4)-zn(i,1)-zn(i,2)
        ENDDO 
        DO i=1,nel
          e3x = ry(i) * sz(i) - rz(i) * sy(i) 
          e3y = rz(i) * sx(i) - rx(i) * sz(i) 
          e3z = rx(i) * sy(i) - ry(i) * sx(i) 
          det = sqrt(e3x*e3x + e3y*e3y + e3z*e3z)
          area(i)=fourth*det
          al1 = rx(i)*rx(i) + ry(i)*ry(i)+ rz(i)*rz(i)
          al2 = sx(i)*sx(i) + sy(i)*sy(i)+ sz(i)*sz(i)
          llsh(i) = fourth*max(al1,al2)
        ENDDO 
C
      RETURN
      END