fvinjectint.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    fvinjectint    ../starter/source/airbag/fvinjectint.F
!||--- called by ------------------------------------------------------
!||    fvmesh0        ../starter/source/airbag/fvmesh0.F
!||--- uses       -----------------------------------------------------
!||====================================================================
      SUBROUTINE fvinjectint(IBUF  , ELEM   , IBAGJET, 
     .                       NJET  , IGRSURF,
     .                       ITAGEL, NN     , NEL, NB_NODE, MINUS_SIGN_REVERSE)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE groupdef_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IBUF(*), ELEM(3,*), IBAGJET(NIBJET,*), 
     .        NJET, 
     .        itagel(*), nn, nel, nb_node, minus_sign_reverse(nel)
      TYPE (SURF_)   , DIMENSION(NSURF)   :: IGRSURF
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, II, ITABINV(NB_NODE), ITAGINJ(NN), IREVERSED(NN), IINJ,
     .        ISU, NELSU, IEL, NG1, NG2, NG3, NG4, N1, N2, N3, N4,
     .        nall, nn1, nn2, rev
 
      INTEGER :: INV3(3)
      DATA INV3/3,2,1/
C
      DO i=1,nb_node
         itabinv(i)=0
      ENDDO
C
      DO i=1,nn
         ii=ibuf(i)
         itabinv(ii)=i
         itaginj(i)=0
      ENDDO
C
      DO iinj=1,njet
         isu=ibagjet(14,iinj)
         IF(isu==0) cycle
         nelsu=igrsurf(isu)%NSEG
         DO iel=1,nelsu
            ng1 = igrsurf(isu)%NODES(iel,1)
            ng2 = igrsurf(isu)%NODES(iel,2)
            ng3 = igrsurf(isu)%NODES(iel,3)
            ng4 = igrsurf(isu)%NODES(iel,4)
            n1=itabinv(ng1)
            n2=itabinv(ng2)
            n3=itabinv(ng3)
            n4=itabinv(ng4)
            itaginj(n1)=iinj
            itaginj(n2)=iinj
            itaginj(n3)=iinj
            itaginj(n4)=iinj
            rev = igrsurf(isu)%REVERSED(iel)
            ireversed(n1) = rev
            ireversed(n2) = rev
            ireversed(n3) = rev
            ireversed(n4) = rev
         ENDDO
      ENDDO
C
      DO iel=1,nel
         n1=elem(1,iel)
         n2=elem(2,iel)
         n3=elem(3,iel)
         itagel(iel)=0
         nall=itaginj(n1)*itaginj(n2)*itaginj(n3)
         IF (nall/=0) THEN
            nn1=itaginj(n2)-itaginj(n1)
            nn2=itaginj(n3)-itaginj(n1)
            IF (nn1==0.AND.nn2==0) THEN 
               itagel(iel)=itaginj(n1)
               IF(ireversed(n1) + ireversed(n2) + ireversed(n3) == 3) THEN
                  elem(1,iel) = n3
                  elem(3,iel) = n1
                  minus_sign_reverse(iel) = 1
               ENDIF
            ENDIF
         ENDIF
      ENDDO
C
      RETURN
      END