get_size_tag.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    get_size_tag   ../starter/source/spmd/get_size_tag.F
!||====================================================================
        SUBROUTINE get_size_tag(FLAG_FVM,FLAG_TAG,I24MAXNSNE,SIZE_TAG,IPARI)
!       ----------------------------------------------------------------
!       Description : GET_SIZE_TAG checks if TAG array is used and computes
!                     the size of TAG
!                     TAG is used for the following interfaces:
!                     7, 20, 22, 23, 24 and 25
!                     size of TAG: NUMNOD + I24MAXNSNE + SIZE_FVM
!                                               |            |
!                    max NSNE for TYP24     ____|            |
!       SIZE_FVM=NUMELS for INACTI=7 and FVM, otherwise 0 ___|
!       ----------------------------------------------------------------
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
 
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
        LOGICAL, INTENT(INOUT) :: FLAG_TAG
        LOGICAL, INTENT(IN) :: FLAG_FVM
        INTEGER, INTENT(IN) :: I24MAXNSNE
        INTEGER, INTENT(INOUT) :: SIZE_TAG
        INTEGER, DIMENSION(NPARI,*), INTENT(IN) ::  IPARI       
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
        INTEGER :: NI,ITYP,INACTI,SIZE_FVM
C-----------------------------------------------
C
        flag_tag=.false.
        size_fvm=0
        size_tag=0
        DO ni =1, ninter
                ityp = ipari(7,ni)
                inacti = ipari(22,ni)
                IF( ityp==7.OR.ityp==20.OR.ityp==22.OR.ityp==23.OR.
     .              ityp==24.OR.ityp==25 )    THEN
                        flag_tag=.true.                
                        size_tag = numnod+i24maxnsne
                        IF (flag_fvm .AND. inacti == 7) size_fvm = numels
                ENDIF
        ENDDO
        IF(flag_tag) size_tag = numnod+i24maxnsne+size_fvm  
 
 
        RETURN
        END SUBROUTINE get_size_tag
 
!||====================================================================
!||    get_size_inter24   ../starter/source/spmd/get_size_tag.F
!||--- called by ------------------------------------------------------
!||    lectur             ../starter/source/starter/lectur.F
!||====================================================================
        SUBROUTINE get_size_inter24(I24MAXNSNE,NINTER,NPARI,IPARI,FLAG_24_25)
!       ----------------------------------------------------------------
!       Description : GET_SIZE_INTER24 checks if NODLOCAL24 array is used and computes
!                     the size of NODLOCAL24
!                     NODLOCAL24 is used for the following interfaces:
!                     24 and 25
!                     size of NODLOCAL24: NUMNOD + I24MAXNSNE 
!                                                      |            
!                           max NSNE for TYP24     ____|            
!
!       ----------------------------------------------------------------
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
!       -*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*
!       NINTER : integer, number of interface
!       NPARI : integer, size of IPARI
!       I24MAXNSNE : integer, size of TAG_SCRATCH for interface 24
!       FLAG_24_25 : logical, flag for interface 24 or 25
!       -*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*
        INTEGER, INTENT(IN) :: NINTER,NPARI
        INTEGER, INTENT(INOUT) :: I24MAXNSNE
        LOGICAL, INTENT(INOUT) :: FLAG_24_25
        INTEGER, DIMENSION(NPARI,*), INTENT(IN) :: IPARI
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
        INTEGER :: NI,ITYP,NSNE
C ----------------------------------------
C Care TYPE24 + E2E
C Edge to Edge Nodes fictive Nodes are numbered over NUMNOD 
C Tag Arrays must be increased accordingly
        i24maxnsne = 0
        flag_24_25 = .false.
        DO ni= 1, ninter
                ityp = ipari(7,ni)
                IF(ityp==24)THEN
                        nsne   = ipari(55,ni)
                        i24maxnsne = max(i24maxnsne,nsne)
                ENDIF
                IF( (ityp==24).OR.(ityp==25) ) flag_24_25 = .true.
        ENDDO
 
        END SUBROUTINE get_size_inter24
 
!||====================================================================
!||    get_size_numnod_local   ../starter/source/spmd/get_size_tag.F
!||--- called by ------------------------------------------------------
!||    lectur                  ../starter/source/starter/lectur.F
!||--- calls      -----------------------------------------------------
!||    plist_ifront            ../starter/source/spmd/node/ddtools.F
!||====================================================================
        SUBROUTINE get_size_numnod_local(NUMNOD,NUMNOD_L)
!       ----------------------------------------------------------------
!       Description : GET_SIZE_NUMNOD_LOCAL computes the local number of 
!                     element on each domain
!       ----------------------------------------------------------------
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
        INTEGER, INTENT(IN) :: NUMNOD
        INTEGER, DIMENSION(NSPMD), INTENT(INOUT) :: NUMNOD_L
!       -*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*
!       NUMNOD : integer, 
!                total number of element
!       NSPMD  : integer,
!                number of domain
!       NUMNOD_L : integer, dimension=NSPMD
!                  number of element on each domain
!       -*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
        INTEGER I, J, ISPMD, NBR_PROC
        INTEGER, DIMENSION(NSPMD) :: ID_SPMD      
C ----------------------------------------
        numnod_l(1:nspmd) = 0   
        DO i=1,numnod
                CALL plist_ifront(id_spmd,i,nbr_proc)
#include "vectorize.inc"
                DO j=1,nbr_proc
                        ispmd = id_spmd(j)
                        numnod_l(ispmd) = numnod_l(ispmd) + 1
                ENDDO
        ENDDO
C
        RETURN
        END SUBROUTINE get_size_numnod_local
C