fail_rtcl_c.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    fail_rtcl_c     ../engine/source/materials/fail/rtcl/fail_rtcl_c.F
!||--- called by ------------------------------------------------------
!||    mulawc          ../engine/source/materials/mat_share/mulawc.F90
!||    usermat_shell   ../engine/source/materials/mat_share/usermat_shell.F
!||====================================================================
      SUBROUTINE fail_rtcl_c (
     1     NEL      ,NUPARAM  ,NUVAR    ,TIME     ,TIMESTEP ,UPARAM   ,
     2     SIGNXX   ,SIGNYY   ,SIGNXY   ,SIGNYZ   ,SIGNZX   ,NPTOT    ,
     3     NGL      ,DPLA     ,UVAR     ,OFF      ,DFMAX    ,TDELE    ,
     4     AREA     ,FOFF     ,IGTYP    ,OFFL     ,IPT      ,THK0     )
C!-----------------------------------------------
C!   I m p l i c i t   T y p e s
C!-----------------------------------------------
#include "implicit_f.inc"
C!---------+---------+---+---+-------------------
#include "units_c.inc"
#include "comlock.inc"
C!-----------------------------------------------
      INTEGER NEL, NUPARAM, NUVAR,NGL(NEL),IGTYP,IPT,
     .        NPTOT
      my_real TIME,TIMESTEP,UPARAM(*),
     .   SIGNXX(NEL),SIGNYY(NEL),OFFL(NEL),
     .   signxy(nel),signyz(nel),signzx(nel),uvar(nel,nuvar),
     .   dpla(nel),off(nel),dfmax(nel),tdele(nel),area(nel),thk0(nel)
      INTEGER, DIMENSION(NEL), INTENT(INOUT) :: FOFF
C!-----------------------------------------------
C!   L o c a l   V a r i a b l e s
C!-----------------------------------------------
      INTEGER I,J,INDX(NEL),NINDX,CONDITION(NEL),INST
      my_real 
     .        NHARD,EPSCAL,P,triaxs,vmises,hydros,EPS_CR,F_RTCL
C!--------------------------------------------------------------
      !=======================================================================
      ! - INITIALISATION OF COMPUTATION ON TIME STEP
      !=======================================================================
      ! Recovering model parameters
      epscal = uparam(1)
      inst   = nint(uparam(2))
      nhard  = uparam(3)
c
      ! Store initial element size
      IF (uvar(1,1) == zero) THEN 
        DO i = 1,nel
          uvar(i,1) = sqrt(area(i))
          uvar(i,2) = thk0(i)
        ENDDO
      ENDIF
C
      ! Initialization of variable
      nindx = 0  
c      
      !====================================================================
      ! - LOOP OVER THE ELEMENT TO COMPUTE THE DAMAGE VARIABLE
      !====================================================================       
      DO i=1,nel
c
        ! If the element is not broken
        IF (off(i) ==  one .AND. dpla(i) /= zero) THEN
c        
          ! Computation of hydrostatic stress, Von Mises stress, and stress triaxiality
          hydros = (signxx(i)+ signyy(i))/three
          vmises = sqrt((signxx(i)**2)+(signyy(i)**2)-(signxx(i)*signyy(i))+(three*signxy(i)**2))
          triaxs = hydros / max(em20,vmises)
          IF (triaxs > two_third)  triaxs = two_third
          IF (triaxs < -two_third) triaxs = -two_third
c
          ! Computing the plastic strain at failure according to stress triaxiality
          IF (triaxs < -third) THEN 
            f_rtcl = zero
          ELSEIF ((triaxs >= -third).AND.(triaxs < third)) THEN
            f_rtcl = two*((one+triaxs*sqrt(twelve-twenty7*(triaxs**2)))/
     .                  (three*triaxs+sqrt(twelve-twenty7*(triaxs**2))))
          ELSE
            f_rtcl = exp(-half)*exp(three_half*triaxs)
          ENDIF
c 
          ! Computation of simple tension failure strain (according to mesh size)
          IF (inst == 2) THEN 
            eps_cr = nhard + (epscal - nhard)*(uvar(i,2)/uvar(i,1))
          ELSE
            eps_cr = epscal
          ENDIF
c
          ! Computation of damage variables
          dfmax(i) = dfmax(i) + f_rtcl*dpla(i)/max(eps_cr,em6)
          dfmax(i) = min(one,dfmax(i))
c
          ! Checking element failure using global damage
          IF (offl(i) == one .AND. dfmax(i) >= one) THEN
            offl(i)          = zero
            foff(i)          = 0
            nindx            = nindx + 1
            indx(nindx)      = i  
            condition(nindx) = ipt
          ENDIF
        ENDIF 
      ENDDO
c------------------------
c------------------------
      IF (nindx > 0) THEN        
        DO j=1,nindx             
          i = indx(j)         
#include "lockon.inc"
          IF(condition(j) >= 1)  THEN         
            WRITE(iout, 2000) ngl(i),condition(j),time
            WRITE(istdo,2000) ngl(i),condition(j),time
          ENDIF
#include "lockoff.inc" 
        END DO                   
      END IF   ! NINDX         
c------------------------
 2000 FORMAT(1x,'FOR SHELL ELEMENT (RTCL)',i10,1x,'LAYER',i3,':',/,
     .       1x,'STRESS TENSOR SET TO ZERO',1x,'AT TIME :',1pe12.4)
      END