anioffc.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    anioffc           ../engine/source/output/anim/generate/anioffc.F
!||--- called by ------------------------------------------------------
!||    genani            ../engine/source/output/anim/generate/genani.F
!||--- calls      -----------------------------------------------------
!||    spmd_iget_partn   ../engine/source/mpi/anim/spmd_iget_partn.F
!||    write_c_c         ../common_source/tools/input_output/write_routines.c
!||--- uses       -----------------------------------------------------
!||    elbufdef_mod      ../common_source/modules/mat_elem/elbufdef_mod.f90
!||    my_alloc_mod      ../common_source/tools/memory/my_alloc.F90
!||====================================================================
      SUBROUTINE anioffc(ELBUF_TAB,IPARG ,IOFF   ,EL2FA,NBF    ,
     .                   IADD ,NBF_L ,NBPART ,IADG ,NODGLOB,
     .                   IPART,IPARTC,IPARTTG)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE elbufdef_mod        
      USE my_alloc_mod    
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "remesh_c.inc"
#include      "scr17_c.inc"
#include      "spmd_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
C     REAL
      INTEGER IPARG(NPARG,*),EL2FA(*),NBF,IOFF(*),
     .        IADD(*),NBF_L,NBPART, IADG(NSPMD,*),NODGLOB(*),
     .        ipart(lipart1,*), ipartc(*), iparttg(*)
      TYPE (ELBUF_STRUCT_), TARGET, DIMENSION(NGROUP) :: ELBUF_TAB
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
C     REAL
      INTEGER I, NG, NEL, NFT, IAD, ITY, LFT, NPT,
     . LLT, MLW,NBX,IP,
     . nn1,nn2,nn3,nn4,nn5,nn6,nn7,nn8,nn9,nn10,
     . n_fa, ihbe, istrain, iexpan, iseatbelt
      INTEGER RBUF
      INTEGER,DIMENSION(:),ALLOCATABLE :: IOFFBUF
      TYPE(g_bufel_)  ,POINTER :: GBUF     
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7--
      CALL my_alloc(ioffbuf,nbf_l)
      nn1 = 1
      nn2 = 1
      nn3 = 1
      nn4 = nn3 + numelq
      nn5 = nn4 + numelc
      nn6 = nn5 + numeltg
      nn7 = nn6 
      nn8 = nn7 
      nn9 = nn8 
      nn10= nn9
C-----------------------------------------------
C
      DO ng=1,ngroup
        mlw   =iparg(1,ng)
        nel   =iparg(2,ng)
        ity   =iparg(5,ng)
        nft   =iparg(3,ng)
        iad   =iparg(4,ng)
        iseatbelt = iparg(91,ng)
        lft=1
        llt=nel
        nbx = iad - 1
        gbuf => elbuf_tab(ng)%GBUF
C-----------------------------------------------
C       QUAD
C-----------------------------------------------
        IF (ity == 2) THEN          
          n_fa = nn3 + nft
C-----------------------------------------------
C       COQUES 4 N
C-----------------------------------------------
        ELSEIF(ity == 3)THEN
          ihbe = iparg(23,ng)
          npt    =iparg(6,ng)
          istrain=iparg(44,ng)
          iexpan=iparg(49,ng)
          n_fa = nn4 + nft
C-----------------------------------------------
C       COQUES 3 N
C-----------------------------------------------
        ELSEIF(ity == 7)THEN
          npt    =iparg(6,ng)
          istrain=iparg(44,ng)
          iexpan=iparg(49,ng)
          n_fa = nn5 + nft
C-----------------------------------------------
C       RNUR
C-----------------------------------------------
        ELSEIF(ity == 50)THEN
          n_fa = nn9 + nft
        ELSE
          ity=0
        ENDIF
C-----------------------------------------------
        IF  (ity /= 0) THEN
         IF (mlw == 0 .OR. mlw == 13 .OR. iseatbelt == 1)THEN
C-----------------------------------------------
C         DUMMY ELEMENTS
C-----------------------------------------------
          DO i=lft,llt
            ioff(el2fa(n_fa+i)) = 1
          ENDDO
         ELSE
C-----------------------------------------------
C         OFF
C-----------------------------------------------
          IF (ity == 2) THEN
            DO i=lft,llt
              ioff(el2fa(n_fa+i)) = nint(min(gbuf%OFF(i),one))
            ENDDO
          ELSEIF (nadmesh==0 .AND. (ity==3 .OR. ity==7)) THEN
            DO i=lft,llt
              ioff(el2fa(n_fa+i)) = nint(min(gbuf%OFF(i),one))
            ENDDO
          ELSEIF (ity == 3) THEN
            DO i=lft,llt
              ip=ipartc(nft+i)
              IF(ipart(10,ip)>0)THEN
                ioff(el2fa(n_fa+i))=nint(max(zero,min(gbuf%OFF(i),one)))
              ELSE
                ioff(el2fa(n_fa+i))=nint(min(gbuf%OFF(i),one))
              END IF
            ENDDO
          ELSEIF (ity ==7 ) THEN
            DO i=lft,llt
              ip=iparttg(nft+i)
              IF(ipart(10,ip)>0)THEN
                ioff(el2fa(n_fa+i))=nint(max(zero,min(gbuf%OFF(i),one)))
              ELSE
                ioff(el2fa(n_fa+i))=nint(min(gbuf%OFF(i),one))
              END IF
            ENDDO
          ENDIF
         ENDIF
        ENDIF
C-----------------------------------------------
      ENDDO
C-----------------------------------------------
      IF (nspmd == 1) THEN
        CALL write_c_c(ioff,nbf)
      ELSE
        DO i = 1, nbf_l
          ioffbuf(i) = ioff(i)
        ENDDO
         IF (ispmd == 0) THEN
          rbuf = (numelqg+numelcg+numeltgg)
          CALL spmd_iget_partn(1,nbf_l,ioffbuf,nbpart,iadg,rbuf,2)
        ELSE
          rbuf = 1
          CALL spmd_iget_partn(1,nbf_l,ioffbuf,nbpart,iadg,rbuf,2)
        END IF
      ENDIF
C-----------
      DEALLOCATE(ioffbuf)
      RETURN
      END