dmasanic.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    dmasanic       ../engine/source/output/anim/generate/dmasanic.F
!||--- called by ------------------------------------------------------
!||    genani         ../engine/source/output/anim/generate/genani.F
!||--- uses       -----------------------------------------------------
!||    elbufdef_mod   ../common_source/modules/mat_elem/elbufdef_mod.F90
!||    element_mod    ../common_source/modules/elements/element_mod.F90
!||    stack_mod      ../engine/share/modules/stack_mod.F
!||====================================================================
      SUBROUTINE dmasanic(ELBUF_TAB,X   ,D    ,GEO  ,IPARG,
     .                    IXQ  ,IXC  ,IXTG ,MAS  ,PM   ,
     .                    EL2FA,NBF  ,IGEO,STACK)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE elbufdef_mod 
      USE stack_mod
      use element_mod , only : nixq,nixc,nixtg       
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
C     REAL
      my_real
     .   mas(*) ,pm(npropm,*),geo(npropg,*),x(3,*),
     .   d(3,*)
      INTEGER IPARG(NPARG,*),IXC(NIXC,*),IXTG(NIXTG,*),
     .        IXQ(NIXQ,*),EL2FA(*),NBF,IGEO(NPROPGI,*)
      TYPE (ELBUF_STRUCT_), TARGET, DIMENSION(NGROUP) :: ELBUF_TAB
      TYPE (STACK_PLY) :: STACK
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
C     REAL
      my_real
     .   off, p, vonm2, vonm, s1, s2, s12, s3, VALUE,thk0,a0,al0,
     .   rho0,xx1,xx2,xx3,yy1,yy2,yy3,zz1,zz2,zz3
      INTEGER I, NG, NEL, NFT, IAD, ITY, LFT, NPT, 
     .        IADD, N, J, LLT, MLW, 
     .        istrain,nn, k1, k2,jturb,mt,jale, imid, ialel,ipid,
     .        n1,n2,n3,n4,
     .        nn1,nn2,nn3,nn4,nn5,nn6,nn7,nn8,nn9,nn10,
     .        offset,nel_old,ity_old,nft_fa,n_fa
      INTEGER ISUBSTACK, IGTYP
 
      TYPE(g_bufel_)  ,POINTER :: GBUF     
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7--
      nn1 = 1
      nn2 = 1
      nn3 = 1
      nn4 = nn3 + numelq
      nn5 = nn4 + numelc
      nn6 = nn5 + numeltg
      nn7 = nn6 
      nn8 = nn7 
      nn9 = nn8 
      nn10= nn9
C-----------------------------------------------
C
      nel_old = 0
      ity_old = 0
      DO 490 ng=1,ngroup
        gbuf => elbuf_tab(ng)%GBUF
        nel   =iparg(2,ng)
        ity   =iparg(5,ng)
        npt   =iabs(iparg(6,ng))
        IF (ispmd==0) THEN
          IF (ity/=ity_old) THEN
            nel_old = 0
            ity_old= ity
          ENDIF
          nft_fa = nel_old
          nel_old = nel_old + nel
        ENDIF
        nft   =iparg(3,ng)
        iad   =iparg(4,ng)
        lft=1
        llt=nel
        IF (ispmd==0) THEN
            nft_fa = nel_old - nel 
        ELSE
            nft_fa = nft
        ENDIF
C-----------------------------------------------
C       QUAD
C-----------------------------------------------
        IF(ity==2)THEN
         ialel=(iparg(7,ng)+iparg(11,ng))
C
         DO i=lft,llt
               n = i + nft
               n_fa = i + nft_fa
               IF(ialel==0)THEN
                 mt=ixq(1,n)
                 VALUE=pm(89,mt)*gbuf%VOL(i)
               ELSE
                 off = min(gbuf%OFF(i),one)
                 VALUE=gbuf%RHO(i)*gbuf%VOL(i)*off
               ENDIF
               mas(el2fa(nn3+n_fa)) = VALUE
         ENDDO
C-----------------------------------------------
C       COQUES 4 N
C-----------------------------------------------
        ELSEIF(ity==3)THEN
C
          isubstack=iparg(71,ng)
          igtyp   = iparg(38,ng)
          IF(igtyp /= 17 . and. igtyp /= 51 .AND. igtyp /= 52) THEN
            DO i=lft,llt
              n = i + nft
              n_fa = i + nft_fa
              rho0 = pm(1,ixc(1,n))
              thk0 = geo(1,ixc(6,n))
              n1 = ixc(2,n)
              n2 = ixc(3,n)
              n3 = ixc(4,n)
              n4 = ixc(5,n)
              xx1 = x(1,n3)-d(1,n3)-x(1,n1)+d(1,n1)
              yy1 = x(2,n3)-d(2,n3)-x(2,n1)+d(2,n1)
              zz1 = x(3,n3)-d(3,n3)-x(3,n1)+d(3,n1)
              xx2 = x(1,n4)-d(1,n4)-x(1,n2)+d(1,n2)
              yy2 = x(2,n4)-d(2,n4)-x(2,n2)+d(2,n2)
              zz2 = x(3,n4)-d(3,n4)-x(3,n2)+d(3,n2)
              xx3 = yy1*zz2 - zz1*yy2
              yy3 = zz1*xx2 - xx1*zz2
              zz3 = xx1*yy2 - yy1*xx2
              a0  = half*sqrt(xx3*xx3 + yy3*yy3 + zz3*zz3)
              mas(el2fa(nn4+n_fa)) = rho0*thk0*a0
            ENDDO
          ELSE
