write_sensors.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    write_sensors          ../engine/source/output/restart/write_sensors.F
!||--- called by ------------------------------------------------------
!||    wrrestp                ../engine/source/output/restart/wrrestp.F
!||--- calls      -----------------------------------------------------
!||    fretitl                ../engine/source/input/freform.F
!||    write_db               ../common_source/tools/input_output/write_db.F
!||    write_dpdb             ../common_source/tools/input_output/write_db.f
!||    write_i_c              ../common_source/tools/input_output/write_routtines.c
!||--- uses       -----------------------------------------------------
!||    names_and_titles_mod   ../common_source/modules/names_and_titles_mod.F
!||    sensor_mod             ../common_source/modules/sensor_mod.F90
!||====================================================================
      SUBROUTINE write_sensors(SENSORS)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE sensor_mod
      USE names_and_titles_mod, ONLY: nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include "implicit_f.inc"
#include "scr07_c.inc"
#include "scr17_c.inc"
#include "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (SENSORS_) ,INTENT(IN) ,TARGET :: SENSORS
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,ISEN,LEN,IAD,NFIX,NPARI,NPARR,NVAR,TYP
      INTEGER, DIMENSION(LTITR) :: ITITLE
      my_real, DIMENSION(:), ALLOCATABLE :: rbuf
      CHARACTER(LEN = NCHARTITLE) :: TITLE
      TYPE (SENSOR_STR_) ,POINTER :: SENSOR
C=======================================================================
      nfix = 11
c
      IF (sensors%NSENSOR > 0) THEN
        DO isen = 1,sensors%NSENSOR
          sensor => sensors%SENSOR_TAB(isen)
          typ   = sensor%TYPE 
          npari = sensor%NPARI
          nparr = sensor%NPARR
          nvar  = sensor%NVAR
          title = sensor%TITLE
          
          len = nfix + npari + nparr + nvar
          ALLOCATE (rbuf(len) )
c
          iad = 0
          rbuf(iad+1) = sensor%TYPE    
          rbuf(iad+2) = sensor%SENS_ID 
          rbuf(iad+3) = sensor%STATUS  
          rbuf(iad+4) = sensor%TCRIT 
          rbuf(iad+5) = sensor%TMIN  
          rbuf(iad+6) = sensor%TDELAY
          rbuf(iad+7) = sensor%TSTART
          rbuf(iad+8) = sensor%VALUE 
          rbuf(iad+9) = sensor%NPARI 
          rbuf(iad+10)= sensor%NPARR 
          rbuf(iad+11)= sensor%NVAR  
          iad = iad + nfix
c
          IF (npari > 0) THEN
            DO i = 1,npari
              rbuf(iad+i) = sensor%IPARAM(i)
            END DO
            iad = iad + npari
          END IF
          IF (nparr > 0) THEN
            DO i = 1,nparr
              rbuf(iad+i) = sensor%RPARAM(i)
            END DO
            iad = iad + nparr
          END IF        
          IF (nvar > 0) THEN
            DO i = 1,nvar
              rbuf(iad+i) = sensor%VAR(i)
            END DO
            iad = iad + nvar
          END IF
c
          CALL write_db (rbuf,len)
          DEALLOCATE (rbuf)
c
c         write sensor title
          CALL fretitl(title,ititle,ltitr)
          CALL write_i_c(ititle,ltitr)
c
          IF (typ==29.OR.typ==30.OR.typ==31)THEN
            CALL write_i_c(sensor%INTEGER_USERPARAM,nsenpari)
            CALL write_i_c(sensor%INTEGER_USERBUF,isenbuf)
 
            CALL write_db (sensor%FLOAT_USERPARAM,nsenparr)
            CALL write_db (sensor%FLOAT_USERBUF,lsenbuf)
 
          ENDIF
          IF(typ == 40 ) THEN
            CALL write_i_c(sensor%PYTHON_FUNCTION_ID,1)
          ENDIF
        END DO
c
c--------------------------------------
c       Write Logical sensor index array
c--------------------------------------
 
        CALL write_i_c(sensors%LOGICAL_SENSOR_COUNT,1)
        CALL write_i_c(sensors%LOGICAL_SENSORS_LIST,sensors%LOGICAL_SENSOR_COUNT)
c
c--------------------------------------
c       Write spmd/PON exchange arrays
c--------------------------------------
 
        CALL write_dpdb(sensors%FSAV,12*6*sensors%SFSAV)
        CALL write_i_c(sensors%TABSENSOR,sensors%STABSEN)
c--------------------------------------
c       Write sensor lists in engine output options (/STOP/LSENSOR, /STAT/LSENSOR...)
c       in case of chkpoint restart
        IF (wmcheck == 1) THEN
           CALL write_i_c(sensors%STOP ,sensors%NSTOP) ! Must be read at any chkpt restart
        ENDIF
 
        IF (ispmd == 0 .and. wmcheck == 1) THEN
          CALL write_i_c(sensors%STAT ,sensors%NSTAT)
          CALL write_i_c(sensors%OUTP ,sensors%NOUTP)
          CALL write_i_c(sensors%ANIM ,sensors%NANIM)
        END IF
c
      END IF
c-----------
      RETURN
      END