fail_johnson_b.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    fail_johnson_b   ../engine/source/materials/fail/johnson_cook/fail_johnson_b.F
!||--- called by ------------------------------------------------------
!||    fail_beam3       ../engine/source/elements/beam/fail_beam3.F
!||====================================================================
      SUBROUTINE fail_johnson_b(
     .           NEL      ,NGL      ,NUPARAM  ,UPARAM   ,
     .           TIME     ,TSTAR    ,SVM      ,PRESSURE ,
     .           DPLA     ,EPSD     ,OFF      ,DFMAX    ,
     .           TDEL     ,IOUT     ,ISTDO    )
C-----------------------------------------------
c    Johnson-Cook failure model for standard beams (TYPE 3)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include  "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include  "comlock.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER                     ,INTENT(IN)    :: NEL     ! size of element group
      INTEGER                     ,INTENT(IN)    :: NUPARAM ! size of parameter array
      INTEGER                     ,INTENT(IN)    :: IOUT    ! output file unit
      INTEGER                     ,INTENT(IN)    :: ISTDO   ! output file unit
      INTEGER ,DIMENSION(NEL)     ,INTENT(IN)    :: NGL     ! table of element identifiers
      my_real                     ,INTENT(IN)    :: time    ! current time
      my_real ,DIMENSION(NUPARAM) ,INTENT(IN)    :: uparam  ! failure model parameter array
      my_real ,DIMENSION(NEL)     ,INTENT(IN)    :: dpla    ! plastic strain increment
      my_real ,DIMENSION(NEL)     ,INTENT(IN)    :: svm     ! Von Mises stress
      my_real ,DIMENSION(NEL)     ,INTENT(IN)    :: pressure! element pressure
      my_real ,DIMENSION(NEL)     ,INTENT(IN)    :: epsd    ! strain rate
      my_real ,DIMENSION(NEL)     ,INTENT(IN)    :: tstar   ! normalized temperature
      my_real ,DIMENSION(NEL)     ,INTENT(INOUT) :: off     ! element deactivation flag
      my_real ,DIMENSION(NEL)     ,INTENT(INOUT) :: dfmax   ! maximum damage
      my_real ,DIMENSION(NEL)     ,INTENT(INOUT) :: tdel    ! deactivation time
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I,J,NINDX
      INTEGER ,DIMENSION(NEL) :: INDX
      my_real :: D1,D2,D3,D4,D5,EPSD0,EPSF,EPSF_MIN
C=======================================================================
      nindx = 0  
      d1    = uparam(1)
      d2    = uparam(2)
      d3    = uparam(3)
      d4    = uparam(4)
      d5    = uparam(5)
      epsd0 = uparam(6)
      epsf_min = uparam(12)
c-----------------------------
      DO i=1,nel
        IF (off(i) == one .and. dpla(i) > zero) THEN
          epsf = d3 * pressure(i) / max(em20, svm(i))
          epsf = d1 + d2 * exp(epsf)
          IF (d4 /= zero)  epsf = epsf * (one + d4*log(max(one,epsd(i)/epsd0)))
          IF (d5 /= zero)  epsf = epsf * (one + d5*tstar(i))        
          epsf = max(epsf,epsf_min)   
          IF (epsf > zero) dfmax(i) = dfmax(i) + dpla(i) / epsf  
          IF (dfmax(i) >= one) THEN ! total damage in integration point
            nindx = nindx + 1
            indx(nindx) = i  
            tdel(i)     = time
            dfmax(i)    = one
            off(i)      = four_over_5
          ENDIF
        ENDIF 
      ENDDO      
c------------------------
      IF (nindx > 0) THEN        
        DO j=1,nindx             
          i = indx(j)            
#include "lockon.inc"
          WRITE(iout, 1000) ngl(i),time
          WRITE(istdo,1000) ngl(i),time
#include "lockoff.inc" 
        END DO                   
      END IF   ! NINDX             
c------------------
 1000 FORMAT(5x,'FAILURE (JC) OF BEAM ELEMENT ',i10,1x,'AT TIME :',1pe12.4)
c------------------
      RETURN
      END