gettrans.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    gettrans   ../engine/source/elements/solid/solide8z/gettrans.f
!||--- called by ------------------------------------------------------
!||    mmats      ../engine/source/elements/solid/solide8z/mmats.f
!||====================================================================
      SUBROUTINE gettrans(JFT    ,JLT   ,GAMA ,QC  ,QCG  ,
     .                    QGC    ,QG   ) 
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JFT, JLT  
C     REAL
      my_real
     .   gama(mvsiz,6),qc(3,3,*),qcg(3,3,*),qgc(3,3,*),qg(3,3,*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,K
C     REAL
      my_real
     .   e1(mvsiz,3),e2(mvsiz,3),e3(mvsiz,3)
C-----------------------------------------------
       DO j= 1,3
        DO i=jft,jlt
          e1(i,j)=gama(i,j)
          e2(i,j)=gama(i,j+3)
        ENDDO
       ENDDO
       DO i=jft,jlt
          e3(i,1)=e1(i,2)*e2(i,3)-e1(i,3)*e2(i,2)
          e3(i,2)=e1(i,3)*e2(i,1)-e1(i,1)*e2(i,3)
          e3(i,3)=e1(i,1)*e2(i,2)-e1(i,2)*e2(i,1)
       ENDDO
C
       DO j= 1,3
        DO i=jft,jlt
         qc(1,j,i)=e1(i,j)*e1(i,j)
         qc(2,j,i)=e2(i,j)*e2(i,j)
         qc(3,j,i)=e3(i,j)*e3(i,j)
C
         qgc(1,j,i)=e1(i,j)*e2(i,j)
         qgc(2,j,i)=e2(i,j)*e3(i,j)
         qgc(3,j,i)=e1(i,j)*e3(i,j)
        ENDDO
       ENDDO
       DO j= 1,3
        k = j+1
        IF (k>3) k = 1
        DO i=jft,jlt
         qg(1,j,i)=e1(i,j)*e2(i,k)+e2(i,j)*e1(i,k)
         qg(2,j,i)=e2(i,j)*e3(i,k)+e3(i,j)*e2(i,k)
         qg(3,j,i)=e3(i,j)*e1(i,k)+e1(i,j)*e3(i,k)
C
         qcg(1,j,i)=two*e1(i,j)*e1(i,k)
         qcg(2,j,i)=two*e2(i,j)*e2(i,k)
         qcg(3,j,i)=two*e3(i,j)*e3(i,k)
        ENDDO
       ENDDO
C      
      RETURN
      END