!!             IIGEO   =  40 + 5*(ISUBSTACK - 1) 
!!             IADR    = IGEO(IIGEO + 4,IXC(6,NFT + 1))
!!             NTHK   =  IADR + 3*NPT 
            DO i=lft,llt
              n = i + nft
              n_fa = i + nft_fa
              rho0 = pm(1,ixc(1,n))
              thk0 = stack%GEO(1,isubstack)
              n1 = ixc(2,n)
              n2 = ixc(3,n)
              n3 = ixc(4,n)
              n4 = ixc(5,n)
              xx1 = x(1,n3)-d(1,n3)-x(1,n1)+d(1,n1)
              yy1 = x(2,n3)-d(2,n3)-x(2,n1)+d(2,n1)
              zz1 = x(3,n3)-d(3,n3)-x(3,n1)+d(3,n1)
              xx2 = x(1,n4)-d(1,n4)-x(1,n2)+d(1,n2)
              yy2 = x(2,n4)-d(2,n4)-x(2,n2)+d(2,n2)
              zz2 = x(3,n4)-d(3,n4)-x(3,n2)+d(3,n2)
              xx3 = yy1*zz2 - zz1*yy2
              yy3 = zz1*xx2 - xx1*zz2
              zz3 = xx1*yy2 - yy1*xx2
              a0  = half*sqrt(xx3*xx3 + yy3*yy3 + zz3*zz3)
              mas(el2fa(nn4+n_fa)) = rho0*thk0*a0
            ENDDO 
          ENDIF 
C-----------------------------------------------
C       COQUES 3 N
C-----------------------------------------------
        ELSEIF(ity==7)THEN
C       
          isubstack=iparg(71,ng)
          igtyp   = iparg(38,ng)
          IF(igtyp /= 17 . and. igtyp /= 51 .AND. igtyp /= 52) THEN
          DO i=lft,llt
            n = i + nft
            n_fa = i + nft_fa
            rho0 = pm(1,ixtg(1,n))
            thk0 = geo(1,ixtg(5,n))
            n1 = ixtg(2,n)
            n2 = ixtg(3,n)
            n3 = ixtg(4,n)
            xx1 = x(1,n2)-d(1,n2)-x(1,n1)+d(1,n1)
            yy1 = x(2,n2)-d(2,n2)-x(2,n1)+d(2,n1)
            zz1 = x(3,n2)-d(3,n2)-x(3,n1)+d(3,n1)
            xx2 = x(1,n3)-d(1,n3)-x(1,n1)+d(1,n1)
            yy2 = x(2,n3)-d(2,n3)-x(2,n1)+d(2,n1)
            zz2 = x(3,n3)-d(3,n3)-x(3,n1)+d(3,n1)
            xx3 = yy1*zz2 - zz1*yy2
            yy3 = zz1*xx2 - xx1*zz2
            zz3 = xx1*yy2 - yy1*xx2
            a0  = half*sqrt(xx3*xx3 + yy3*yy3 + zz3*zz3)
            mas(el2fa(nn5+n_fa)) = rho0*thk0*a0
          ENDDO
          ELSE
              n = 1 + nft 
!!             IIGEO   =  40 + 5*(ISUBSTACK - 1) 
!!             IADR    = IGEO(IIGEO + 4,IXC(6,N))
!!             NTHK   =  IADR + 3*NPT 
             DO i=lft,llt
              n = i + nft
              n_fa = i + nft_fa
              rho0 = pm(1,ixtg(1,n))
              thk0 = stack%GEO(1,isubstack)
              n1 = ixtg(2,n)
              n2 = ixtg(3,n)
              n3 = ixtg(4,n)
              xx1 = x(1,n2)-d(1,n2)-x(1,n1)+d(1,n1)
              yy1 = x(2,n2)-d(2,n2)-x(2,n1)+d(2,n1)
              zz1 = x(3,n2)-d(3,n2)-x(3,n1)+d(3,n1)
              xx2 = x(1,n3)-d(1,n3)-x(1,n1)+d(1,n1)
              yy2 = x(2,n3)-d(2,n3)-x(2,n1)+d(2,n1)
              zz2 = x(3,n3)-d(3,n3)-x(3,n1)+d(3,n1)
              xx3 = yy1*zz2 - zz1*yy2
              yy3 = zz1*xx2 - xx1*zz2
              zz3 = xx1*yy2 - yy1*xx2
              a0  = half*sqrt(xx3*xx3 + yy3*yy3 + zz3*zz3)
              mas(el2fa(nn5+n_fa)) = rho0*thk0*a0
             ENDDO       
          ENDIF
C
        ELSE
        ENDIF
C-----------------------------------------------
C       end of loop over offsets
C-----------------------------------------------
 490  CONTINUE
C-----------------------------------------------
C
      RETURN
      END