gruneisen.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    gruneisen   ../common_source/eos/gruneisen.F
!||--- called by ------------------------------------------------------
!||    eosmain     ../common_source/eos/eosmain.F
!||====================================================================
      SUBROUTINE gruneisen(IFLAG , NEL    ,PM   ,OFF   ,EINT  ,MU   ,MU2 ,
     2                     ESPE  , DVOL   ,DF   ,VNEW  ,MAT   ,RHO0,
     3                     PNEW  , DPDM   ,DPDE ,PSH   ,
     4                     NUMMAT, NPROPM )
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
!----------------------------------------------------------------------------
!! \details STAGGERED SCHEME IS EXECUTED IN TWO PASSES IN EOSMAIN : IFLG=0 THEN IFLG=1
!! \details COLLOCATED SCHEME IS DOING A SINGLE PASS : IFLG=2
!! \details
!! \details  STAGGERED SCHEME
!! \details     EOSMAIN / IFLG = 0 : DERIVATIVE CALCULATION FOR SOUND SPEED ESTIMATION c[n+1] REQUIRED FOR PSEUDO-VISCOSITY (DPDE:partial derivative, DPDM:total derivative)
!! \details     MQVISCB            : PSEUDO-VISCOSITY Q[n+1]
!! \details     MEINT              : INTERNAL ENERGY INTEGRATION FOR E[n+1] : FIRST PART USING P[n], Q[n], and Q[n+1] CONTRIBUTIONS
!! \details     EOSMAIN / IFLG = 1 : UPDATE P[n+1], T[N+1]
!! \details                          INTERNAL ENERGY INTEGRATION FOR E[n+1] : LAST PART USING P[n+1] CONTRIBUTION
!! \details                            (second order integration dE = -P.dV where P = 0.5(P[n+1] + P[n]) )
!! \details  COLLOCATED SCHEME
!! \details     EOSMAIN / IFLG = 2 : SINGLE PASS FOR P[n+1] AND DERIVATIVES
!----------------------------------------------------------------------------
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
        INTEGER,INTENT(IN) :: NUMMAT            !< number of material laws  (size for PM array)
        INTEGER,INTENT(IN) :: NPROPM            !< size for PM array
        INTEGER,INTENT(IN) :: IFLAG             !< flag for the operation (staggered scheme IFLAG=0,1 ; collocated scheme IFLAG=2)
        INTEGER,INTENT(IN) :: NEL               !< number of elements in the current group
        INTEGER,INTENT(IN) :: MAT(NEL)          !< material identifier of each element
        my_real,INTENT(IN) :: pm(npropm,nummat) !< material buffer
        my_real,INTENT(IN) :: off(nel)          !< OFF=1 if element is active, OFF=0 if element is inactive
        my_real,INTENT(IN) :: mu(nel)           !< volumetric strain : rho/rho0-1
        my_real,INTENT(IN) :: mu2(nel)          !< MU**2 IF MU > 0 , 0 otherwise
        my_real,INTENT(IN) :: espe(nel)         !< specific internal energy
        my_real,INTENT(IN)  :: dvol(nel)        !< volume change
        my_real,INTENT(IN) :: vnew(nel)         !< current volume
        my_real,INTENT(IN) :: rho0(nel)         !< reference density
        my_real,INTENT(IN) :: df(nel)           !< relative volume (v/v0 = rho0/rho)
        my_real,INTENT(INOUT) :: eint(nel)      !< internal energy
        my_real,INTENT(INOUT) :: psh(nel)       !< pressure shift (for relative pressure modeling)
        my_real,INTENT(INOUT) :: pnew(nel)      !< current pressure
        my_real,INTENT(INOUT) :: dpde(nel)      !< partial derivative dP/dE where E=Eint/V0
        my_real,INTENT(INOUT) :: dpdm(nel)      !< total derivative : DP/Dmu = dPdmu + dPdE* P/(1+mu)**2
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
        INTEGER I, MX
        my_real AA, BB, DVV, FF, FG, FAC, XX, DFF, DFG, FAC1, PP
        my_real CC(NEL),S1(NEL),S2(NEL),S3(NEL),G0(NEL),GA(NEL),PC(NEL)
