fail_maxstrain_c.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    fail_maxstrain_c   ../engine/source/materials/fail/max_strain/fail_maxstrain_c.F
!||--- called by ------------------------------------------------------
!||    mulawc             ../engine/source/materials/mat_share/mulawc.F90
!||    usermat_shell      ../engine/source/materials/mat_share/usermat_shell.F
!||====================================================================
      SUBROUTINE fail_maxstrain_c(
     1     NEL       ,NUPARAM   ,NUVAR     ,UPARAM    ,UVAR      , 
     2     TIME      ,NGL       ,IPG       ,ILAY      ,IPT       ,                          
     3     EPSXX     ,EPSYY     ,EPSXY     ,EPSYZ     ,EPSZX     ,  
     4     OFF       ,FOFF      ,DMG_FLAG  ,DMG_SCALE ,
     5     DFMAX     ,LF_DAMMX  ,TDEL      ,TIMESTEP  )               
C-----------------------------------------------
C    modified Puck model ------
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include  "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include  "units_c.inc"
#include  "comlock.inc"
C-----------------------------------------------
C   I N P U T   A r g u m e n t s
C-----------------------------------------------
      INTEGER ,INTENT(IN) :: NEL,NUPARAM,NUVAR,IPG,ILAY,IPT,LF_DAMMX
      INTEGER ,DIMENSION(NEL) ,INTENT(IN) :: NGL
      my_real ,INTENT(IN) :: TIME,TIMESTEP
      my_real ,DIMENSION(NEL) ,INTENT(IN) :: OFF,
     .   EPSXX,EPSYY,EPSXY,EPSYZ,EPSZX
      my_real,DIMENSION(NUPARAM) ,INTENT(IN) :: uparam
C-----------------------------------------------
C   I N P U T   O U T P U T   A r g u m e n t s 
C-----------------------------------------------
      INTEGER ,INTENT(OUT) :: DMG_FLAG
      INTEGER ,DIMENSION(NEL) ,INTENT(INOUT) :: FOFF
      my_real ,DIMENSION(NEL,LF_DAMMX),INTENT(INOUT) :: DFMAX
      my_real ,DIMENSION(NEL) ,INTENT(OUT)   :: TDEL,DMG_SCALE
      my_real ,DIMENSION(NEL,NUVAR) ,INTENT(INOUT) :: UVAR
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I,J,NINDX,IFAIL_SH
      INTEGER ,DIMENSION(NEL) :: INDX
      my_real
     .   EPS1_MAX,EPS2_MAX,GAM12_MAX,TMAX,FCUT
      my_real
     .   exx(nel),eyy(nel),exy(nel),findex,rfactr,asrate
C!----------------------------------------------
      !=======================================================================
      ! - INITIALISATION OF COMPUTATION ON TIME STEP
      !=======================================================================
      ! Recovering model parameters
      eps1_max  = uparam(1)
      eps2_max  = uparam(2)
      gam12_max = uparam(3)
      tmax      = uparam(4)
      fcut      = uparam(5)
      ifail_sh  = int(uparam(6))
c
      ! Stress softening activation
      dmg_flag = 1    
c
      ! Stress tensor filtering
      IF (fcut > zero) THEN
        asrate = two*pi*fcut*timestep
        asrate = asrate/(one+asrate)
        DO i = 1,nel
          exx(i)    = asrate*epsxx(i) + (one - asrate)*uvar(i,2)
          eyy(i)    = asrate*epsyy(i) + (one - asrate)*uvar(i,3)
          exy(i)    = asrate*epsxy(i) + (one - asrate)*uvar(i,4)
          uvar(i,2) = exx(i)
          uvar(i,3) = eyy(i)
          uvar(i,4) = exy(i)
        ENDDO
      ELSE
        DO i = 1,nel
          exx(i) = epsxx(i)
          eyy(i) = epsyy(i)
          exy(i) = epsxy(i)
        ENDDO
      ENDIF
c
      !====================================================================
      ! - COMPUTATION OF THE DAMAGE VARIABLE EVOLUTION
      !==================================================================== 
      ! Initialization of element failure index           
      nindx = 0
      indx(1:nel) = 0  
c
      ! Loop over the elements
      DO i=1,nel
c
        ! If damage has not been reached yet
        IF (dfmax(i,1)<one) THEN
c
          ! Compute failure index and reserve factor
          findex = max(abs(exx(i))/eps1_max,
     .                 abs(eyy(i))/eps2_max,
     .                 abs(exy(i))/gam12_max)
          findex = max(zero,findex)
c
          ! Compute reserve factor 
          dfmax(i,2) = one/max(sqrt(findex),em20)
c
          ! Damage variable update
          dfmax(i,1) = min(one ,max(findex,dfmax(i,1)))
          IF (dfmax(i,1) >= one) THEN
            nindx = nindx+1                                    
            indx(nindx) = i                                    
            IF (ifail_sh > 0) THEN 
              uvar(i,1) = time
            ENDIF                                
          ENDIF
        ENDIF
c
        ! Stress relaxation in case of damage reached
        IF ((uvar(i,1) > zero).AND.(foff(i) /= 0).AND.(ifail_sh > 0)) THEN 
          dmg_scale(i) = exp(-(time - uvar(i,1))/tmax)   
          IF (dmg_scale(i) < em02) THEN
            foff(i) = 0
            tdel(i) = time
            dmg_scale(i) = zero
          ENDIF
        ENDIF  
      ENDDO       
c              
      !====================================================================
      ! - PRINTOUT DATA ABOUT FAILED ELEMENTS
      !====================================================================
      IF (nindx > 0) THEN  
        DO j=1,nindx       
          i = indx(j)      
#include  "lockon.inc"
          WRITE(iout, 2000) ngl(i),ipg,ilay,ipt
          WRITE(istdo,2100) ngl(i),ipg,ilay,ipt,time
#include  "lockoff.inc"
        END DO
      END IF              
c------------------------
 2000 FORMAT(1x,'FAILURE (MAXSTRAIN) OF SHELL ELEMENT ',i10,1x,',GAUSS PT',
     .       i2,1x,',LAYER',i3,1x,',INTEGRATION PT',i3)
 2100 FORMAT(1x,'FAILURE (MAXSTRAIN) OF SHELL ELEMENT ',i10,1x,',GAUSS PT',
     .       i2,1x,',LAYER',i3,1x,',INTEGRATION PT',i3,1x,'AT TIME :',1pe12.4)
c------------------------
      END