complex

Functions
subroutine	cptsv (n, nrhs, d, e, b, ldb, info)
	CPTSV computes the solution to system of linear equations A * X = B for PT matrices
subroutine	cptsvx (fact, n, nrhs, d, e, df, ef, b, ldb, x, ldx, rcond, ferr, berr, work, rwork, info)
	CPTSVX computes the solution to system of linear equations A * X = B for PT matrices

Detailed Description

This is the group of complex solve driver functions for PT matrices

Function Documentation

cptsv()

subroutine cptsv	(	integer	n,
		integer	nrhs,
		real, dimension( * )	d,
		complex, dimension( * )	e,
		complex, dimension( ldb, * )	b,
		integer	ldb,
		integer	info )

CPTSV computes the solution to system of linear equations A * X = B for PT matrices

Download CPTSV + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CPTSV computes the solution to a complex system of linear equations
!> A*X = B, where A is an N-by-N Hermitian positive definite tridiagonal
!> matrix, and X and B are N-by-NRHS matrices.
!>
!> A is factored as A = L*D*L**H, and the factored form of A is then
!> used to solve the system of equations.
!> 

Parameters

[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of right hand sides, i.e., the number of columns !> of the matrix B. NRHS >= 0. !>
[in,out]	D	!> D is REAL array, dimension (N) !> On entry, the n diagonal elements of the tridiagonal matrix !> A. On exit, the n diagonal elements of the diagonal matrix !> D from the factorization A = L*D*L**H. !>
[in,out]	E	!> E is COMPLEX array, dimension (N-1) !> On entry, the (n-1) subdiagonal elements of the tridiagonal !> matrix A. On exit, the (n-1) subdiagonal elements of the !> unit bidiagonal factor L from the L*D*L**H factorization of !> A. E can also be regarded as the superdiagonal of the unit !> bidiagonal factor U from the U**H*D*U factorization of A. !>
[in,out]	B	!> B is COMPLEX array, dimension (LDB,NRHS) !> On entry, the N-by-NRHS right hand side matrix B. !> On exit, if INFO = 0, the N-by-NRHS solution matrix X. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !> > 0: if INFO = i, the leading minor of order i is not !> positive definite, and the solution has not been !> computed. The factorization has not been completed !> unless i = N. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 114 of file cptsv.f.

*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDB, N, NRHS
*     ..
*     .. Array Arguments ..
      REAL               D( * )
      COMPLEX            B( LDB, * ), E( * )
*     ..
*
*  =====================================================================
*
*     .. External Subroutines ..
      EXTERNAL           cpttrf, cpttrs, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF( n.LT.0 ) THEN
         info = -1
      ELSE IF( nrhs.LT.0 ) THEN
         info = -2
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -6
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CPTSV ', -info )
         RETURN
      END IF
*
*     Compute the L*D*L**H (or U**H*D*U) factorization of A.
*
      CALL cpttrf( n, d, e, info )
      IF( info.EQ.0 ) THEN
*
*        Solve the system A*X = B, overwriting B with X.
*
         CALL cpttrs( 'Lower', n, nrhs, d, e, b, ldb, info )
      END IF
      RETURN
*
*     End of CPTSV
*

cptsvx()

subroutine cptsvx	(	character	fact,
		integer	n,
		integer	nrhs,
		real, dimension( * )	d,
		complex, dimension( * )	e,
		real, dimension( * )	df,
		complex, dimension( * )	ef,
		complex, dimension( ldb, * )	b,
		integer	ldb,
		complex, dimension( ldx, * )	x,
		integer	ldx,
		real	rcond,
		real, dimension( * )	ferr,
		real, dimension( * )	berr,
		complex, dimension( * )	work,
		real, dimension( * )	rwork,
		integer	info )

CPTSVX computes the solution to system of linear equations A * X = B for PT matrices

Download CPTSVX + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CPTSVX uses the factorization A = L*D*L**H to compute the solution
!> to a complex system of linear equations A*X = B, where A is an
!> N-by-N Hermitian positive definite tridiagonal matrix and X and B
!> are N-by-NRHS matrices.
!>
!> Error bounds on the solution and a condition estimate are also
!> provided.
!> 

Description:

!>
!> The following steps are performed:
!>
!> 1. If FACT = 'N', the matrix A is factored as A = L*D*L**H, where L
!>    is a unit lower bidiagonal matrix and D is diagonal.  The
!>    factorization can also be regarded as having the form
!>    A = U**H*D*U.
!>
!> 2. If the leading i-by-i principal minor is not positive definite,
!>    then the routine returns with INFO = i. Otherwise, the factored
!>    form of A is used to estimate the condition number of the matrix
!>    A.  If the reciprocal of the condition number is less than machine
!>    precision, INFO = N+1 is returned as a warning, but the routine
!>    still goes on to solve for X and compute error bounds as
!>    described below.
!>
!> 3. The system of equations is solved for X using the factored form
!>    of A.
!>
!> 4. Iterative refinement is applied to improve the computed solution
!>    matrix and calculate error bounds and backward error estimates
!>    for it.
!> 

Parameters

[in]	FACT	!> FACT is CHARACTER*1 !> Specifies whether or not the factored form of the matrix !> A is supplied on entry. !> = 'F': On entry, DF and EF contain the factored form of A. !> D, E, DF, and EF will not be modified. !> = 'N': The matrix A will be copied to DF and EF and !> factored. !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of right hand sides, i.e., the number of columns !> of the matrices B and X. NRHS >= 0. !>
[in]	D	!> D is REAL array, dimension (N) !> The n diagonal elements of the tridiagonal matrix A. !>
[in]	E	!> E is COMPLEX array, dimension (N-1) !> The (n-1) subdiagonal elements of the tridiagonal matrix A. !>
[in,out]	DF	!> DF is REAL array, dimension (N) !> If FACT = 'F', then DF is an input argument and on entry !> contains the n diagonal elements of the diagonal matrix D !> from the L*D*L**H factorization of A. !> If FACT = 'N', then DF is an output argument and on exit !> contains the n diagonal elements of the diagonal matrix D !> from the L*D*L**H factorization of A. !>
[in,out]	EF	!> EF is COMPLEX array, dimension (N-1) !> If FACT = 'F', then EF is an input argument and on entry !> contains the (n-1) subdiagonal elements of the unit !> bidiagonal factor L from the L*D*L**H factorization of A. !> If FACT = 'N', then EF is an output argument and on exit !> contains the (n-1) subdiagonal elements of the unit !> bidiagonal factor L from the L*D*L**H factorization of A. !>
[in]	B	!> B is COMPLEX array, dimension (LDB,NRHS) !> The N-by-NRHS right hand side matrix B. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[out]	X	!> X is COMPLEX array, dimension (LDX,NRHS) !> If INFO = 0 or INFO = N+1, the N-by-NRHS solution matrix X. !>
[in]	LDX	!> LDX is INTEGER !> The leading dimension of the array X. LDX >= max(1,N). !>
[out]	RCOND	!> RCOND is REAL !> The reciprocal condition number of the matrix A. If RCOND !> is less than the machine precision (in particular, if !> RCOND = 0), the matrix is singular to working precision. !> This condition is indicated by a return code of INFO > 0. !>
[out]	FERR	!> FERR is REAL array, dimension (NRHS) !> The forward error bound for each solution vector !> X(j) (the j-th column of the solution matrix X). !> If XTRUE is the true solution corresponding to X(j), FERR(j) !> is an estimated upper bound for the magnitude of the largest !> element in (X(j) - XTRUE) divided by the magnitude of the !> largest element in X(j). !>
[out]	BERR	!> BERR is REAL array, dimension (NRHS) !> The componentwise relative backward error of each solution !> vector X(j) (i.e., the smallest relative change in any !> element of A or B that makes X(j) an exact solution). !>
[out]	WORK	!> WORK is COMPLEX array, dimension (N) !>
[out]	RWORK	!> RWORK is REAL array, dimension (N) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !> > 0: if INFO = i, and i is !> <= N: the leading minor of order i of A is !> not positive definite, so the factorization !> could not be completed, and the solution has not !> been computed. RCOND = 0 is returned. !> = N+1: U is nonsingular, but RCOND is less than machine !> precision, meaning that the matrix is singular !> to working precision. Nevertheless, the !> solution and error bounds are computed because !> there are a number of situations where the !> computed solution can be more accurate than the !> value of RCOND would suggest. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 232 of file cptsvx.f.

*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          FACT
      INTEGER            INFO, LDB, LDX, N, NRHS
      REAL               RCOND
*     ..
*     .. Array Arguments ..
      REAL               BERR( * ), D( * ), DF( * ), FERR( * ),
     $                   RWORK( * )
      COMPLEX            B( LDB, * ), E( * ), EF( * ), WORK( * ),
     $                   X( LDX, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO
      parameter( zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            NOFACT
      REAL               ANORM
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               CLANHT, SLAMCH
      EXTERNAL           lsame, clanht, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           ccopy, clacpy, cptcon, cptrfs, cpttrf, cpttrs,
     $                   scopy, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      nofact = lsame( fact, 'N' )
      IF( .NOT.nofact .AND. .NOT.lsame( fact, 'F' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -9
      ELSE IF( ldx.LT.max( 1, n ) ) THEN
         info = -11
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CPTSVX', -info )
         RETURN
      END IF
*
      IF( nofact ) THEN
*
*        Compute the L*D*L**H (or U**H*D*U) factorization of A.
*
         CALL scopy( n, d, 1, df, 1 )
         IF( n.GT.1 )
     $      CALL ccopy( n-1, e, 1, ef, 1 )
         CALL cpttrf( n, df, ef, info )
*
*        Return if INFO is non-zero.
*
         IF( info.GT.0 )THEN
            rcond = zero
            RETURN
         END IF
      END IF
*
*     Compute the norm of the matrix A.
*
      anorm = clanht( '1', n, d, e )
*
*     Compute the reciprocal of the condition number of A.
*
      CALL cptcon( n, df, ef, anorm, rcond, rwork, info )
*
*     Compute the solution vectors X.
*
      CALL clacpy( 'Full', n, nrhs, b, ldb, x, ldx )
      CALL cpttrs( 'Lower', n, nrhs, df, ef, x, ldx, info )
*
*     Use iterative refinement to improve the computed solutions and
*     compute error bounds and backward error estimates for them.
*
      CALL cptrfs( 'Lower', n, nrhs, d, e, df, ef, b, ldb, x, ldx, ferr,
     $             berr, work, rwork, info )
*
*     Set INFO = N+1 if the matrix is singular to working precision.
*
      IF( rcond.LT.slamch( 'Epsilon' ) )
     $   info = n + 1
*
      RETURN
*
*     End of CPTSVX
*