C-----------------------------------------------
C   B o d y
C-----------------------------------------------
        IF(iflag == 0) THEN !--- SOUND SPEED DERIVATIVE (DPDE is partial derivative, DPDM is total derivative)
          ! user parameters
          DO i=1,nel
            mx = mat(i)
            cc(i) = pm(33,mx)
            s1(i) = pm(34,mx)
            s2(i) = pm(160,mx)
            s3(i) = pm(161,mx)
            g0(i) = pm(35,mx)
            ga(i) = pm(36,mx)
            pc(i) = pm(37,mx)
            psh(i) = pm(88,mx)
          ENDDO
 
          ! Derivative
          DO i=1,nel
            fac=one
            fac1=one
            IF(mu(i) > zero) THEN
              xx= mu(i)/(one+mu(i))
              ff=one+(one-half*g0(i))*mu(i)-half*ga(i)*mu2(i)
              fg=one-(s1(i)-one+s2(i)*xx+s3(i)*xx*xx)*mu(i)
              fac=ff/(fg*fg)
              dff=one-half*g0(i)-ga(i)*mu(i)
              dfg=one-s1(i)+xx*(-two*s2(i)+xx*(s2(i)-three*s3(i))+two*s3(i)*xx*xx)
              fac1=fac*(one+mu(i)*(dff/ff-two*dfg/fg))
            ENDIF
            aa=fac*rho0(i)*cc(i)*cc(i)*mu(i)
            bb=g0(i)+ga(i)*mu(i)
            pp=max(aa+bb*espe(i),pc(i))*off(i) ! total pressure need for sound speed calculation (=> no pressure shift)
            dpdm(i)=fac1*rho0(i)*cc(i)*cc(i)+pp*df(i)*df(i)*bb+ga(i)*espe(i)
            dpde(i)=bb
            pnew(i) = max(pp,pc(i))*off(i)! P(mu[n+1],E[n])
            pnew(i) = pnew(i) - psh(i)
          ENDDO
 
        ELSEIF(iflag == 1) THEN  !--- P[n+1] and EINT[n+1]
          ! user parameters
          DO i=1,nel
            mx = mat(i)
            cc(i) = pm(33,mx)
            s1(i) = pm(34,mx)
            s2(i) = pm(160,mx)
            s3(i) = pm(161,mx)
            g0(i) = pm(35,mx)
            ga(i) = pm(36,mx)
            pc(i) = pm(37,mx)
            psh(i) = pm(88,mx)
          ENDDO
 
          ! Pressure P[n+1]
          ! Internal Energy Eint[n+1] (2nd order integration requires P[n+1])
          DO i=1,nel
            fac=one
            IF(mu(i) > zero) THEN
              xx= mu(i)/(one+mu(i))
              ff=one+(one-half*g0(i))*mu(i)-half*ga(i)*mu2(i)
              fg=one-(s1(i)-one+s2(i)*xx+s3(i)*xx*xx)*mu(i)
              fac=ff/(fg*fg)
            ENDIF
            aa=fac*rho0(i)*cc(i)*cc(i)*mu(i)
            bb=g0(i)+ga(i)*mu(i)
            dpde(i) = bb
            dvv=half*dvol(i)*df(i) / max(em15,vnew(i))
            pnew(i)=(aa+bb*espe(i))/(one+bb*dvv)
            pnew(i)= max(pnew(i),pc(i))*off(i) ! P(mu[n+1],E[n+1])
            eint(i)=eint(i) - half*dvol(i)*pnew(i) !total pressure for energy integration
            pnew(i) = pnew(i) - psh(i)
          ENDDO
 
        ELSEIF(iflag == 2) THEN  !--- collocated scheme (law151)
          ! user parameters
          DO i=1, nel
            mx = mat(i)
            cc(i) = pm(33,mx)
            s1(i) = pm(34,mx)
            s2(i) = pm(160,mx)
            s3(i) = pm(161,mx)
            g0(i) = pm(35,mx)
            ga(i) = pm(36,mx)
            pc(i) = pm(37,mx)
            psh(i) = pm(88,mx)
          ENDDO
          ! pressure and sound speed derivatives
          DO i=1,nel
            IF (vnew(i) > zero) THEN
              fac=one
              fac1=one
              IF(mu(i) > zero) THEN
                xx= mu(i)/(one+mu(i))
                ff=one+(one-half*g0(i))*mu(i)-half*ga(i)*mu2(i)
                fg=one-(s1(i)-one+s2(i)*xx+s3(i)*xx*xx)*mu(i)
                fac=ff/(fg*fg)
                dff=one-half*g0(i)-ga(i)*mu(i)
                dfg=one-s1(i)+xx*(-two*s2(i)+xx*(s2(i)-three*s3(i))+two*s3(i)*xx*xx)
                fac1=fac*(one+mu(i)*(dff/ff-two*dfg/fg))
              ENDIF
              aa=fac*rho0(i)*cc(i)*cc(i)*mu(i)
              bb=g0(i)+ga(i)*mu(i)
              pnew(i)=max(aa+bb*espe(i),pc(i))*off(i)
              dpdm(i)=fac1*rho0(i)*cc(i)*cc(i)+pnew(i)*df(i)*df(i)*bb+ga(i)*espe(i)
              dpde(i)=bb
              pnew(i)=pnew(i)-psh(i)
            ENDIF
          ENDDO
 
        ENDIF
 
        RETURN
      END