write_mat_table.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    write_mat_table   ../engine/source/materials/tools/write_mat_table.F
!||--- called by ------------------------------------------------------
!||    write_eosparam    ../engine/source/output/restart/write_eosparam.F90
!||    write_matparam    ../engine/source/output/restart/write_matparam.F
!||    write_viscparam   ../engine/source/output/restart/write_viscparam.F
!||--- calls      -----------------------------------------------------
!||    write_db          ../common_source/tools/input_output/write_db.F
!||    write_i_c         ../common_source/tools/input_output/write_routtines.c
!||--- uses       -----------------------------------------------------
!||    table4d_mod       ../common_source/modules/table4d_mod.F
!||====================================================================
      SUBROUTINE write_mat_table(TABLE, NUMTABL)
C-----------------------------------------------
      USE table4d_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ,INTENT(IN)    :: NUMTABL
      TYPE(table_4d_) ,INTENT(IN) :: TABLE(NUMTABL)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,K,L,M,N,LEN,NPT,NDIM
      INTEGER LDIM(4)
      my_real, DIMENSION(:) ,ALLOCATABLE :: ytmp
c===============================================
      DO n=1,numtabl
        len  = 1
        CALL write_i_c(table(n)%NOTABLE,len)
        ndim = table(n)%NDIM
        CALL write_i_c(ndim,len)
        DO i=1,ndim
          npt = SIZE(table(n)%X(i)%VALUES)
          CALL write_i_c(npt , len)
          CALL write_db(table(n)%X(i)%VALUES,npt)
          ldim(i) = npt 
        END DO
c
        npt = ldim(1)
        IF (ndim == 1) THEN
          CALL write_db(table(n)%Y1D,npt)
          len = npt
        ELSE IF (ndim == 2) THEN
          len = ldim(1)*ldim(2)
          ALLOCATE(ytmp(len))
          m = 0
          DO j=1,ldim(2)
            DO i=1,npt
              m = m+1
              ytmp(m) = table(n)%Y2D(i,j)
            END DO
          END DO
          CALL write_db(ytmp, len)
        ELSE IF (ndim == 3) THEN
          len = ldim(1)*ldim(2)*ldim(3)
          ALLOCATE(ytmp(len))
          m = 0
          DO k=1,ldim(3)
            DO j=1,ldim(2)
              DO i=1,npt
                m = m+1
                ytmp(m) = table(n)%Y3D(i,j,k)
              END DO
            END DO
          END DO
          CALL write_db(ytmp, len)
        ELSE IF (ndim == 4) THEN
          len = ldim(1)*ldim(2)*ldim(3)*ldim(4)
          ALLOCATE(ytmp(len))
          m = 0
          DO l=1,ldim(4)
            DO k=1,ldim(3)
              DO j=1,ldim(2)
                DO i=1,npt
                  m = m+1
                  ytmp(m) = table(n)%Y4D(i,j,k,l)
                END DO
              END DO
            END DO
          END DO
          CALL write_db(ytmp, len)
        END IF
        IF (ALLOCATED(ytmp)) DEALLOCATE(ytmp)
      END DO
c-----------
      RETURN
      END SUBROUTINE write_mat_table