freiniv.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    freiniv                ../engine/source/input/freiniv.F
!||--- called by ------------------------------------------------------
!||    freform                ../engine/source/input/freform.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../engine/source/output/message/message.F
!||    arret                  ../engine/source/system/arret.F
!||    errmsg                 ../engine/source/input/errmsg.F
!||    wriusc2                ../engine/source/input/wriusc2.F
!||--- uses       -----------------------------------------------------
!||    message_mod            ../engine/share/message_module/message_mod.F
!||    names_and_titles_mod   ../common_source/modules/names_and_titles_mod.F
!||====================================================================
      SUBROUTINE freiniv(IKAD,KEY0,KINIV,NINIV)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE names_and_titles_mod, ONLY: ncharline100
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IKAD(0:*),KINIV,NINIV
      CHARACTER KEY0(*)*5
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      INTEGER NVAR
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,M,N,NBC,K,K3,IV1(40),IKEY,JJ,IFM,IOS,IGN
      my_real v,vtx,vty,vtz
      CHARACTER KEY2*5, KEY3*5
      CHARACTER(LEN=NCHARLINE100)::CARTE
C-----------------------------------------------
      k=0
      ios = 0
      ikey=kiniv
      m = 0
      DO n=1,niniv
       READ(iusc1,rec=ikad(ikey)+k,fmt='(7X,A,1X,A,1X,I5,25X,I10)',
     .        err=9990)key2,key3,k3,nbc
       k=k+1
       IF (key2=='TRA  ') THEN
         m=1
         IF(key3(1:1)=='X') THEN
           jj=1
         ELSEIF(key3(1:1)=='Y') THEN
           jj=2
         ELSEIF(key3(1:1)=='Z') THEN
           jj=3
         ELSE
           CALL errmsg(key2)
         ENDIF
       ELSEIF (key2=='ROT  ') THEN
         m=1
         IF(key3(1:1)=='X') THEN
           jj=4
         ELSEIF(key3(1:1)=='Y') THEN
           jj=5
         ELSEIF(key3(1:1)=='Z') THEN
           jj=6
         ELSE
           CALL errmsg(key2)
         ENDIF
       ELSEIF (key2=='AXIS ') THEN
         m=2
         IF(key3(1:1)=='X') THEN
           jj=-1
         ELSEIF(key3(1:1)=='Y') THEN
           jj=-2
         ELSEIF(key3(1:1)=='Z') THEN
           jj=-3
         ELSE
           CALL errmsg(key2)
         ENDIF
       ELSE
         CALL errmsg(key2)
       ENDIF
C
       IF (jj < 0) THEN
c        first line
         CALL wriusc2(ikad(ikey)+k,1,key0(ikey))
         k=k+1
         READ(iusc2,*,err=9990,END=9990) ifm
c        second line
         CALL wriusc2(ikad(ikey)+k,1,key0(ikey))
         k=k+1
         READ(iusc2,*,err=9990,END=9990) VTX, VTY, VTZ, v
       ELSE
         CALL wriusc2(ikad(ikey)+k,1,key0(ikey))
         k=k+1
         READ(iusc2,*,iostat=ios) v
       ENDIF
C
       IF(nbc<=m .OR. ios /= 0 .OR.(k3==2.AND.nbc/=(m+1))) THEN
         CALL ancmsg(msgid=73,anmode=aninfo,c1=key0(ikey))
         CALL arret(2)
       END IF
C------
       IF (k3==2) THEN
         READ(iusc1,rec=ikad(ikey)+k,fmt='(A)',err=9990)carte
         k=k+1
         READ(carte,fmt='(I10)') ign
         WRITE(iin,'(3I10,1PG20.13)')-ign,ign,jj,v
         IF(jj < 0) THEN
           WRITE(iin,'(1P3G20.13,I10)')vtx,vty,vtz,ifm
         ENDIF
       ELSE
         DO i=1,nbc-m
           READ(iusc1,rec=ikad(ikey)+k,fmt='(A)',err=9990)carte
           CALL wriusc2(ikad(ikey)+k,1,key0(ikey))
           k=k+1
           READ(iusc2,*,err=9990,END=9990)(IV1(J),J=1,NVAR(CARTE))
           DO j=1,nvar(carte),k3+1
             WRITE(iin,'(3I10,1PG20.13)')iv1(j),iv1(j+k3),jj,v
             IF(jj < 0) THEN
               WRITE(iin,'(1P3G20.13,I10)')vtx,vty,vtz,ifm
             ENDIF
           ENDDO
         ENDDO
       END IF
      ENDDO
C
      RETURN
C
 9990 CONTINUE
      CALL ancmsg(msgid=73,anmode=aninfo,
     .            c1=key0(ikey))
      CALL arret(0)
      END