fail_rtcl_s.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    fail_rtcl_s     ../engine/source/materials/fail/rtcl/fail_rtcl_s.F
!||--- called by ------------------------------------------------------
!||    mmain           ../engine/source/materials/mat_share/mmain.F90
!||    mmain8          ../engine/source/materials/mat_share/mmain8.F
!||    mulaw           ../engine/source/materials/mat_share/mulaw.F90
!||    mulaw8          ../engine/source/materials/mat_share/mulaw8.F90
!||    usermat_solid   ../engine/source/materials/mat_share/usermat_solid.F
!||====================================================================
      SUBROUTINE fail_rtcl_s (
     1     NEL      ,NUPARAM  ,NUVAR    ,TIME     ,TIMESTEP ,UPARAM   ,
     2     SIGNXX   ,SIGNYY   ,SIGNZZ   ,SIGNXY   ,SIGNYZ   ,SIGNZX   ,
     3     NGL      ,DPLA     ,UVAR     ,OFF      ,DFMAX    ,TDELE    )
C!-----------------------------------------------
C!   I m p l i c i t   T y p e s
C!-----------------------------------------------
#include "implicit_f.inc"
C!---------+---------+---+---+-------------------
#include "mvsiz_p.inc"
#include "scr17_c.inc"
#include "units_c.inc"
#include "comlock.inc"
C!-----------------------------------------------
      INTEGER NEL, NUPARAM, NUVAR,NGL(NEL)
      my_real TIME,TIMESTEP,UPARAM(*),
     .   SIGNXX(NEL),SIGNYY(NEL),SIGNZZ(NEL),
     .   signxy(nel),signyz(nel),signzx(nel),uvar(nel,nuvar),
     .   dpla(nel),off(nel),dfmax(nel),tdele(nel)
C!-----------------------------------------------
C!   L o c a l   V a r i a b l e s
C!-----------------------------------------------
      INTEGER I,J,INDX(MVSIZ),NINDX
      my_real 
     .        P,triaxs,SVM,SXX,SYY,SZZ,EPS_CR,F_RTCL
C!--------------------------------------------------------------
      !=======================================================================
      ! - INITIALISATION OF COMPUTATION ON TIME STEP
      !=======================================================================
      ! Recovering model parameters
      eps_cr = uparam(1)
c
      ! Checking element failure and recovering user variable
      DO i=1,nel
       IF (off(i) < em01) off(i) = zero
       IF (off(i) < one .AND. off(i) > zero) off(i) = off(i)*four_over_5
      END DO
C
      ! Initialization of variable
      nindx = 0  
c      
      !====================================================================
      ! - LOOP OVER THE ELEMENT TO COMPUTE THE DAMAGE VARIABLE
      !====================================================================       
      DO i=1,nel
c
        ! If the element is not broken
        IF (off(i) ==  one .AND. dpla(i) /= zero) THEN
c        
          ! Computation of hydrostatic stress, Von Mises stress, and stress triaxiality
          p   = third*(signxx(i) + signyy(i) + signzz(i))
          sxx = signxx(i) - p
          syy = signyy(i) - p
          szz = signzz(i) - p
          svm = half*(sxx**2 + syy**2 + szz**2)
     .          + signxy(i)**2 + signzx(i)**2 + signyz(i)**2
          svm = sqrt(three*svm)
          triaxs = p/max(em20,svm)
          IF (triaxs > one)  triaxs = one
          IF (triaxs < -one) triaxs = -one
c
          ! Computing the plastic strain at failure according to stress triaxiality
          IF (triaxs < -third) THEN 
            f_rtcl = zero
          ELSEIF ((triaxs >= -third).AND.(triaxs < third)) THEN
            f_rtcl = two*((one+triaxs*sqrt(twelve-twenty7*(triaxs**2)))/
     .                  (three*triaxs+sqrt(twelve-twenty7*(triaxs**2))))
          ELSE
            f_rtcl = exp(-half)*exp(three_half*triaxs)
          ENDIF
c
          ! Computation of damage variables
          dfmax(i) = dfmax(i) + f_rtcl*dpla(i)/max(eps_cr,em6)
          dfmax(i) = min(one,dfmax(i))
c
          ! Checking element failure using global damage
          IF (dfmax(i) >= one .AND. off(i) == one) THEN
            off(i)      = four_over_5
            nindx       = nindx + 1
            indx(nindx) = i
            tdele(i)    = time    
          ENDIF
        ENDIF 
      ENDDO
c------------------------
c------------------------
      IF (nindx > 0) THEN
        DO j=1,nindx
          i = indx(j)     
#include "lockon.inc"
          WRITE(iout, 1000) ngl(i),time
          WRITE(istdo,1100) ngl(i),time
#include "lockoff.inc"
        END DO
      END IF         
c------------------------
 1000 FORMAT(1x,'DELETE SOLID ELEMENT NUMBER (RTCL) el#',i10,
     .          ' AT TIME :',1pe12.4)     
 1100 FORMAT(1x,'DELETE SOLID ELEMENT NUMBER (RTCL) el#',i10,
     .          ' AT TIME :',1pe12.4)
      END