fvtemp.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    fvtemp         ../engine/source/airbag/fvtemp.F
!||--- called by ------------------------------------------------------
!||    fv_up_switch   ../engine/source/airbag/fv_up_switch.F
!||    fvbag1         ../engine/source/airbag/fvbag1.F
!||    fvupd1         ../engine/source/airbag/fvupd.F
!||--- uses       -----------------------------------------------------
!||    cast_mod       ../common_source/modules/cast_mod.F90
!||====================================================================
      SUBROUTINE fvtemp(ITYP  , EFAC_IN , CPA_IN  , CPB_IN  , CPC_IN  ,
     .                  CPD_IN   , CPE_IN  , CPF_IN  , RMW_IN  , TEMP0_IN,
     .                  TEMP_IN  )
       USE cast_mod, ONLY : double_to_my_real
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ITYP
      my_real, intent(in) ::
     .        efac_in, cpa_in, cpb_in, cpc_in, cpd_in, cpe_in, cpf_in, rmw_in, temp0_in
      my_real, intent(inout) ::  temp_in
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER K
      DOUBLE PRECISION :: CVA, HH, TEMP2, EFAC
      DOUBLE PRECISION :: CPA, CPB, CPC, CPD, CPE, CPF, RMW, TEMP0, TEMP
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      cpa=cpa_in
      cpb=cpb_in
      cpc=cpc_in
      cpd=cpd_in
      cpe=cpe_in
      cpf=cpf_in
      rmw=rmw_in
      temp0=temp0_in
      temp=temp_in
      efac = efac_in
 
      IF(ityp == 6) THEN
         cva=cpa-rmw
         IF(cpc == zero) THEN
            IF(cpb == zero) THEN
               temp=efac/cva
            ELSE IF( cpb .NE. zero) THEN
               temp=(sqrt(max(zero,cva*cva+two*cpb*efac))-cva)/cpb
            ELSE 
               temp = temp0
            ENDIF
         ELSE
            temp=temp0
            DO k=1,5
               hh=cpa+half*cpb*temp+third*cpc*temp*temp
               temp=efac/(hh-rmw)
            ENDDO
         ENDIF
      ELSEIF(ityp == 8) THEN
         temp=temp0
         DO k=1,5
            temp2=temp*temp
            hh=cpa+half*cpb*temp+third*cpc*temp2+
     .         fourth*cpd*temp*temp2-cpe/temp2+one_fifth*cpf*temp2*temp2   
            IF( (hh-rmw) > zero) THEN
              temp=efac/(hh-rmw)
            ELSE
              temp_in=zero
              RETURN
            ENDIF
         ENDDO
      ENDIF
      ! TEMP__IN**4 will be used, so we need to limit the value TEMP_IN 
      ! to avoid overflow
      ! in sp sqrt(sqrt(HUGE(TEMP_IN))) is 4.2E+9
      ! in dp sqrt(sqrt(HUGE(TEMP_IN))) is 1.2E+77
      temp_in = double_to_my_real(temp,max_value = sqrt(sqrt(huge(temp_in))))
      RETURN
      END