gradient_reconstruction2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    gradient_reconstruction2         ../engine/source/ale/alemuscl/gradient_reconstruction2.F
!||--- called by ------------------------------------------------------
!||    ale51_gradient_reconstruction2   ../engine/source/ale/alemuscl/ale51_gradient_reconstruction2.F
!||--- uses       -----------------------------------------------------
!||    ale_connectivity_mod             ../common_source/modules/ale/ale_connectivity_mod.F
!||    alemuscl_mod                     ../common_source/modules/ale/alemuscl_mod.F
!||    element_mod                      ../common_source/modules/elements/element_mod.F90
!||    segvar_mod                       ../engine/share/modules/segvar_mod.F
!||====================================================================
      SUBROUTINE gradient_reconstruction2(IXQ, X, ALE_CONNECT, NV46, ITRIMAT, SEGVAR)
C-----------------------------------------------
C  D e s c r i p t i o n
C  This subroutine computes a gradient of the scalar field value in each 
C  element:
C        mean square approximation of the gradient in the face related 
C        neighborhood of the element
C-----------------------------------------------
C   M o d u l e s 
C-----------------------------------------------
      USE alemuscl_mod
      USE segvar_mod
      USE ale_connectivity_mod
      use element_mod , only :nixq
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include "vect01_c.inc"
#include "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NV46
      INTEGER, INTENT(IN) :: IXQ(NIXQ, NUMELQ)
      my_real, INTENT(IN) :: x(3, numnod)
      INTEGER, INTENT(IN) :: ITRIMAT
      TYPE(t_segvar) :: SEGVAR
      TYPE(t_ale_connectivity), INTENT(IN) :: ALE_CONNECT
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I, II, KK, IAD2, LGTH
      my_real ::  yk, zk, yl, zl,yf, zf
      my_real :: valk, vall
      my_real :: mat(2, 2), rhs(2), sol(2)
      INTEGER :: VOIS_ID
      INTEGER :: FACE_TO_NODE_LOCAL_ID(4, 2), NODEID1, NODEID2
      my_real :: det, undet
C-----------------------------------------------
C   S o u r c e   L i n e s 
C-----------------------------------------------
!!! Once for all, associate node local id to a face number
!!! Face 1
      face_to_node_local_id(1, 1) = 1 ; face_to_node_local_id(1, 2) = 2
!!! Face 2
      face_to_node_local_id(2, 1) = 2 ; face_to_node_local_id(2, 2) = 3
!!! Face 3
      face_to_node_local_id(3, 1) = 3 ; face_to_node_local_id(3, 2) = 4
!!! Face 4
      face_to_node_local_id(4, 1) = 4 ; face_to_node_local_id(4, 2) = 1
 
      DO i = lft, llt
         ii = i + nft
         !!! Reset mat, rhs
         mat(1:2, 1:2) = zero ; rhs(1:2) = zero
         !!! Value of the target function in the element
         valk = alemuscl_buffer%VOLUME_FRACTION(ii,itrimat)
         yk = alemuscl_buffer%ELCENTER(ii,2) ;
         zk = alemuscl_buffer%ELCENTER(ii,3)
         !!! IXS(2:9, II) : Node global ID
         iad2 = ale_connect%ee_connect%iad_connect(ii)
         lgth = ale_connect%ee_connect%iad_connect(ii+1)-iad2
         DO kk = 1, nv46
            vois_id = ale_connect%ee_connect%connected(iad2 + kk - 1)
            IF (vois_id > 0) THEN
               !!! Value of the target function in the current neighbor
               vall = alemuscl_buffer%VOLUME_FRACTION(vois_id,itrimat)
               yl = alemuscl_buffer%ELCENTER(vois_id,2) ;
               zl = alemuscl_buffer%ELCENTER(vois_id,3) ;
            ELSE
               IF(vois_id == 0) THEN
                 vall = valk
               ELSE
                 !vois_id<0 : means EBCS), -vois_id is seg_id
                 vall = segvar%PHASE_ALPHA(itrimat,-vois_id)
               ENDIF
 
               nodeid1 = ixq(1 + face_to_node_local_id(kk, 1), ii)
               nodeid2 = ixq(1 + face_to_node_local_id(kk, 2), ii)
 
               yf = half * (x(2, nodeid1) + x(2, nodeid2))
               zf = half * (x(3, nodeid1) + x(3, nodeid2))
 
               yl = two * yf - alemuscl_buffer%ELCENTER(ii,2)
               zl = two * zf - alemuscl_buffer%ELCENTER(ii,3)
            ENDIF
 
            !!! Incrementing mat and rhs
            rhs(1) = rhs(1) + (valk - vall) * (yl - yk)
            rhs(2) = rhs(2) + (valk - vall) * (zl - zk)
            mat(1, 1) = mat(1, 1) + (yl - yk) * (yl - yk)
            mat(1, 2) = mat(1, 2) + (yl - yk) * (zl - zk)
            mat(2, 1) = mat(2, 1) + (zl - zk) * (yl - yk)
            mat(2, 2) = mat(2, 2) + (zl - zk) * (zl - zk)
         ENDDO
         
         det = mat(1, 1) * mat(2, 2) - mat(2, 1) * mat(1, 2)
         IF (det == 0) THEN
            print*, "OUPS"
         ENDIF
         undet = one / det
         sol(1) = undet * (rhs(1) * mat(2,2) - rhs(2) * mat(1,2))
         sol(2) = undet * (- mat(2,1) * rhs(1) + mat(1, 1) * rhs(2))
         !!! Solution goes to the gradient
         alemuscl_buffer%GRAD(ii,2,itrimat) = -sol(1)
         alemuscl_buffer%GRAD(ii,3,itrimat) = -sol(2)
      ENDDO  ! I = LFT, LLT
C-----------------------------------------------      
      END SUBROUTINE gradient_reconstruction2